[Graphe AT PRo : programmation]

[smallcaps90]

Rebonjour,


Pour ceux de nos amis qui seraient intéressés par les différents "Super_Trend" présentés ici en mars dernier, après passage sur l'excellent blog "O-BO: Bourse, forex et trading" et sur les forums "TSD Forex" et "Forex Fatory", j'ai dépoussièré "SUPER_TREND_CCI" publié en mars dernier.
On peut trouver les versions antérieures et les développements qui en ont été faits à l'adresse:
<a href='/ref.php?uri=http%3A%2F%2Fwww.pro-at.com%2Fforums-bourse%2Ftopic.php%3Fwhichpage%3D138%26TOPIC_ID%3D6593' target="_blank">http://www.pro-at.com/forums-bourse/topic.php?whic...</a>
et pages suivantes,
puis aussi sur la file [GrapheAT Pro:Systèmes de Trading] à l'adresse :
<a href='/ref.php?uri=http%3A%2F%2Fwww.pro-at.com%2Fforums-bourse%2Ftopic.php%3Fwhichpage%3D6%26TOPIC_ID%3D27034' target="_blank">http://www.pro-at.com/forums-bourse/topic.php?whic...</a>

Cet indicateur de tendance ne repeint plus les couleurs comme il le faisait auparavant puisqu'il n'utilise plus qu'une couleur.(merci Chriss...).


<strong>Programme : "SUPER_TREND_CCI"</strong>

//=================
//SUPER_TREND_CCI
//=================


//V2.0
//smallcaps90
//d'après Forums TSD-Forex
//et Forex Factory
//Voir aussi www.o-bo.com
//le 08/09/2009
//=======================

//INDICATEURS reprogrammés
//

//CCI_P1
//
TP(0)=(Haut+Bas+Cloture)/3
M=Moyenne(TP,P1)
Devia=Moyenne(Absolu(TP-M),P1)
CCI_P1(0)=(TP-M)/(0.015 * Devia)

//ATR_P2
//
Si RangHisto=1
Alors
TR(0)=Haut-Bas
Sinon
TR=MAXVAL(MAXVAL((Haut-Bas),(Cloture(1)-Haut)),(Cloture(1)-Bas))
FinSi
Si RangHisto=P2 Alors ATR_P2(0)=Moyenne(TR,P2)
Si RangHisto>P2 Alors ATR_P2=((P2-1)*ATR_P2(1)+TR)/P2


//Super_Trend_CCI (ancien Super_Trend_CCI revisité)
//
Si CCI_P1>=0 Alors ST_CCI=Bas-ATR_P2
Si CCI_P1<0 Alors ST_CCI=Haut+ATR_P2

Si CCI_P1>=0 ET ST_CCI<ST_CCI(1)
OU
CCI_P1<0 ET ST_CCI>ST_CCI(1)
Alors
ST_CCI=ST_CCI(1)
FinSi

//Fin du code


<strong>Propriétés :</strong>

<center><img src='http://images.pro-at.com/forums-bourse/1009/3668_091352.png' alt='' /></center>

<strong>CAC40 avec le Super_Trend_CCI :</strong>

<center><img src='http://images.pro-at.com/forums-bourse/1009/3668_091358.png' alt='' /></center>

Cordialement.

[LONGWAY]

Bonjour Daniel,

Merci pour l'indicateur et la statistique cela fonctionne parfaitement.

Deux questions:

Puis je mettre la flèche sur l'indicateur et non sur les cours.

Si je veux créer un indicateur avec l'entrée en survente de l'un ou l'autre. Dois je simplement remplacer les « ET » par « OU »?

Cordialement.

[smallcaps90]

Bonjour Laurent,


Ok on supprime l'indic sur les cours et on intègre les flèches sur les indics.
Pour n'avoir les surventes que sur l'un ou l'autre il ne suffit pas de remplacer le ET par un OU, si tu veux une seule flèche par survente bien sûr.

Puisque tu poses cette question j'ai pensé qu'il serait intéressant de pouvoir visualiser les surventes sur le D seul ou sur le W seul ou sur les deux indics conjugués.
Dans ce dernier cas c'est souvent le D qui entre en survente avant le W mais il y a des cas inverses. Tu en verras un exemple sur Renault plus bas le 08/07/2009 dernier.

Pour pouvoir sélectionner entre ces trois cas de recherche des surventes, j'ai introduit un paramètre supplémentaire P7 dans le programme.
Si P7=0 tu auras seulement les surventes sur D du Stoch_ATD.
Si P7=1 ce sera sur le Williams seul et si P7=2 sur les deux indics conjugués (la flèche apparaîtra sur l'indic qui passe en survente le deuxième).

<strong>Programme "STO_WILL_SURVENTE" :</strong>

//=================
//STO_WILL_SURVENTE
//=================

//v2.0
//le 05/10/2009
//Modif le 11/10/2009
//smallcaps.90 pour LONGWAY
//============================================================
//Fonction :
//On cherche les dates où Stoch ATD et Stoch Williams
//sont ensemble sous leurs seuils de survente
//============================================================
//Paramètres :
//P1=recul de calcul du %K du Stoch_ATD et du %R de Williams
//P2=recul de calcul de la moyenne du %K du Stoch ATD
//P3=recul de calcul de la moyenne du %R de Williams
//P4=seuil de survente du Stoch
//P5=seuil de survente du Will
//P6=nb de tics scannés
//P7=origine de la survente P7=0-->D, P7=1-->W, P7=2-->D et W
//============================================================

//1-Indicateurs
//
//
//D du STOCH_ATD
//2ème version
//approximation par moyennes exponentielles
//
PH = Max(Haut,P1)
PB = Min(Bas,P1)
K = 100*(Cloture-PB)/(PH-PB)
D = Exposuiv(D,K,P2)

//%R de Williams
//
R = 100*(Cloture-PH)/(PH-PB)
W = Exposuiv(W,R,P3)


//2-Test de survente
//avec affichage dans la fenêtre d'affichage de la règle
//
Si RangHisto=1
Alors
Afficher "Dates des entrées en survente du STOCH ATD et du STOCH WILL :"
Afficher ""
Afficher nomaction$
Afficher ""
FinSi


Si RangHisto>FinHisto-P6 Alors

//Surventes sur D seul
Si D<=P4 ET flagD=0 ET (P7=0) Alors
flagD=1
Survente_D=P4
Afficher "Survente sur D le : " & datehisto$
FinSi

//Surventes sur W seul
Si W<=P5 ET flagW=0 ET (P7=1) Alors
flagW=1
Survente_W=P5
Afficher "Survente sur W le : " & datehisto$
FinSi

//Surventes sur les deux indics
//D est en survente avant W
Si D<=P4 ET flagD=0 ET flagW=0 ET (P7=2) Alors
flagD=1
Afficher "Survente sur D le : " & datehisto$
FinSi

Si flagD=1 ET flagW=0 ET W<=P5 ET (P7=2) Alors
flagW=1
Survente_W=P5
FinSi

//W est en survente avant D
Si W<=P5 ET flagW=0 ET flagD=0 ET (P7=2) Alors
flagW=1
Afficher "Survente sur W le : " & datehisto$
FinSi

Si flagW=1 ET flagD=0 ET D<=P4 ET (P7=2) Alors
flagD=1
Survente_D=P4
FinSi

Si D>P4 Alors flagD=0
Si W>P5 Alors flagW=0

FinSi

//Tracés de seuils de survente
//
SEUIL_STOCH=P4
SEUIL_WILL=P5

//Fin du code

<strong>Fenêtre Propriétés :</strong>

<center><img src='http://images.pro-at.com/forums-bourse/1009/3668_111152.png' alt='' /></center>

<strong>Exemples avec Renault :</strong>

<center><img src='http://images.pro-at.com/forums-bourse/1009/3668_111153.png' alt='' /></center>
<center><img src='http://images.pro-at.com/forums-bourse/1009/3668_111153_05caeb24edaae25b69f1baec4e9a4bea.png' alt='' /></center>
<center><img src='http://images.pro-at.com/forums-bourse/1009/3668_111153_4adb563e0f8a02c20cede1f6ce0c5492.png' alt='' /></center>

Les instructions "Afficher" qui se trouvent dans le programme te permettent déjà d'avoir des renseignements par la fenêtre d'affichage de la règle sans utiliser la statistique qui ne te donne que la dernière date d'entrée en survente du groupe d'actions scannées.


Pour ce qui concerne la stat, et pour faire simple, je n'ai pas distingué les différents cas. Le programme est néanmoins légèrement modifié comme suit :

<strong>Programme stat "STAT_SURVENTE" :</strong>

//=============
//STAT_SURVENTE
//=============

//v2.0
//le 06/10/2009
//modifiée le 11/10/2009
//smallcaps90
//=============

n=50 //défini la longueur du scan

Pour n Cours
Si STO_WILL_SURVENTE.Survente_D <>0
OU
STO_WILL_SURVENTE.Survente_W <>0
Alors
Colonne1="Entrée en survente le : " & datehisto$
Select=1
FinSi
FinPour

Si Select=1 Alors Selection

//Fin du code

La fenêtre Propriétés est inchangée.

Bon dimanche.
Cordialement.

[LONGWAY]

<blockquote><strong>Citation de : smallcaps90</strong> <em>(au 23-10-2008 19:15:42)</em>

Merci Fred d'avoir détecté le bug dans mon programme de l'ATR version Wilder.
Effectivement, il manquait bien une parenthèse après le deuxième MAXVAL derrière le "Sinon" dans le /1-/2-.
Toutes mes excuses.
La version correcte du programme est :

//==================
//Average True Range
//==================

//le 19/10/2008
//smallcaps90
//==================

//1 et 2- Calculer le premier True Range et les suivants.
//

Si RangHisto=1
Alors
TR=Haut-Bas
Sinon
TR=MAXVAL(MAXVAL((Haut-Bas),Absolu(Cloture(1)-Haut)),Absolu(Cloture(1)-Bas))
//ou encore ce qui revient au même :
//TR = MAXVAL(HAUT,CLOTURE(1)) - MINVAL(BAS,CLOTURE(1))
FinSi

//3- Calculer le premier ATR.
//

Si RangHisto=P1 Alors ATR=Moyenne(TR,P1)

//4- Calculer les ATR suivants.
//

Si RangHisto>P1 Alors ATR=((P1-1)*ATR(1)+TR)/P1

//fin du code

Cordialement.

</blockquote><hr />


Bonjour Daniel,

Dans la dernière version de l'ATR que tu as posté, quand je contrôle cela me spécifie une error "l'argument doit être historisé (tableau)". Qu'est ce que cela veut dire?

<center><img src='http://images.pro-at.com/forums-bourse/1009/7909_201910.jpg' alt='' /></center>

Et quand je clique sur OK le curseur se positionne derrière TR de :

Si RangHisto=P1 Alors ATR=Moyenne(TR,P1)

Où fais je une erreur?

Cordialement

[smallcaps90]

Bonjour Laurent,

Excuse-moi pour le retard mis à te répondre, je rentre tout juste d'une petite semaine de vacances en Toscane.

Pour résoudre ton pb il suffit que tu historises la variable TR comme ci-dessous :


//1 et 2- Calculer le premier True Range et les suivants.
//
Si RangHisto=1
Alors
<font color='#FF0000'>TR(0)=Haut-Bas </font>
Sinon
TR=MAXVAL(MAXVAL((Haut-Bas),Absolu(Cloture(1)-Haut)),Absolu(Cloture(1)-Bas))
//ou encore ce qui revient au même :
//TR = MAXVAL(HAUT,CLOTURE(1)) - MINVAL(BAS,CLOTURE(1))
FinSi
....

En effet, le calcul de la moyenne qui est fait ensuite pour générer l'ATR nécessite des variables historisées.


Cordialement.

[elpacha36]

bonsoir smallcaps90
vu le magic trend sur le site de o-bo je recherche un signal multi frame de cette indicateur sur mt4 comme celui proposé pour heikin ashi smothed merci pour tes infos

[smallcaps90]

Bonsoir elpacha36,


Je n'utilise pas MT4 mais tu peux peut-être aller voir les forum suivants (si tu ne les connais pas déjà) sur lesquels on trouve beaucoup d'indics dispos pour ce soft :
<a href='/ref.php?uri=http%3A%2F%2Fwww.forex-tsd.com%2Fforum.php' target="_blank">http://www.forex-tsd.com/forum.php</a>
<a href='/ref.php?uri=http%3A%2F%2Fwww.forexfactory.com%2Fforum.php' target="_blank">http://www.forexfactory.com/forum.php</a>
<a href='/ref.php?uri=http%3A%2F%2Fwww.trader-forex.fr%2Fforum%2F' target="_blank">http://www.trader-forex.fr/forum/</a>

Il est vraisemblable que le nom de l'indicateur "Magic Trend", créé par chris sur son blog, ne soit pas le même sur ces forums. Il faudra donc que tu cherches...

Cordialement.

[ftrillat]

Salut Max_et_Min as-tu avancé sur le système Droméas, j'ai vu ta programmation sur la file c'est assez intéressant cela fait penser aux points pivots avec l'ajout des 3 moyennes (34)
C'est étonnant que cela n'éveille pas plus l'attention ce système parait pourtant intéressant <img src='http://www.pro-at.com/style/images/icones/icon_smile.gif' border='0' alt='' title='' align='middle' />

ftrillat

[ftrillat]

Bonjour à tous , j'ai rentré les composante de max_et_min sur droméas mais je me retrouve avec un petit liseret de couleur en haut et une barre large bleu et rose en bas (le tout sur les cours) J'ai rentré les donnés de la page 142 1ère solution.Ou j'ai gaffé <img src='http://www.pro-at.com/style/images/icones/icon_smile_question.gif' border='0' alt='' title='' align='middle' />

D'autre part je voudrais ajouter sur la formule pivot J-1 ci-dessous les 3 moyennes expo (34) de droméas. La formule est de smallcaps publié dans la file. C'est pour des comparaison avec max_et_min où on pourrait aussi ajouter ces moyennes aussi puisqu'elles font partie de son système.

Je suis heureux de retrouver la liste maintenant que je suis éligible à l'adsl <img src='http://www.pro-at.com/style/images/icones/icon_smile_sleepy.gif' border='0' alt='' title='' align='middle' />

//===========
//POINT_PIVOT
//===========
//revu le 10/04/2008 pour jour J-1 P1=1

Si RangHisto=FinHisto-P1
Alors

Pour P2 Cours
X(0) = RangPour
Y(0) = (Haut+Bas+Cloture)/3
FinPour

SomX = Somme(X,P2)
SomY = Somme(Y,P2)
SomXX = Somme(X*X,P2)
SomXY = Somme(X*Y,P2)

A= (P2*SomXY-SomX*SomY)/(P2*SomXX-SomX*SomX)
B= (SomY-A*SomX)/P2

Pour P2 Cours
PP = A*X+B
FinPour

Pour P2 Cours
S1 = 2*PP-Haut
S2 = PP-Haut+Bas
S3 = S1-Haut+Bas
R1 = 2*PP-Bas
R2 = PP+Haut-Bas
R3 = R1+Haut-Bas
FinPour

FinSi

[smallcaps90]

Bonjour Fabrice,


Pas de souci pour les 3 moyennes expos de Raghee, il suffit d'ajouter les 3 lignes qui les définissent au listing avec le paramètre P3=34 de leur calcul.
Cà donne ceci :

<strong>PROGRAMME : </strong>

//============
//POINTS_PIVOT
//============

//V1.2
//revu le 10/04/2008
//modifié le 29/10/2009
//smallcaps90
//=====================


Si RangHisto=FinHisto-P1
Alors

Pour P2 Cours
X(0) = RangPour
Y(0) = (Haut+Bas+Cloture)/3
FinPour

SomX = Somme(X,P2)
SomY = Somme(Y,P2)
SomXX = Somme(X*X,P2)
SomXY = Somme(X*Y,P2)

A= (P2*SomXY-SomX*SomY)/(P2*SomXX-SomX*SomX)
B= (SomY-A*SomX)/P2

Pour P2 Cours
PP = A*X+B
FinPour

Pour P2 Cours
S1 = 2*PP-Haut
S2 = PP-Haut+Bas
S3 = S1-Haut+Bas
R1 = 2*PP-Bas
R2 = PP+Haut-Bas
R3 = R1+Haut-Bas
FinPour

FinSi

//Ajout 3 moyennes expo de Raghee Horner
//
MEH=EXPOSUIV(MEH,Haut,P3)
MEC=EXPOSUIV(MEC,Cloture,P3)
MEB=EXPOSUIV(MEB,Bas,P3)

//fin du code


<strong>PROPRIETES :</strong>

<center><img src='http://images.pro-at.com/forums-bourse/1009/3668_291608.png' alt='' /></center>

<strong>EXEMPLE :</strong>

<center><img src='http://images.pro-at.com/forums-bourse/1009/3668_291609.png' alt='' /></center>


Pour ce qui concerne DROMEAS de Kosta, Didier le dit bien page 142 :
"J'insiste ce n'est pas la régle KOSTA, juste une ébauche...".
La dernière vidéo de Kosta ne dévoile toujours pas l'algorithme qu'il utilise pour définir les niveaux qui permettent d'encadrer la zone de stabilité et les autres zones. Difficile par conséquent de programmer qq chose.
Ceci dit, effectivement son système semble intéressant. Peut-être en dira-t-il plus sur la prochaine vidéo?

Tu as du faire une erreur de recopie quelque part car cela fonctionne bien chez moi.


Cordialement.

[ftrillat]

Ok merci Daniel je vais rentrer tout ça ce WE . Tu es toujours fidel au poste <img src='http://www.pro-at.com/style/images/icones/icon_smile_wink.gif' border='0' alt='' title='' align='middle' />
Pour droméas oui c'est très intéressant je vais voir ou j'aurais pu faire une erreur pour le programme de max_et_min,j'avais vu ça précision t'inquiétes <img src='http://www.pro-at.com/style/images/icones/icon_smile.gif' border='0' alt='' title='' align='middle' />

C'est vrai que l'on attend la suite avec impatience et merci à
de m'avoir fait découvrir ces vidéos. Ne riez pas jusqu'à maintenant je ne pouvais pas lire car j'étais en zone blanche <img src='http://www.pro-at.com/style/images/icones/icon_smile_dead.gif' border='0' alt='' title='' align='middle' />

Bon WE à tous

[ftrillat]

Bonsoir à tous j'ai une question technique à vous poser:
Je change de PC (je laisse l'ancien à mes enfants)

Pour installer graphe at pro sur la nouvelle bécane avec toutes les formules de la liste que j'ai rentré, quelle est la façon la plus efficace de procéder <img src='http://www.pro-at.com/style/images/icones/icon_smile_question.gif' border='0' alt='' title='' align='middle' />

Pour vous c'est peut être, évident pour l'utilisateur moyen que je suis beaucoup moins <img src='http://www.pro-at.com/style/images/icones/icon_smile_dead.gif' border='0' alt='' title='' align='middle' />

au fait pour Daniel j'ai bien vérifier tout la formule de max-et-min l'ai effacé et re rentré mais j'ai toujours le mauvais affichage avec dans les cours un liseret de plusieurs couleurs en haut et une grosse barre bleu et rose sur le bas des prix,mistère... <img src='http://www.pro-at.com/style/images/icones/icon_smile_dead.gif' border='0' alt='' title='' align='middle' />

Pour sa description dans les vidéos, il semble qu'il fasse varier ces couleurs de chandeliers au franchissement des points pivots du chandelier précédent à la façon de J-1 que j'ai évoqué à la page précédente.

Fabrice

[smallcaps90]

Bonjour Fabrice,


Sur une clé USB ou un DD externe, sauvegarde ton répertoire C:Program FilesGraphe AT ProBase actuel
ainsi que le fichier GrapheAT.ini qui contient des infos sur tes styles et bien d'autres choses et replace-les dans le répertoire C:Program FilesGraphe AT Pro sur Ta nouvelle machine après demande d'une nouvelle clé à MLOG et installation de GrapheAT Pro. Je pense ne rien avoir oublié.

Je ne vois pas ce qui peut clocher dans l'install du programme "DROMEAS" de Didier. Vu que tu as un pb d'affichage, vérifie peut-être dans ta fenêtre Propriétés que les types de courbes "Histogramme" et "Histogramme bas" soient bien placés.

Quant à Kosta, oui bien sûr les couleurs des barres changent suivant la position des bougies par rapport aux limites des différentes zones de stabilité et autres chaos. Mais crois-tu qu'il utilise les points pivots classiques ou de Carter pour définir ces zones? Pas évident du tout.


Cordialement.

[ftrillat]

Merci pour tes conseils j'ai fait la demande à Mlog et je vais suivre ta procédure.

Concernant Droméas c'est en effet difficile à dire : en tout cas je remarque sur ces traits à droite que la zone neutre est matérialisée par 2 niveaux (point pivot et clôture J-1 ?) mais qu'il ne marque dans un sens que 2 niveaux de chaos pour 3 chez Carter(par sens de trade bien entendu)
As tu comparer avec d'autre méthodes de pivots pour voir les similitudes <img src='http://www.pro-at.com/style/images/icones/icon_smile_question.gif' border='0' alt='' title='' align='middle' />
Fabrice

[Jeff_X]

En passant, j'ai vu que MLOG nous a préparé une mise à jour du logiciel (V. 3.10 maintenant).

Je l'ai installé et c'est OK.

Cette mise à jour apporte quelques nouveaux petits trucs, notamment la position de la boîte de commentaires et l'ajout d'un choix relié au téléchargement des devises; en somme, rien de majeur.

Perso, étant donné que je suis Canadien et que je transige les actions nord-américaines, je télécharge tout ce qui m'intéresse via un shareware qui se nomme HSQuotes ainsi que les Indices Globaux & devises de EODData.com. Auparavant, j'utilisais le module de téléchargement de GrapheAT (marchés US), mais après avoir enduré quelques "bogues" j'ai décidé d'opter pour un shareware indépendent.

Par ailleurs, quelqu'un pourrait-il me dire si GrapheAT Pro fonctionne sur Windows 7 ?? Moi aussi je pense acheter un nouvel ordi éventuellement.

Merci d'avance.