[Graphe AT PRo : programmation]

[Gilda56]

[<font color='#FF0000'>b]Statistiques Intraday Abcbourse </strong><font color='#FF0000'></font></font><u></u>

Je teste enfin le telechargement de ABCBourse et j'ai une question sur les statistiques .

En Day je faisais tous les soirs tourner la machine et j'arrivais à obtenir qq actions qui auraient pu etre interessantes ALORS ma question c'est de savoir si c'est possible d'avoir la meme recherche stat par exemple en prenant l'unité de temps de 30 minutes ??

Bonjour à TOUS et à Smallcaps

[ftrillat]

Non les statistiques ne marchent qu'en daily
ftrillat

[Gilda56]

Merci

Tu as aussi Graphe At Pro avec le flux de ABC bourse ??


Moi je viens de faire un test pour ce mois

[ftrillat]

oui
ftrillat

[smallcaps90]

Bonsoir ftrillat,

Comme promis voici une solution possible pour la représentation RENKO des cours.
Je devrais plutôt dire de "type RENKO" car nous sommes limités à différents niveaux avec la version 3.08 actuelle de GrapheAT Pro.
En effet, GrapheAT Pro travaille sur une échelle de temps à pas constant alors que RENKO ne le fait pas. De plus les moyens de visualisation des briques RENKO y sont plus que limitées.
Un autre élément ne peut également pas être facilement traduit avec GrapheAT Pro : dans le cas où une transition nécessite plusieurs briques successives alors que l'on passe simplement d'une période à la suivante sur les cours, cette transition sera repésentée par une seule "super-brique" égale au nombre de briques correspondant. On ne peut pas opérer différemment non plus si on visualise ces transitions par des flèches sur les cours comme tu le suggères.

J'ai créé l'indicateur sur les cours, on pourrait tout aussi bien le créer sous les cours.

Programme :

//=====
//RENKO
//=====

//10/10/2006
//v1.3

//P1 est la taille de la brique Renko

SI RANGHISTO=1 ALORS
//------------inits
//
UP(0)=CLOTURE
DN(0)=CLOTURE

SINON

//------------transitions DOWN--->UP
//------------et poursuite trend haussier
//
SI CLOTURE>=UP(1)+P1 ALORS
NB_UP(0)=ENTIER((CLOTURE-UP(1))/P1)
DELTA_UP=NB_UP*P1
DN=UP(1)
UP=UP(1)+DELTA_UP
UP_V=UP
DN_V=DN
TEND=1
FLECHE_UP=-DN
FINSI

//------------transition UP---->DOWN
//------------et poursuite trend baissier
SI CLOTURE<=DN(1)-P1 ALORS
NB_DN(0)=ENTIER((DN(1)-CLOTURE)/P1)
DELTA_DN=NB_DN*P1
UP=DN(1)
DN=DN(1)-DELTA_DN
UP_R=UP
DN_R=DN
TEND=-1
FLECHE_DN=DN
FINSI

//------------pas de transition ni poursuite
//
SI CLOTURE<UP(1)+P1 ET CLOTURE>DN(1)-P1 ALORS
SI TEND=1 ALORS
SI NB_UP(1)>1 ALORS
DN=UP(1)-P1
UP=UP(1)
UP_V=UP
DN_V=DN
SINON
UP=UP(1)
DN=DN(1)
UP_V=UP
DN_V=DN
FINSI
FINSI

SI TEND=-1 ALORS
SI NB_DN(1)>1 ALORS
UP=DN(1)+P1
DN=DN(1)
UP_R=UP
DN_R=DN
SINON
UP=UP(1)
DN=DN(1)
UP_R=UP
DN_R=DN
FINSI
FINSI
FINSI


FINSI

//fin du code

Propriétés :
<center><img src='http://images.pro-at.com/forums-bourse/1006/3668_161806.gif' alt='' /></center>

Quelques possibilités de visualisation obtenues en sélectionnant les types d'affichages corrects dans la fenêtre Propriétés avec des briques de 0.5 :

A l'aide de tirets :
Sélectionner les 4 premières courbes comme dans la fenêtre Propriétés ci-dessus avec le type "tirets".

<center><img src='http://images.pro-at.com/forums-bourse/1006/3668_161808.gif' alt='' /></center>
Les zones encerclées sont relatives aux transitions qui comportent plusieurs briques pour une seule période. Les nombres inscrits correspondent aux nombres de briques empilées à la période.

A l'aide de segments :
Sélectionner uniquement les 4 premières courbes mais avec le type "segments" au lieu du type "tirets".
<center><img src='http://images.pro-at.com/forums-bourse/1006/3668_161809.gif' alt='' /></center>

A l'aide de flèches qui repèrent les transitions (simples et multiples) entre briques :
Sélectionner les deux courbes FLECHE_UP (type "flèche haut", couleur verte) et FLECHE_DN (type "flèche bas", couleur rouge).
<center><img src='http://images.pro-at.com/forums-bourse/1006/3668_161820.gif' alt='' /></center>

Cordialement.

[ftrillat]

Super boulot SmallCaps90,

Alors voici l'affichage en horaire sur le CAC des 2 indicateurs. Je préfère garder mes MME sur le graphe lui même car elles sont essentielles pour moi.

J'ai fait défilé le graphique volontairement pour te montrer un souci sur le sommet du cassure en 3 lignes. En fait les flèches disparaissent car on est au sommet de l'affichage de l'indicateur, tu vois une solution <img src='http://www.pro-at.com/style/images/icones/icon_smile_question.gif' border='0' alt='' title='' align='middle' />

POur le renko les flèches sont collées en haut mais à priori cela ne gène pas la lecture. J'ai choisi les 4 premières courbes avec "flèche haut et bas"

Bonne soirée ftrillat <img src='http://www.pro-at.com/style/images/icones/icon_smile_wink.gif' border='0' alt='' title='' align='middle' /><center><img src='http://images.pro-at.com/forums-bourse/1006/279_162130.gif' alt='' /></center>

[smallcaps90]

Re ftrillat,

Ok pour ton idée d'aligner les flèches rouges et vertes comme tu le fais sur un indicateur, cela reste lisible.

Pas de solution malheureusement lorsque les flèches sortent des limites de l'épure...
C'est le cas de la flèche verte qui apparaît sous le cours du 13/09/2006 sur le graphe daily suivant :
<center><img src='http://images.pro-at.com/forums-bourse/1006/3668_162306.gif' alt='' /></center>
Elle disparaît lorsqu'on se déplace vers la droite sur le graphe et qu'aucun cours plus bas que la flèche ne permet plus de la visualiser, comme ci-dessous :
<center><img src='http://images.pro-at.com/forums-bourse/1006/3668_162307.gif' alt='' /></center>

Ce qui se passe sur le graphe RENKO ci-dessus se produit également sur tout indicateur placé dans des conditions identiques.
C'est un inconvénient que MLOG pourrait traiter...

Cordialement.

[ftrillat]

Espérons que MLOG nous lit de temps en temps alors <img src='http://www.pro-at.com/style/images/icones/icon_smile_wink.gif' border='0' alt='' title='' align='middle' />

Ca reste utilisable en l'état en attendant "notre programmeur", sur l'horaire le renko et le three line sont très complémentaires.

Merci pour ton travail

ftrillat

[Gilda56]

bONJOUR
C'est curieux car Mlog il n'intervient pas Pourtant je dois avouer qu'avec Small il aurait tout intéret à le faire et nous aussi d'ailleurs Il y aurait une amélioration sympa d'un graphe qui est pas trop mal Mais sans l'aide de Small moi je serais à la rue


Alors vivement la prochaine version.

Bravo Ftrillat

[29manu29]

Bonjour SMALLCAPS90

Tout d'abord merci pour ton travail et tes interventions toujous trés instructives

Je m'intéresse depuis quelques temps à l'utilisation de la moyenne de HULL pour la construction d'un système de trading intraday. Je suis également arrivé à la construction d'un indicateur basé sur les pics et les creux de la vitesse de cette moyenne, sur lequel j'applique un filtre basé sur l'ADX pour évter de sortir prématurément d'un trend mais cela ne résoud pas tous les cas.

A cours d'idée ces temps-ci je suis tombé sur ce forum en faisant une recherche sur le net. Ton indicateur HULL_ANTICIP me semble assez intéressant.

As-tu progressé sur son utilisation ? Tu parlais de l'utilisation de la logique floue pour l'exploiter peux-tu donner quelques renseignements sur le sujet ?

J'ai une question relative à Graphe AT pro. Est-il possible de développer un indicateur basé sur le principe des Matrices Trading Action décrites par Samuel Rondot ?

Cordialement

[smallcaps90]

Bonjour 29manu29,

Merci de t'intéresser aux indicateurs que nous avions créé autour de la moyenne de Hull : Hull_Pics_Creux et Hull-Anticip, et de redonner ainsi un peu de punch par ton intervention à notre file un peu endormie.
En réalité, une réflexion s'effectue en privé avec d'autres amis du forum intéressés par la proposition de travail collaboratif que nous avions postée dernièrement au sujet de l'utilisation de la moyenne de Hull. Des résultats sont à attendre prochainement...

Je n'ai pas non plus de résultats tangibles à poster, pour l'instant, quant à l'emploi de la logique floue dans ce contexte. Ceci dit il est tout à fait possible de développer des indicateurs qui utilisent les "Fuzzy Sets" avec GrapheAT Pro...j'ai une moyenne exponentielle "adaptative" qui tourne en utilisant cette technique.

Par contre, je ne peux pas répondre de manière fiable à ta question concernant les MTA que S. Rondot propose car je n'ai pas lu ses bouquins. A ma connaissance un module spécifique est proposé aux utilistaurs de Waldata.
Le module Statistiques de GrapheAT Pro permet de faire pas mal de choses...alors tous les espoirs nous sont permis. "Tout est possible, tout est réalisable" (sic)...il suffit de s'y mettre...

Pour revenir aux moyennes de Hull, je t'en propose ci-dessous une version "polygonalisée", encore prototype, qui pourrait t'éviter de sortir trop tôt d'un trend...peut-être...au lieu de suivre les signaux donnés par "Hull_Pics_Creux" :
PROGRAMME :

//==========
//HULL_POLYG
//==========

//Hull polygonalisée
//V1.0
//smallcaps90 le 25/06/2006
//

//Paramètres
//
RECUL=P1 //recul du calcul de la Hull
SEUIL=P2% //seuil de la polygonalisation
BICOLORE=P3 //=1 permet de distinguer les trends haussiers en vert des trends baissiers en rouge
//=0 monocolor

//Moyenne de Hull
//
HULL_MA = PONDERE(2*PONDERE(CLOTURE,RECUL/2)-PONDERE(CLOTURE,RECUL),RACINE(RECUL))
M_BASE=HULL_MA

//Traitement des couleurs dans le cas où P3=1
//
DELTA=(HULL_MA-HULL_MA(1))/HULL_MA(1)
SI SEUIL>0 //pas vraiment utile....
ALORS
SI ABSOLU(DELTA)<SEUIL
ALORS
HULL_MA=HULL_MA(1)
FINSI

SI BICOLORE=1
ALORS
TENDANCE(0) = TENDANCE(1)
SI DELTA>SEUIL ALORS TENDANCE=1
SI -DELTA>SEUIL ALORS TENDANCE=-1

SI TENDANCE>0
ALORS
M_PLUS=HULL_MA
SI TENDANCE(1)<0 ALORS M_PLUS(1)=HULL_MA(1)
M_MOINS=0
FINSI

SI TENDANCE<0
ALORS
M_MOINS=HULL_MA
SI TENDANCE(1)>0 ALORS M_MOINS(1)=HULL_MA(1)
M_PLUS=0
FINSI

FINSI

FINSI

//fin du code

PROPRIETES :
<center><img src='http://images.pro-at.com/forums-bourse/1106/3668_152008.gif' alt='' /></center>

Exemples avec différentes valeurs du seuil P2%:
<center><img src='http://images.pro-at.com/forums-bourse/1106/3668_152010.gif' alt='' /></center>
<center><img src='http://images.pro-at.com/forums-bourse/1106/3668_152009_17fbc2f72a3af79c19c0b0e899b6d242.gif' alt='' /></center>
<center><img src='http://images.pro-at.com/forums-bourse/1106/3668_152010_4cfb3cf19bc3ff40f0af7cf1c868fff2.gif' alt='' /></center>

Cordialement.

[29manu29]

Bonsoir,

Merci pour ta réponse et je vais de ce pas saisir l'indicateur HULL_POLYG.

Concernant les matrices MTA il y a effectivement WALDATA qui propose un module spécifique mais la prise en main semble assez ardue et waldata n'est pas au même tarif que Graphe AT pro.

Je connais mal le module statistiques, est-il possible de tracer une courbe représentant pour chaque barre le nombre de valeurs ayant déclenché un signal ?

J'ai regardé d'un peu plus prés l'indicateur HULL_ANTICIP, et n'y aurait-il pas la possibilité d'accélérer le calcul en effectuant une recherche de la valeur CF par dichotomie ?

Enfin peux-tu me fournir quelques explications supplémentaires sur ta moyenne exponentielle adaptative (je ne connais absolument rien à la logique floue)

Encore merci

Cordialement

[smallcaps90]

Re 29manu29,

<font color='#0000FF'><em>Je connais mal le module statistiques, est-il possible de tracer une courbe représentant pour chaque barre le nombre de valeurs ayant déclenché un signal ?</em> </font>

On ne peut pas avec la V3.08 tracer de courbe à partir du module "Statistique", par contre on pourrait générer un tableau qui contiendrait ces infos.

<font color='#0000FF'><em>J'ai regardé d'un peu plus prés l'indicateur HULL_ANTICIP, et n'y aurait-il pas la possibilité d'accélérer le calcul en effectuant une recherche de la valeur CF par dichotomie ? </em></font>

Il faudrait alors remettre à plat l'indicateur en question...pourquoi pas?

<font color='#0000FF'><em>Enfin peux-tu me fournir quelques explications supplémentaires sur ta moyenne exponentielle adaptative (je ne connais absolument rien à la logique floue) </em></font>

En quelques mots, il s'agit tout simplement de déterminer le facteur ALPHA qui intervient dans le calcul d'une moyenne exponentielle (des cours clôture par exemple), suivant l'expression classique :
M_EXPO = M_EXPO(1)+(CLOTURE-M_EXPO(1))*ALPHA.
Au lieu de garder ALPHA constant comme on le fait habituellement, il est possible en utilisant un contrôleur flou d'architecture classique, de changer la valeur de ALPHA continuellement suivant des règles floues "appropriées". On peut ainsi obtenir une moyenne exponentielle adaptative.
Entre les 2 cas extrêmes :
- ALPHA=0, qui entraîne M_EXPO=M_EXPO(1) la moyenne restant constante, avec un lag maxi par conséquent,
- et ALPHA=1 qui entraîne M_EXPO=CLOTURE donc avec un lag =0,
entre ces deux cas extrêmes il existe une infinité de valeurs possibles.
Le but de l'opération est de trouver celles qui sont les mieux adaptées à chaque barre suivant certains critères comme lissage et/ou lag "corrects"...

Si ALPHA est faible, cela va impliquer un recul de calcul : R=(2-ALPHA)/ALPHA, grand et par conséquent la prise en compte de nombreuses valeurs passées de la clôture. On estime alors non gênant que le passé intervienne beaucoup. C'est la cas si les clôtures varient peu. La moyenne sera peu "nerveuse".
Si au contraire ALPHA est grand, cela va impliquer un recul de calcul faible donc la prise en compte d'un petit nombre de barres. En d'autres mots on souhaite que le passé intervenne peu et la moyenne suivra rapidement les changements de valeurs de la clôture si celle-ci varie vite.

A partir de ces considérations, dont l'essence est floue, on peut obtenir un système qui détermine les valeurs ad-hoc de ALPHA à chaque barre.

Comme il n'est pas possible de faire ici un cours complet sur la logique floue (il existe de nombreux sites Internet très bien faits sur le sujet), je me contenterai de donner quelques principes basiques.

En raccourci :
- on commence par rendre floue une quantité qui représente par exemple la vitesse de variation de la clôture à chaque barre. On peut faire de même avec son accélération éventuellement. Ces deux grandeurs constitueront les entrées du système. Cette opération de passage du non-flou au flou se nomme "fuzzyfication" ;
- ces deux quantités rendues floues sont ensuite confrontées aux règles dont j'ai présenté succinctement le principe ci-dessus afin d'en déduire une valeur floue du facteur ALPHA. Le module qui réalise cette opération est un mini système expert flou comportant une "base de connaissances" avec ses règles floues et un "moteur d'inférence" qui implémente les raisonnements adéquats...;
- enfin comme nous avons besoin in fine d'une valeur précise de ALPHA pour effectuer le calcul de la moyenne expo à chaque barre, il faut générer celle-ci. L'opération correspondante de passage du flou au non-flou se nomme "défuzzyfication".

Voici ce qu'on obtient avec un jeu de règles et des méthodes de fuzzyfication et défuzzyfication appropriées :
<center><img src='http://images.pro-at.com/forums-bourse/1106/3668_160006.gif' alt='' /></center>
Je n'ai pas encore introduit de connaissance relative au lissage dans la base de règles floues, ce qui explique l'apparition de quelques points anguleux sur la moyenne expo à certains endroits.

Pour conclure, je dirai que le principe de construction de cet indicateur utilisant la logique floue est en soi plus intéressant que le résultat final obtenu...mais cela se discute bien entendu.

Cordialement.

[29manu29]

Bonsoir SMALLCAPS90

Merci pour tes explications, je suis allé à la recherche d'infos sur la logique floue et j'ai trouver 2 ou 3 présentations simples (pas facile de trouver une présentation au ras des paquerettes), il me reste plus qu'à trouver du temps.

Pour l'indicateur HULL_ANTICIP je vais essayé de me pencher sur la recherche par dichotomie, cela me fera un bon exercice pour me familiariser avec le langage de programmation de Graphe AT PRO.

Concernant les règles statistiques de Graphe AT PRO comment faudrait-il s'y prendre pour avoir, pour chaque barre, le nombre de valeurs ayant présenté un PIC ou un CREUX sur l'indicateur HULL_PICS_CREUX au cours des n dernières barres ?

Merci pour ton aide

[29manu29]

Rebonsoir

Existe-t-il sur ce forum le source des indicateurs Swing Index et Accumulation Swing Index

Cordialement