[Graphe AT PRo : programmation]

**asynergy** · 02/03/2009, 10:16

Bonjour à Tous,

Je cherche à introduire SuperTrend de Seban dans GraphePro sans succès.

Il dit qu'il faut prendre 3 fois la moyenne des 10 derniers range qu'on ajoute ou retranche du milieu du chandelier en cours.

Basiquement j'ai fait ainsi :

sp= (haut+bas)/2
sp1=haut(1)-bas(1)
sp2=haut(2)-bas(2)
sp3=haut(3)-bas(3)
sp4=haut(4)-bas(4)
sp5=haut(5)-bas(5)
sp6=haut(6)-bas(6)
sp7=haut(7)-bas(7)
sp8=haut(8)-bas(8)
sp9=haut(9)-bas(9)
sp10=haut(10)-bas(10)

M=sp1+sp2+sp3+sp4+sp5+sp6+sp7+sp8+sp9+sp10
MM=M/10
MM3=MM*3

Courbe = sp+MM3

Bien entendu ce n’est pas le bon raisonnement ;-(

Si quelqu'un à déjà la formule magique pour notre logiciel préféré, je l'en remercie par avance.

@+
francis

**asynergy** · 02/03/2009, 10:17

Bonjour à Tous,

Je cherche à introduire SuperTrend de Seban dans GraphePro sans succès.

Il dit qu'il faut prendre 3 fois la moyenne des 10 derniers range qu'on ajoute ou retranche du milieu du chandelier en cours.

Basiquement j'ai fait ainsi :

sp= (haut+bas)/2
sp1=haut(1)-bas(1)
sp2=haut(2)-bas(2)
sp3=haut(3)-bas(3)
sp4=haut(4)-bas(4)
sp5=haut(5)-bas(5)
sp6=haut(6)-bas(6)
sp7=haut(7)-bas(7)
sp8=haut(8)-bas(8)
sp9=haut(9)-bas(9)
sp10=haut(10)-bas(10)

M=sp1+sp2+sp3+sp4+sp5+sp6+sp7+sp8+sp9+sp10
MM=M/10
MM3=MM*3

Courbe = sp+MM3

Bien entendu ce n’est pas le bon raisonnement ;-(

Si quelqu'un à déjà la formule magique pour notre logiciel préféré, je l'en remercie par avance.

@+
francis

**smallcaps90** · 03/03/2009, 14:37

Bonjour Asynergy,

Tu avais calculé l'ATR sur 10 périodes mais uniquement l'un des segments du Super_Trend de O.Seban, en l'occurence celui qui est au dessus des cours quand ceux-ci sont en trend baissier. Et puis il te restais aussi à gèrer quel segment conserver à chaque instant suivant que le trend est haussier ou baissier...

Voici une version qui tourne du Super_Trend de O.Seban sur GrapheAT Pro. Je ne l'ai pas comparée à la version PRT, ce serait peut-être intéressant à faire.

Programme :

//===========
//SUPER_TREND
//===========

//v1.0 d'après O. Seban (à valider)
//le 02/03/2009
//smallcaps90
//=============

Si RangHisto=1 Alors
Trend=1 //initialisation
Sinon
//Ingrédients
//
TR(0)=MAXVAL(HAUT,CLOTURE(1))-MINVAL(BAS,CLOTURE(1))
MTR=Moyenne(TR,P1) //conforme à ATR
PM=(Haut+Bas)/2 //prix moyen
Up(0)=PM+P2*MTR //segment en trend baissier
Down(0)=PM-P2*MTR //segment en trend haussier

//Changement de tendance?
//
Si Cloture<Down(1)
Alors
Trend=-1 //passage en trend baissier
FinSi
Si Cloture>Up(1)
Alors
Trend=1 //passage en trend haussier
FinSi

//Filtrage des segments
//
Si Trend=1 ET Down<Down(1) Alors Down=Down(1)
Si Trend=-1 ET Up>Up(1) Alors Up=Up(1)

//Choix du segment sur le Super_Trend
//
Si Trend=1
Alors
SUPER_TREND=Down
Sinon
SUPER_TREND=Up
FinSi

FinSi

//Fin du code

Fenêtre Propriétés :
<center><img src='http://images.pro-at.com/forums-bourse/0309/3668_031523.png' alt='' /></center>

Exemple avec PPR :

Indicateur seul :
<center><img src='http://images.pro-at.com/forums-bourse/0309/3668_031523_8acbe3678ab963b1ccf71095679373ff.png' alt='' /></center>

Indicateur avec les courbes Up et Down à titre d'illustration :
<center><img src='http://images.pro-at.com/forums-bourse/0309/3668_031524.png' alt='' /></center>

Remarque :

Il existe de nombreux indics de ce genre qui suivent les tendances (avec plus ou moins de retard) à l'image d'un stop suiveur ou du SAR. Si cela peut intéresser, j'ai retenu le "Abraham Trend Indicator" de Andrew Abraham présenté dans TASC de sept 1998. Il est proche de celui de Seban.
Enfin un autre aussi, que j'utilise parfois, récupéré d'un forum sur MT4 et qui associe le CCI et l'ATR.

Programme :

//===================
//ABRAHAM_TREND_INDIC
//===================

//v1.0
//le 03/03/2009
//smallcaps90
//===================

Si RangHisto=1
Alors
HC=-100000
LC=100000
FinSi

Si RangHisto>=P2 Alors

TR(0)=MaxVal(Haut,Cloture(1))-MinVal(Bas,Cloture(1))
V1=P1*Pondere(TR,P2)
Si RangHisto=P2 Alors V2=HC-V1

Si Cloture>HC
Alors
HC=Cloture
FinSi

Si Cloture<LC
Alors
LC=Cloture
FinSi

Si Cloture<V2
Alors
V2=LC+V1
HC=Cloture
FinSi

Si Cloture>V2
Alors
V2=HC-V1
LC=Cloture
FinSi

V3(0)=V2
ATI=V3(1)

FinSi

//Fin du code

Fenêtre Propriétés :
<center><img src='http://images.pro-at.com/forums-bourse/0309/3668_031530.png' alt='' /></center>

Avec le même PPR que ci-dessus :
<center><img src='http://images.pro-at.com/forums-bourse/0309/3668_031531.png' alt='' /></center>

Voici enfin celui qui utilise le CCI et l'ATR .

Programme :

//===============
//SUPER_TREND_CCI
//===============

//smallcaps90 le 3/7/2006

//CCI20
//
MO=MOYENNE((HAUT+BAS+CLOTURE)/3,P2)
DEVIA=MOYENNE(ABSOLU(HAUT+BAS+CLOTURE)/3-MO,P2)
CCI20(0)=(HAUT+BAS+CLOTURE)/3-MO

//ATR5
//
TR5(0)=MAXVAL(HAUT,CLOTURE(1))-MINVAL(BAS,CLOTURE(1))
ATR5=MOYENNE(TR5,P3)

//Règles
//
CCI_ACTU=CCI20(0)
CCI_PRECED=CCI20(1)

SI CCI_ACTU>=P1 ET CCI_PRECED<P1 ALORS TR_UP(1)=TR_DN(1)

SI CCI_ACTU<=P1 ET CCI_PRECED>P1 ALORS TR_DN(1)=TR_UP(1)

SI CCI_ACTU>=P1
ALORS
TR_UP=BAS-ATR5
SI TR_UP<TR_UP(1) ALORS TR_UP=TR_UP(1)
FINSI

SI CCI_ACTU<=P1
ALORS
TR_DN=HAUT+ATR5
SI TR_DN>TR_DN(1) ALORS TR_DN=TR_DN(1)
FINSI

//Fin du Code

Fenêtre Propriétés :
<center><img src='http://images.pro-at.com/forums-bourse/0309/3668_031533.png' alt='' /></center>

Même exemple PPR :
<center><img src='http://images.pro-at.com/forums-bourse/0309/3668_031533_5c07b991efc0abdd1ee251f811ff6ded.png' alt='' /></center>

A partir de là, fais toi une opinion, parfois il n'y a pas photo...

Cordialement.

**asynergy** · 04/03/2009, 11:24

Bonjour SmallCaps90

Toujours aussi généreux !

Grand merci, je vais regarder tes 3 propositions en détail

Mais manifestement ce n’est pas la panacée et à consulter en symbiose avec les chandeliers et des momentums

Encore merci !
francis

**Papy29** · 12/03/2009, 17:29

Bonjour Smallcaps

merci pour ta réponse
lors de ta première intervention je n’avais pas bien saisi le Pb de repeindre le passé, mais depuis avec plusieurs test en chargent les cotations au jour le jour et en comparant les résultats sur Excel, j’ai eu des surprises parfois l’indicateur HP_CONV_CONC revient 2 a 3 jours en arrière ou disparaît , tu as raison c’était trop beau
par contre il donne des indications sur la tendance
je vais refaire des tests avec ta stratégie prudente

pour le Pb de style je vais contacter mlog

cordialement

**crnd** · 14/03/2009, 07:28

Bonjour Smallcaps

Je ne comprends pas ta formule CCI dans le "super_trend_cci"

MO=MOYENNE((HAUT+BAS+CLOTURE)/3,P2)
DEVIA=MOYENNE(ABSOLU(HAUT+BAS+CLOTURE)/3-MO,P2)
CCI20(0)=(HAUT+BAS+CLOTURE)/3-MO
elle ne prends en compte la deviation

je l'ai comparé avec celle du triplecciwood....ne devrait elle pas plutot s'ecrire comme ci dessous??

MO = MOYENNE((Haut+Bas+Cloture)/3,P2)
DEVIA = MOYENNE(ABSOLU((Haut+Bas+Cloture)/3-MO),P2)
CCI20(0)=((haut+Bas+Cloture)/3-MO)/(0.015 * DEVIA)

Merci d'avance et on week end

**smallcaps90** · 14/03/2009, 10:46

Bonjour crnd,

Oui je vois il y a eu un "joyeux" mélange, excuse-m'en.
En fait le programme date de juillet 2006 et n'avait pas été publié sur le forum. J'y avais testé diverses versions dont la version CCI et je m'étais rendu compte qu'avec ce CCI "classique" les résultats étaient moins bons qu'avec un simple oscillateur de moyennes dont le programme est bien celui qui a été posté le 03/03 dernier. L'identificateur "CCI20" est évidemment impropre ainsi que son nom "SUPER_TREND_CCI".

Voici le programme "repeigné" et renommé "SUPER_TREND_OSC" :

//===============
//SUPER_TREND_OSC
//===============

//V2.0
//le 14/03/2009
//smallcaps90
//===============

//Oscillateur de moyenne
//
MO=Moyenne((Haut+Bas+Cloture)/3,P1)
Osc(0)=((Haut+Bas+Cloture)/3-MO)

//ATR5
//
Tr5(0)=MaxVal(Haut,Cloture(1))-MinVal(Bas,Cloture(1))
ATR5=Moyenne(Tr5,P2)

//Règles
//
Si Osc>0 ET Osc(1)<0 Alors TR_UP(1)=TR_DN(1)

Si Osc<0 ET Osc(1)>0 Alors TR_DN(1)=TR_UP(1)

Si Osc>0
Alors
TR_UP=Bas-ATR5
Si TR_UP<TR_UP(1) Alors TR_UP=TR_UP(1)
FinSi

Si Osc<0
Alors
TR_DN=Haut+ATR5
Si TR_DN>TR_DN(1) Alors TR_DN=TR_DN(1)
Finsi

//Fin du Code

Fenêtre Propriétés :

<center><img src='http://images.pro-at.com/forums-bourse/0309/3668_141130.png' alt='' /></center>

En comparaison, la version Oscillateur de Moyenne et la version CCI qui tient donc compte de la variable DEVIA est moins "nette".
Voici les graphes daily pour PPR :

<center><img src='http://images.pro-at.com/forums-bourse/0309/3668_141140.png' alt='' /></center>

<center><img src='http://images.pro-at.com/forums-bourse/0309/3668_141141.png' alt='' /></center>

Avec la version Oscillateur de Moyenne, les performances sont aussi meilleures.
Pour la CAC40 un petit backtest daily sur les 500 dernières périodes (environ 2 ans) donne 37 valeurs avec un gain positif alors qu'avec la version CCI on n'en a que 22.

Je posterai ceci dans la file dédiée aux système de trading.

Cordialement.

**VIVI** · 14/03/2009, 15:51

Bonjour

Est-ce que quelq'un qui connait graphe AT Pro et TS saurait transcrire "SUPER_TREND_OSC" en easylanguage de TS

Merci et salutations
VIVI

**smallcaps90** · 16/03/2009, 09:22

Gruëzi VIVI,

Comme personne ne se lance, je te réponds.
Je n'utilise pas Tradestation aussi je ne te garantis pas que ma traduction en EasyLanguage de "SUPER_TREND_OSC" soit exempte de bugs syntaxiques...
J'en ai fait une image à cause des indentations :

<center><img src='http://images.pro-at.com/forums-bourse/0309/3668_161021.png' alt='' /></center>

Cordialement.

**VIVI** · 16/03/2009, 12:29

Bonjour

et merci smallcaps

cordiales salutations
VIVI

**smallcaps90** · 18/03/2009, 16:51

Bonsoir,

"Quelques nouvelles du front" :

Je viens de recevoir un email de Mr Metois de MLOG qui m'informe de l'avancement du projet de la future version 3.09 de GrapheAT Pro.
Le voici :

Bonjour,

Dans la nouvelle version 3.09, on pourra choisir le caractère graphique
affiché parmi tous ceux des polices spéciales Wingdings et Webdings (voir
écrans ci-joints). On pourra les choisir aussi dans les commentaires (hors
programmation).

Un nouveau type permet d'avoir un histogramme à 2 bornes (comme vous êtes
demandeur je crois). Cela permet d'implémenter la représentation Heikin Ashi
par exemple.

Cordialement.

Trois images jointes à l'email.
La police Wingdings :
<center><img src='http://images.pro-at.com/forums-bourse/0309/3668_181746.jpg' alt='' /></center>

Les types "O" et "X" pour le développement en cours d'une représentation en "point et figure" à laquelle je travaille :

<center><img src='http://images.pro-at.com/forums-bourse/0309/3668_181748.jpg' alt='' /></center>

Un exemple d'emploi du nouveau type de courbes "Histogramme à deux limites différentes de 0" demandé et son utilisation pour la reprentation en Heiken Ashi des cours :

<center><a href='http://images.pro-at.com/forums-bourse/0309/3668_181749.jpg' target='_blank' style='display:block; width:600px; border:2px dashed #888; padding:10px'><img src="http://images.pro-at.com/forums-bourse/0309/3668_181749.jpg" alt='' width='600' height='351' />Cliquez pour agrandir</a></center>

Un grand merci à lui.

Cordialement.

**FOKI** · 18/03/2009, 16:59

Bonjour ... et merci Smallcaps <img src='http://www.pro-at.com/style/images/icones/Super11.gif' border='0' alt='' title='' align='middle' />

FOKI

**crnd** · 23/03/2009, 17:02

Hello!!!!

D'exellentes nouvelles....merci Mr METOIS

Merci aussi à toi Smallcaps

**smallcaps90** · 02/04/2009, 09:38

Bonjour à toutes et à tous,

Excellente nouvelle, voici le mail que j'ai reçu cette nuit :

==================================
From : "mlog" <mlog@graphat.com>
02/04/09 01:44

Bonjour,

La version 3.09 est dispo sur le site. J'espère qu'elle répondra à certaines de vos attentes.

Cordialement.
==================================

Vous pouvez d'ores et déjà poster vos impressions sur la nouvelle version. Je ne suis pas chez moi actuellement et je ne pourrai la tester qu'à partir de demain.

Un grand merci à Mr Metois pour sa réactivité et l'attention qu'il a manifestée envers nos souhaits d'évolution.

Cordialement.

**LONGWAY** · 02/04/2009, 10:52

Bonjour,

Je viens de télécharger et cela me dit que ma version est non enregistrée.

Je quitte le téléchargement j'ouvre Graphe AT avec mon raccourci et cela s'ouvre sans la mise à jour?

Savez-vous d'où peut venir le problème?

Cordialement

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire