TTM Squeeze

[jmes]

La lecture du livre de John Carter " Maitriser le trade " fait réference à un indicateur TTM Squeeze ; mélange de Bandes de Bollinger , de canaux de Keltner et de momentum .

Cet indicateur existerait dans TradeStation et eSignal ??

Un Analyste Technique programmeur pourrait il mettre la formule sur le site .

Remerciements anticipés .

[mesocarpe]

C'est à vendre sur son site www.tradethemarkets.com

[jmes]

merci beaucoup .

[zer0]

google est ton ami.
vous nous direz si ca correspond bien a l'indicateur que vous cherchez

Inputs: {------------------------------------------------}
Price(Close),
Length(20), { Length for Average True Range (ATR) & Std. Deviation (SD) Calcs }
nK(1.5), { Keltner Channel ATRs from Average }
nBB(2), { Bollinger Band Std. Devs. from Average }
AlertLine( 1 ), { BBS_Index level at which to issue alerts }
NormalColor( Red ), { Normal color for BBS_Ind }
AlertlColor( Blue ); { Color for BBS_Ind below alert line }


Variables: {---------------------------------------------}
ATR(0), { Average True Range }
SDev(0), { Standard Deviation }
BBS_Ind(0), { Bollinger Band Squeeze Indicator }
alertTextID(-1),
Denom(0),
LHMult(0);



if ( barnumber=1 ) then
Begin
If minmove <> 0 then
LHMult = pricescale/minmove;
end;

if barnumber = 1 and alertTextID = -1 then
alertTextID = Text_New(date,time,0,"dummy");

{-- Calculate BB Squeeze Indicator ----------------------}
ATR = AvgTrueRange(Length);
SDev = StandardDev(Price, Length, 1);

Denom = (nK*ATR);
If Denom <> 0 then
BBS_Ind = (nBB * SDev) /Denom;

If BBS_Ind < Alertline then
SetPlotColor(1, NormalColor)
else
SetPlotColor(1, AlertlColor);

{-- Plot the Index & Alert Line -------------------------}
Plot1(0, "BBS_Ind");

{-- Plot delta of price from Donchian mid line ----------}
value2 = LinearRegValue(price-((Highest(H, Length)+Lowest(L, Length))/2
+ xAverage(c,Length))/2,Length,0);

var:color(0); color = yellow;

if value2 > 0 then
if value2 > value2[1] then
color = green
else
color = darkgreen;

if value2 < 0 then
if value2 < value2[1] then color = red
else
color = darkred;

Plot3(value2*LHMult, "NickmNxtMove", color);
{plot3(value2,"BB Squeeze",color);}

{-- Issue Alert when the Squeeze is On ------------------}
if BBS_Ind crosses below AlertLine
and Text_GetTime(alertTextID) <> time then
begin
text_setLocation(alertTextID, date, time, 0);
Alert("BB Squeeze Alert");
end;

{-- Issue Alert when the Squeeze Releases ---------------}
if BBS_Ind crosses above AlertLine
and Text_GetTime(alertTextID) <> time then
begin
text_setLocation(alertTextID, date, time, 0);
Alert("BB Squeeze Is Over");
end;

[jmes]

avec tous mes remerciements .
il va falloir que je me fasse aider pour " ecrire " cela
dans Metastock ...

[tonkin]

Est-il possible de le mettre en place sur Prorealtime ?

Merci de vos avis

Guillaume

[Arnaudbzh]

Bonjour,

Je regarde ce code pour Pro Real Time dès que je trouve un peu de temps,
il n'a pas l'air bien méchant.

Bonne journée
Arnaud

[christian899]

Merci d'avance

[Arnaudbzh]

Bonjour,

Je me suis donc intéressé au code proposé par Zer0 trouvé sur « Google est ton ami »,
tel que décrit par John CARTER dans son bouquin.
On trouvera donc 2 codes :
BB SQUEEZE, qui affiche les bandes de bollingers et le canal de Keltner sur les prix.
N’oubliez pas de rentrer les variables P1, P2, P3 avec leurs valeurs respectives.
Le code contient déjà les couleurs rouge et bleue (fonction RETURN coloured by)

TTM SQUEEZE, pour le fameux indicateur de John Carter.
J’ai retiré du code tout ce qui concerne la gestion des couleurs, je ne sais pas si c’est
réalisable avec PRT de cette manière là. Pas non plus de message d’alerte.
Pas de variables d’optimisation dans ce code, mais rien ne vous empêche de les rajouter,
comme dans le précédent code.
A vous de configurer l’indicateur INDIC en point avec les couleurs qui vont bien.
Et l’histogramme, en histogramme évidement.

J’espère avoir été clair pour tout le monde, mais je compte sur vous pour bidouiller
et cliquer partout ou bon vous semble. Avec les manuels PRT, çà marche mieux aussi.

--------------------------------------------------------------------------------------

REM TTM SQUEZZE by John CARTER
REM ArnaudBZH - Forum PRO-AT.COM

Price = Close

REM Length for Average True Range (ATR) & Std. Deviation (SD) Calculations
Length = 20

REM Keltner Channel ATRs from Average
nK = 1.5

REM Bollinger Band Std. Devs. from Average
nBB = 2

REM BBS_Index level at which to issue alerts
AlertLine = 1


REM Calculate BB Squeeze Indicator
monATR = AverageTrueRange[Length](Price)
SDev = STD[Length](Price)

Denom = (nK * monATR)
IF Denom <> 0 THEN
BBSInd = (nBB * SDev) / Denom
ENDIF

IF BBSInd < Alertline THEN
Indic = -1
ELSE
Indic = 1
ENDIF

REM Plot delta of price from Donchian mid line
Histo = LinearRegression[Length] (price - ((Highest[Length](High) + Lowest[Length](Low))/2 + ExponentialAverage[Length](close))/2 )

RETURN Histo as "Histogramme", Indic coloured by Indic as "Indic"


-------------------------------------------------------------------------------------------------



REM BB SQUEEZE
REM Bandes de Kelter et Bollinger
REM ArnaudBZH - Forum PRO-AT
REM Variable P1=20
REM Variable P2=2
REM Variable P3=1.5

REM Bandes de Bollinger
EP=STD[P1](close)
MB=average[P1](close)
UB=MB + P2 * EP
LB=MB - P2 * EP

REM Bandes de Keltner
avg= AVERAGE[P1](close)
shift= P3* AVERAGETRUERANGE[P1](close)

UK=avg+shift
LK=avg-shift

RETURN UB coloured(0,0,255) as "Bande Bollinger Sup" , LB coloured(0,0,255) as "Bande Bollinger Inf" , UK coloured(255,0,0) as "Bande Keltner Sup" , LK coloured(255,0,0) as "Bande Keltner Inf"

[Arnaudbzh]

[tonkin]

Merci beaucoup à toi Arnaud

[Fabrice17]

bonjour,

les variables ont une valeur en priorité ?
puis je savoir leur variation ?
merci

[swig]

Bonjour,

En pleinne lecture du livre de John F. Carter , je trouve tres interressant les canaux de Keltner.
Question :
Le scrip peut etre integre sur la plate forme MétaTrader
merci de votre réponse.
Bonne journée

[learn]

Bonjour
je suis interessé par le ttm squeeze

j ai essaye de le mettre sur prorealtime
sauf que je ne sais pas ce qu il faut mettre dans

P1

P2

P3


pouvez m aider car je sais pas ce qu il faut mettre dans


la case restriction

valeur minimal
valeur maximale

intervalle



j ai vraiment besoin de ces parametres



merci

[Arnaudbzh]

Bonjour learn,

première chose, as-tu les manuels Pro Real Time ?
Si ce n'est pas le cas, direction le site.

Deuxième chose, comment est construit l'indicateur ??
Eric Lefort dit encore et toujours qu'il faut comprendre
comment un indicateur est construit pour pouvoir l'utiliser.
Sinon c'est la meilleure façon de se planter.

La variable P1 est utilisée ici:
EP=STD[P1](close)
on calcule l'écart type sur un certain nombre de barres.
Est-ce que ce nombre de barre peut être égal à 0 ou négatif ??
Non. Tu as donc la restriction.
Sur combien de périodes veux tu calculer P1 ? 10, 20, 30, 50,
c'est toi qui décide. Tu veux faire varier P1 une période
après une période, ou 2 par 2 ?? 10,11,12 ou 10,12,14 ??

Au début du code, j'ai mis les lignes suivantes:
REM Variable P1=20
REM Variable P2=2
REM Variable P3=1.5

A quoi sert la fonction REM ?? A rien !! C'est juste pour
mettre du texte. Mais j'ai bien du y voir un intérêt...

Pareil pour P2. C'est le nombre d'écart type des bandes
de bollingers. Est-ce qu'un écart type peut être négatif ??
Habituellement on met 2, mais rien ne t'empèche de mettre 1.8
et de le faire varier de 0.2 en 0.2, plutôt que 0.1.

Voilà, tu as presque toutes les réponses.

Est-ce que tu crois les grands intervenants de ce site n'ont pas
beaucoup travaillé pour comprendre toute la finesse des outils
qu'ils utilisent ?? Pour ma part j'ai revu un paquet de math,
à commencer par la formule math du calcul d'une moyenne exponentielle,
alors qu'on la trouve tout cuit dans Pro real Time.

Si tu te pose encore des questions d'ordre mathématique (qu'est-ce
qu'un écart type, Google sera toujours ton ami, Wikipedia aussi.


Bonne journée
Arnaud