[Graphe AT PRo : programmation]

**smallcaps90** · 19/11/2006, 15:45

Merci 29manu29.
Si tu pouvais joindre un graphe Jour d'Accor sur les 100 dernière périodes de l'historique ce serait super...

**29manu29** · 19/11/2006, 20:50

Re SMALLCPS90

Le Graphique accor sur les 10 dernières barres (j'avais oublié de faire l'importation des cours)

Cordialement<center><img src='http://images.pro-at.com/forums-bourse/1106/17495_192150.gif' alt='' /></center>

**smallcaps90** · 20/11/2006, 09:14

Bonjour 29manu29,

Merci pour ce graphe.
J'ai des difficultés à obtenir le même que toi avec ton programme recopié ici alors que j'ai le même tracé avec mon ancien programme... Peut-être est-ce dû au choix du paramètre P3 qui pour moi représentait le nombre d'itérations à effectuer? Dans ton post d'hier tu indiques P3=0.001. Es-tu sûr de cette valeur?
Lorsque je donne à P3 la valeur 1, j'obtiens un blocage systématique du programme. Pour toute autre valeur supérieure j'obtiens un tracé qui colle aux clotûres pour PIC1 et CREUX1.
Le listing que tu as posté est-il conforme à celui que tu utilises?

J'ai modifié assez profondément mon algorithme de recherche des segments montants et descendants de la Hull en le simplifiant drastiquement. Mais cela n'explique pas ce problème puisqu'on ne fait que récupérer ces segments du programme "HULL" à des fins de tracé de la moyenne bicolore dans "HULL_ANTICIP".
On pourrait d'ailleurs lui intégrer ce nouvel algorithme qui n'est pas pénalisant en temps d'exécution...l'architecture un peu bizarre de l'enclenchement des règles étant due au fait que la recherche a progressé lentement depuis que nous nous sommes intéressés FOKI et moi à ce problème...

Cordialement.

**29manu29** · 20/11/2006, 21:59

Bonsoir SMALLCAPS90

Dans l'exemple que j'ai posté j'utilise une moyenne de HULL sur 48 barres (paramètre P1)
Le paramétre P3 sert au calcul de la précision de la valeur caculée utilisée dans la condition de sortie de la boucle TANTQUE, basée sur la différence entre la moyenne et la moyenne anticipée. Je pense qu'il y a un petit problème avec ce test, il ne faut pas tester la valeur absolue de la différence.
J'ai constaté également un plantage lorsque P3 vaut 1 dans le cas où P1=10 (mais pas pour P1=48)
Je me penche sur le problème dés que j'ai un peu de temps (je m'absente pendant trois jours donc ce ne sera pas avant ce week-end).

Cordialement

**29manu29** · 24/11/2006, 21:29

Bonsoir SMALLCAPS90

J'ai fait quelques modifications sur l'indicataur HULL_ANTICIP. Pour le graphe d'Accor j'utilise une moyenne de HULL sur 10 barres. J'ai utilisé le paramètres suivants pour l'indicateur HULL_ANTICIP :
P1=10
P2=100
P3=0,01
P4=25

J'ai comparé avec l'indicatur que tu avais posté, à priori je n'ai pas vu de différence flagrante sauf pour la vitesse d'exécution.

Cordialement

Le code :

//=================
//HULL_ANTICIP
//=================

//Détermination de la clôture future
//qui induira un renversement de la Hull
//
//v3.2
//smallcaps90 le 05/07/2006
//v3.3
//29manu29 le 23/11/2006
//Amélioration de la vitesse de calcul,
//Recherche de la clôture future par dichotomie
//

//Paramètres à définir :
//
//P1 = Recul du calcul de la Hull
//P2 = Nb de périodes avant la FinHisto sur lesquelles on souhaite calculer et
// visualiser les clôtures futures qui entraîneraient des retournements de la Hull
//P3 = Limite de la différence entre HULL et MF_HULL pour arrêter la recherche (en % de la HULL)
//P4 = Paramètre de calcul des limites mini et maxi des clôtures futures (en %)
//

//----Récupérer les segments bicolorés de la Hull pour la tracer
//

HULL_V1=M_HULL_V1
HULL_V2=M_HULL_V2
HULL_R1=M_HULL_R1
HULL_R2=M_HULL_R2
HULL=M_HULL

C(0)=Cloture //simple changement de variables

//----Constitution des clotures retardées
//----pour calculer la Hull future
//

CR(0)=CLOTURE(-1)

//----Calculer sur les P2 dernières périodes les clotures futures
//----qui entraîneraient un retournement de la Hull
//

SI RANGHISTO>=FINHISTO-P2 ALORS
PREC=P3/100*HULL
PAS=P4/100/2*C

//----Rechercher la cloture future CF pour avoir un pic
//----sur la Hull à la période actuelle
//

SI HULL>HULL(1) ALORS
CF(0)=C
TANTQUE FLAG_PIC=0 FAIRE
CR(0)=CF
DELTA=100*(CF-C)/C

//Calculer la Hull future avec comme clôture future CF
MF_HULL=PONDERE(2*PONDERE(CR,P1/2)-PONDERE(CR,P1),RACINE(P1))

DIFF=HULL-MF_HULL
//Pic possible si
SI DIFF>0 et DIFF<PREC ALORS
DP=DELTA
CFP=CF
FLAG_PIC=1
Afficher "Pic à la prochaine période si clôture <= " & ctxt$(CF,2)
Afficher "% de variation par rapport à la clôture actuelle = " & ctxt$(DP,2) & "%"
BREAK
FINSI

SI HULL>=MF_HULL ALORS
CF=CF+PAS
SINON
SI HULL<MF_HULL ALORS
CF=CF-PAS
FINSI
FINSI

PAS=PAS/2
FINTANTQUE
FINSI

//----Rechercher la cloture future CF pour avoir un creux
//----sur la Hull à la période actuelle
//

SI HULL<HULL(1) ALORS
CF(0)=C
TANTQUE FLAG_CREUX=0 FAIRE
CR(0)=CF
DELTA=100*(CF-C)/C

//Calculer la Hull future avec comme clôture future CF
MF_HULL=PONDERE(2*PONDERE(CR,P1/2)-PONDERE(CR,P1),RACINE(P1))

DIFF=MF_HULL-HULL
//Creux possible si
SI DIFF<PREC et DIFF>0 ALORS
DC=DELTA
CFC=CF
FLAG_CREUX=1
Afficher "Creux à la prochaine période si clôture <= " & ctxt$(CF,2)
Afficher "% de variation par rapport à la clôture actuelle = " & ctxt$(DC,2) & "%"
BREAK
FINSI

SI HULL>=MF_HULL ALORS
CF=CF+PAS
SINON
SI HULL<MF_HULL ALORS
CF=CF-PAS
FINSI
FINSI

PAS=PAS/2
FINTANTQUE
FINSI

//Affichager les clôtures futures
//
SI FLAG_PIC=1 ALORS
PIC1=CFP
PIC2=CFP
FINSI

SI FLAG_CREUX=1 ALORS
CREUX1=CFC
CREUX2=CFC
FINSI

//----Réinitinialiser les valeurs des FLAGs et de la cloture future
//----pour le prochain calcul
//

FLAG_PIC=0
FLAG_CREUX=0
CR(0)=CLOTURE(-1)
FINSI

Le graphe Accor :
<center><a href='http://images.pro-at.com/forums-bourse/1106/17495_242229.gif' target='_blank' style='display:block; width:600px; border:2px dashed #888; padding:10px'><img src="http://images.pro-at.com/forums-bourse/1106/17495_242229.gif" alt='' width='600' height='450' />Cliquez pour agrandir</a></center>

**smallcaps90** · 25/11/2006, 11:20

Merci 29manu29.

Un problème subsiste encore chez moi que je ne m'explique pas.
En effet, je ne peux pas dépasser la valeur P2=43 pour Accor en daily. A partir de P2=44, GrapheAT Pro se bloque. J'ai choisi comme toi : P1=10, P3=0.01 et P4=25.
La valeur de P2 qui entraîne un blocage du programme chez moi, varie avec les actions traitées : blocage pour Alcatel par exemple à partir de P2=4, pour P2=5 avec Natixis...
Elle semble varier aussi selon P1 (valeur du recul de calcul de la Hull) : si je choisis P1=20, Natixis bloque dès P2=0. Bizarre...
Je n'ai pas vérifié si P3 et P4 avaient une incidence sur ce phénomène.

Utilisateurs de cette version du programme avez-vous le même problème?

Cordialement.

**sphinx** · 25/11/2006, 14:09

bonjour,
je ne trouve pas le nvi et le pvi. Peut on les poster avec les moyennes mobiles correspondantes?
pour les définitions : <a href='/ref.php?uri=http%3A%2F%2Fwww.walmaster.com%2Fmailing%2F050610%2Findex.asp' target="_blank">http://www.walmaster.com/mailing/050610/index.asp</a>

merci
sphinx

**smallcaps90** · 25/11/2006, 15:06

Bonjour sphinx,

Il me semble qu'ils sont dispos dans les exemples que MLOG livre avec GrapheAT Pro...
A toutes fins utiles je te les donne ci-dessous :

//====
// PVI
//====

//Positive Volume Index

Si RANGHISTO=1 Alors
PVI = 1000
STOP
FinSi

PVI = PVI(1)
Si Volume>Volume(1) Alors
PVI = PVI * (1 + (Cloture - Cloture(1)) / Cloture(1))
FinSi

MPVI=MOYENNE(PVI,252)
<center><img src='http://images.pro-at.com/forums-bourse/1106/3668_251601.gif' alt='' /></center>

//====
// NVI
//====

//Negative Volume Index

Si RANGHISTO=1 Alors
NVI = 1000
STOP
FinSi

NVI = NVI(1)
Si Volume<Volume(1) Alors
NVI = NVI * (1 + (Cloture - Cloture(1)) / Cloture(1))
FinSi

MNVI= MOYENNE(NVI,252)
<center><img src='http://images.pro-at.com/forums-bourse/1106/3668_251603.gif' alt='' /></center>

Exemple pour Accor :
<center><img src='http://images.pro-at.com/forums-bourse/1106/3668_251604_8412e3940ed253c96d37322e7ddfea38.gif' alt='' /></center>

Je reproduis un tableau que Norman Fosback donne dans son article de TASC d'avril 2003 :
<center><img src='http://images.pro-at.com/forums-bourse/1106/3668_251604.gif' alt='' /></center>
Cela vaut ce que cela vaut...

Cordialement.

**29manu29** · 25/11/2006, 15:39

Bonjour SMALLCAPS90

J'ai fait une petite correction à l'inicateur HULL_ANTICIP. Il y avait un problème lorsque la valeur future était située hors des limites calculées à partir de P4 (j'avais remarqué qu'il manquait certaines valeurs dans la 1ère version de l'indicateur que tu avais postée, cela était d'autant plus visible qe le nombre d'historiques utilsés pour le calcul de la HULL était grand). J'ai donc modifié le code pour corriger ce bug. J'ai également supprimé P4, j'utilise comme bornes de recherche systématiquement 0 pour la borne min et 2*C pour la borne max.

Cordialement

le code :

//=================
//HULL_ANTICIP_DICO
//=================

//Détermination de la clôture future
//qui induira un renversement de la Hull
//
//v3.2
//smallcaps90 le 05/07/2006
//v3.3
//29manu29 le 25/11/2006
//Amélioration de la vitesse de calcul,
//Recherche de la clôture future par dichotomie
//

//Paramètres à définir :
//
//P1 = Recul du calcul de la Hull
//P2 = Nb de périodes avant la FinHisto sur lesquelles on souhaite calculer et
// visualiser les clôtures futures qui entraîneraient des retournements de la Hull
//P3 = Limite de la différence entre HULL et MF_HULL pour arrêter la recherche (en % de la HULL)
//P4 = Paramètre de calcul des limites mini et maxi des clôtures futures (en %)
//

//----Récupérer les segments bicolorés de la Hull pour la tracer
//

HULL_V1=M_HULL_V1
HULL_V2=M_HULL_V2
HULL_R1=M_HULL_R1
HULL_R2=M_HULL_R2
HULL=M_HULL

C(0)=Cloture //simple changement de variables

//----Constitution des clotures retardées
//----pour calculer la Hull future
//

CR(0)=CLOTURE(-1)

//----Calculer sur les P2 dernières périodes les clotures futures
//----qui entraîneraient un retournement de la Hull
//

SI RANGHISTO>=FINHISTO-P2 ALORS
PREC=P3/100*HULL
PAS=C

//----Rechercher la cloture future CF pour avoir un pic
//----sur la Hull à la période actuelle
//

SI HULL>HULL(1) ALORS
CF(0)=0
ITER=0
TANTQUE FLAG_PIC=0 FAIRE
ITER=ITER+1
CR(0)=CF
DELTA=100*(CF-C)/C

//Calculer la Hull future avec comme clôture future CF
MF_HULL=PONDERE(2*PONDERE(CR,P1/2)-PONDERE(CR,P1),RACINE(P1))

DIFF=HULL-MF_HULL

//Pic impossible dans les limites de la recherche
SI ITER=1 et DIFF<0 ALORS
FLAG_PIC=-1
Afficher "Pic à la prochaine période hors limite !! "
Afficher ""
BREAK
FINSI

//Pic possible si
SI DIFF>=0 ALORS
SI DIFF<=PREC ALORS
DP=DELTA
CFP=CF
FLAG_PIC=1
Afficher "Pic à la prochaine période si clôture <= " & ctxt$(CF,2)
Afficher "% de variation par rapport à la clôture actuelle = " & ctxt$(DP,2) & "%"
Afficher ""
BREAK
FINSI
FINSI

SI HULL>=MF_HULL ALORS
CF=CF+PAS
SINON
SI HULL<MF_HULL ALORS
CF=CF-PAS
FINSI
FINSI

PAS=PAS/2
FINTANTQUE
FINSI

//----Rechercher la cloture future CF pour avoir un creux
//----sur la Hull à la période actuelle
//

SI HULL<HULL(1) ALORS
CF(0)=C+PAS
ITER=0
TANTQUE FLAG_CREUX=0 FAIRE
ITER=ITER+1
CR(0)=CF
DELTA=100*(CF-C)/C

//Calculer la Hull future avec comme clôture future CF
MF_HULL=PONDERE(2*PONDERE(CR,P1/2)-PONDERE(CR,P1),RACINE(P1))

DIFF=MF_HULL-HULL

//Creux impossible dans les limites de la recherche
SI ITER=1 et DIFF<0 ALORS
FLAG_CREUX=-1
Afficher "Creux à la prochaine période hors limite !! "
Afficher ""
BREAK
FINSI

//Creux possible si
SI DIFF>=0 ALORS
SI DIFF<=PREC ALORS
DC=DELTA
CFC=CF
FLAG_CREUX=1
Afficher "Creux à la prochaine période si clôture <= " & ctxt$(CF,2)
Afficher "% de variation par rapport à la clôture actuelle = " & ctxt$(DC,2) & "%"
Afficher ""
BREAK
FINSI
FINSI

SI HULL>=MF_HULL ALORS
CF=CF+PAS
SINON
SI HULL<MF_HULL ALORS
CF=CF-PAS
FINSI
FINSI

PAS=PAS/2
FINTANTQUE
FINSI

//Affichager les clôtures futures
//
SI FLAG_PIC=1 ALORS
PIC1=CFP
PIC2=CFP
FINSI

SI FLAG_CREUX=1 ALORS
CREUX1=CFC
CREUX2=CFC
FINSI

//----Réinitinialiser les valeurs des FLAGs et de la cloture future
//----pour le prochain calcul
//

FLAG_PIC=0
FLAG_CREUX=0
CR(0)=CLOTURE(-1)
FINSI

**smallcaps90** · 25/11/2006, 16:41

Re 29manu29,

Oui c'est vrai que j'avais limité les bornes de l'espace de recherche dans la méthode par itération. Le pb que tu soulèves est réel.
J'avais envisagé de limiter, au début de cette étude, le nombre de clôtures futures calculées à quelques unes, disons 2 maxi, car en fait c'est la toute dernière qu'il est utile de situer par rapport à la Hull. Ensuite j'ai étendu le nombre de périodes prises en compte en vue d'effectuer des statistiques sur une partie non limitée de l'historique...sans modifier le code des itérations.
Lorsqu'on ne s'intéresse qu'à la dernière clôture future calculée pour qu'il y ait pic ou creux sur la Hull, le bénéfice en temps de calcul que l'on peut tirer de la dichotomie est négligeable devant l'itération pure.

Je reviens à ta dernière version du programme. Celle-ci bloque toujours ici sur Accor en daily avec P1=18, P2=100 et P3=0.01, alors qu'il ne bloque pas pour P1=17...
As-tu le même pb chez toi?

Cordialement.

**29manu29** · 25/11/2006, 17:03

Re SMALLCAPS90

Je viens d'essayé sur ACCOR en daily (jusqu'au 17/11/06) avec les paramétres que tu m'a indiqués, je n'ai pas de bloquage pour P1 = 18.
Je ferai d'autres tests, je te tiens au courant.

Cordialement

**sphinx** · 25/11/2006, 18:50

merci Smallcaps
cordialement
Sphinx

**michka** · 17/12/2006, 20:06

Bonsoir

J’ai quelques soucis avec les règles statistiques semaine.

J ‘ai créé un indicateur qui prend la valeur 10 lorsque certains critères sur les Bollinger le MACD et les volumes sont respectées.
Dans une règle statistiques de l’onglet semaine, je mets le programme suivant :
Select=0
Pour 10 cours
Si ind_brm.ind_brm=10 alors selec =1
Finpour
Si selec=1 alors selection

Ind_brm.ind_brm représente l’indicateur avec sa courbe.
Lorsque j’exécute la stat je n’ai pas de valeur de sélectionnée, alors que je le visualise sur la courbe. Si je mets la règle dans l’onglet jour cela fonctionne.

J’ai refait un indicateur plus simple sur les volumes, et je constate que cette fois ci , il sélection des valeurs qui ne réponde pas aux critères.

Avez vous rencontré ce type de problème ?
Y a t-il une solution de contournement ?

Merci pour les réponses
Michka

**smallcaps90** · 18/12/2006, 07:50

Bonjour Michka,

Bizarre en effet. Je n'ai jamais eu ce problème.
J'ai encore vérifié en faisant passer à l'instant une de mes stats, qui fonctionne bien, de l'onglet Jour à l'onglet Semaine, que cela donne bien les résultats attendus.
Peux-tu poster ton indic, ou à défaut me l'envoyer en message PV si tu préfères, afin que je regarde ce qui pourrait bien créer les problèmes que tu rencontres?

Cordialement.

**michka** · 20/12/2006, 20:12

Bonsoir SmallCaps

Pour faire plus simple je poste le programme sur les volumes

L'indicateur
//indicateur de volume
//10 fois le volume moyen
si volume>moyenne(volume,150)*10 alors vol_f=10
si moyenne(volume,3)>moyenne(volume,150)*5 alors vol_f=10

La règle stat
selec=0
pour 10 cours
si vol_f.vol_f=10 alors selec=1
finpour
si selec=1 alors selection

Le groupe etudié 
Acteos
Arbel
Euro Ressources
Itesoft
Keyrus
Natexis

Lorsque je fais la stat sur l'onglet jour il me donne comme valeur
Euro Ressources et Natexis, ce qui est correct par rapport à la visualisation de l'indicateur. Mais quand je passe la stat dans l'onglet semaine, il me donne
Acteos, Euro Ressources, Itesoft et Natexis.
Acteos et Itesoft ne devraient pas faire partie de la liste car l'indicateur n'est pas à 10 sur le graphe.

Je ne comprend pas ce qui ce passe. Merci de voir si tu as le même problème.
Cordialement

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire