[Graphe AT PRo : programmation]

**smallcaps90** · 27/12/2005, 10:32

Pour l'ATD truc?
Deux indicateurs ont été programmés conformément (on l'espère) aux prescriptions du maître : le SAR et le STOCH.
Pas mal de choses ont été écrites sur le SAR (entre-autre le dernier message sur le sujet date du 02/11/2004, page 46 ) et sur le STOCH (message du 13/09/2004, page 41).
On peut trouver aussi des choses sur la volatilité à la Bollinger et sur quelques statistiques que tu pourras explorer à partir du tableau de longway.

**asynergy** · 30/12/2005, 14:02

Bonjour SmallCaps
Utilisant Xtrade pour les graphes en cassure 3 lignes, je découvre que tu avais déjà proposé la solution sur Graphe AtPro
La lisibilité est meilleure sur le graphe que tu avais publié page 50.
Pourrais-tu publier le programme concernant cette manière de voir ?
Merci par avance de ta réponse
<center><img src='http://images.pro-at.com/200512/b/0cassur3l.gif' alt='' /></center>

**boursicoton** · 30/12/2005, 14:52

j'ai reçu le nison, bigrement interessant ce livre.
smallcaps, kagi et renko en visu ? dans tes cartons, si oui....ahhhhhh, si non, ce n'est pas grave, j'ai tellement de choses à apprendre et à essayer.
petites questions pour tout le monde : je vois aaroon, andrews, des livres de reference là dessus ?
sur la partie gestion de portefeuille : un moyen pour mettre en application les 2 % et les 6% d'elder ? de facon automatique.
bon reveillon à tous
2006 l'année des pv débute !

**smallcaps90** · 30/12/2005, 18:05

Bonsoir Asynergy,
Comme je l'indiquais dans le post de la page 50 que tu cites, j'obtenais ce graphe à partir d'une moulinette Excel qui récupérait le fichier texte de la valeur (Danone en l'occurence) et créait un autre fichier texte conforme à la représentation "Three Line Break" que GrapheAT Pro représentait comme une valeur quelconque (danone essai).
Compte-tenu du peu d'intérêt qu'avait eu cette approche je n'ai rien conservé sur cette moulinette Excel.

**boursicoton** · 30/12/2005, 22:22

une variante du bull power, idem pour bear
// Bull Power

ema = EXPOSUIV(ema,Cloture,P1)
BULLPOWERA(0) = Haut-ema

si (bullpowera(0)>0) et(bullpowera(1)>0) et (bullpowera(0)< bullpowera(1))
alors bullpowerb=bullpowera
sinon
bullpowerb=0
bullpower=bullpowera
finsi

on crée bullpower en courbe histo de couleur au choix
et à chaque fois que le signal est bon, hop changement de couleur et achat !
<img src='http://www.pro-at.com/style/images/icones/icon_smile.gif' border='0' alt='' title='' align='middle' /> vrai ou faux ?
merci à tous
faux.....il manque un test pour savir si c'est le premier changement
à suivre <img src='http://www.pro-at.com/style/images/icones/icon_smile_tongue.gif' border='0' alt='' title='' align='middle' />
suite......
// Bull Power

ema = EXPOSUIV(ema,Cloture,P1)
BULLPOWERA(0) = Haut-ema
si (bullpowera(0)<0)
alors
i=0
finsi
si (bullpowera(0)>0) et(bullpowera(1)>0) et (bullpowera(0)< bullpowera(1)) et i=0
alors
bullpowerb=bullpowera
i=1

Sinon
bullpowerb(0)=0
bullpower=bullpowera

Finsi
<img src='http://www.pro-at.com/style/images/icones/icon_smile_evil.gif' border='0' alt='' title='' align='middle' /> alors ? ce coup-là est-il le bon ?
j''oubliais : une courbe2 appelé bullpowerb avec histogramme et couleur differente et hop un signal de vente !
pour le bearpower,idem creer une courbe bearpowerb de couleur differente et
// Bear Power

ema = EXPOSUIV(ema,Cloture,P1)
BEARPOWERA(0) = Bas-ema

si (bearpowera(0)>0)
alors
i=0
finsi
si (bearpowera(0)<0) et(bearpowera(1)<0) et (bearpowera(0)> bearpowera(1)) et i=0
alors
bearpowerb=bearpowera
i=1

Sinon
bearpowerb(0)=0
bearpower=bearpowera

Finsi

<img src='http://www.pro-at.com/style/images/icones/icon_smile_question.gif' border='0' alt='' title='' align='middle' /><img src='http://www.pro-at.com/style/images/icones/icon_smile_question.gif' border='0' alt='' title='' align='middle' /><img src='http://www.pro-at.com/style/images/icones/icon_smile_question.gif' border='0' alt='' title='' align='middle' />

**boursicoton** · 31/12/2005, 16:31

pour rickenbroc
j'ai de la peine avec l'impulsion, trop de points
j'ai donc legerement modifié ton indicateur :
// Impulse System selon Alexander Elder
// p 157 de Come Into My Trading Room
// Principe:
// si EMA(13) et MACD histo sont en phase alors signal
// la fin du signal indique de sortir de ses positions
// Très utile pour entrer au bon moment en utilisant le Triple Screen
// en n'allant pas contre l'Impulse.

//EMA P1
EMA = EXPOSUIV(EMA,cloture,P1)

SI ((EMA>EMA(1)) ET (RMACDHISTO.RMACDHISTO>RMACDHISTO.RMACDHISTO(1))) et i=0 ALORS
IMPULSEV = Bas * 0.99
i=1
SINON
SI ((EMA<EMA(1)) ET (RMACDHISTO.RMACDHISTO<RMACDHISTO.RMACDHISTO(1))) et i=1 ALORS
IMPULSEA = Haut * 1.01
i=0
SINON
IMPULSE = (Haut+Bas)/2
FINSI
FINSI
et mis deux couleurs differentes pour impulsea et impulsev qui remplace impulse
<img src='http://www.pro-at.com/style/images/icones/icon_smile_tongue.gif' border='0' alt='' title='' align='middle' />
je suis dans le vrai ou dans l'erreur <img src='http://www.pro-at.com/style/images/icones/icon_smile_question.gif' border='0' alt='' title='' align='middle' />

**smallcaps90** · 04/01/2006, 15:58

Bonjour,

J'ai modifié et complèté le programme du ZigZag et des Andrew's pitchfork des pages 34 et 53 à la demande de FOKI.
La nouvelle version intègre une option supplémentaire : celle de pouvoir tracer un zigzag et les fouchettes d'Andrew entre les hauts et les bas des cours. Les options présentes précédemment subsistent : on peut toujours demander des tracés entre les cours d'ouverture, entre les hauts, entre les bas ou entre les clôtures.
Le programme calcule toujours la position du retour éventuel des cours sur la ligne médiane comme l'avait demandé Asynergy page 53. Le repérage s'effectue à l'aide d'un point lorsque celui-ci est situé avant la FINHISTO et par l'intermédiaire d'un message dans la fenêtre d'affichage dans le cas contraire.
Petite modification : les rôles de 2 paramètres P1 et P2 ont été inversés par rapport à la version précédente de la page 53. C'est le paramètre P1 qui sélectionne maintenant les limites choisies sur les cours et le paramètre P2, intégré directement en %, qui donne la valeur du retracement choisi pour le zigzag.

Programme :
<pre>//============
//ZZ_PITCHFORK
//============

//ZigZag et Andrew's pitchfork
//V 3.0
//04/01/2006
//

//=========================
//PARAMETRES ET VARIABLES :
//=========================
//P1 = 0 zigzag sur les ouvertures
//P1 = 1 zigzag sur les bas
//P1 = 2 zigzag sur les hauts
//P1 = 3 zigzag sur les clôtures
//P1 = 4 zigzag sur les hauts/bas
//P2 est la valeur du retracement du zigzag en %
//DONNEE_PIC = contient les valeurs des cours suivant la valeur choisie pour P1
//DONNEE_CREUX idem
//TENDANCE = 1 si zag (historisée)
//TENDANCE = -1 si zig
//MAXI = valeur d'un sommet(non historisée)
//DATEMAXI = date (RANGHISTO) du pic (non historisée)
//MINI = valeur d'un creux (non historisée)
//DATEMINI = date (RANGHISTO) d'un creux (non historisée)
//DELTA = % entre la CLOTURE courante et le MAXI (ou le MINI) actuel (non historisée)
//PENTE_ZAG = pente de chaque segment montant du zigzag (non historisée)
//PENTE_ZIG = pente de chaque segment descendant du zigzag (non historisée)
//ZIG = droite descendante du zigzag, tracée en format SEGMENTS (historisée)
//ZAG = droite montante du zigzag, tracée en format SEGMENTS (historisée)
//MAXI_PRECEDENT = avant-dernier MAXI trouvé (non historisée)
//DATEMAXI_PRECEDENT = sa date (non historisée)
//MINI_PRECEDENT = avant-dernier MINI trouvé (non historisée)
//DATEMINI_PRECEDENT = sa date (non historisée)
//TRACE_ZZ, flag =1 si on termine le zigzag sur un zag, =0 sur un zig (non historisée)
//DATE_MILIEU = RANGHISTO du milieu du zag ou du zig terminal (non historisée)
//ORDONNEE_MILIEU = ordonnée de ce point (non historisée)
//PENTE_FA = pente des segments de la fourche d'Andrews (non historisée)
//Y = ordonnées des points de la ligne médiane de la fourche (historisée)
//YSUP = ordonnées des points de la ligne supérieure de la fourche (historisée)
//YINF = ordonnées des points de la ligne inférieure de la fourche (historisée)
//DERNIER_ZZ = dernier segment du zigzag sur lequel s'appuie la fourche (historisée)
//F_LIM = limite droite du retour probable des cours sur la médiane

//===========================
//1- SELECTIONNER LES DONNEES
//===========================
DONNEE_PIC(0)=OUVERTURE*(P1=0) +
BAS*(P1=1) +
HAUT*(P1=2 OU P1=4) +
CLOTURE*(P1=3)
DONNEE_CREUX(0)=OUVERTURE*(P1=0) +
BAS*(P1=1 OU P1=4) +
HAUT*(P1=2) +
CLOTURE*(P1=3)

//=======================================
//2- TRAITER LE PREMIER COURS/INITIALISER
//=======================================
SI RANGHISTO=1 ALORS
TENDANCE(0)=0
MAXI=DONNEE_PIC
MINI=DONNEE_CREUX
DATEMAXI=RANGHISTO
DATEMINI=RANGHISTO
FINSI

//=======================================
//3- ASSURER LA CONTINUITE DE LA TENDANCE
//=======================================
TENDANCE=TENDANCE(1)

//==================================
//4- DETERMINER LA TENDANCE INITIALE
//==================================
SI TENDANCE=0 ALORS
SI DONNEE_PIC>MINI*(1+P2%) ALORS
MAXI=DONNEE_PIC
DATEMAXI=RANGHISTO
TENDANCE=1
FINSI
SI DONNEE_CREUX<MAXI*(1-P2%) ALORS
MINI=DONNEE_CREUX
DATEMINI=RANGHISTO
TENDANCE=-1
FINSI
Afficher "tendance init = " & ctxt$(tendance,0)
Afficher "pos= " & ctxt$(ranghisto,0)
FINSI

//=======================================================
//5- EXAMINER LA TENDANCE HAUSSIERE
// PASSER EN TENDANCE BAISSIERE SI CONDITION SATISFAITE
// ALORS TRACER LE ZAG
//=======================================================
SI TENDANCE=1 ALORS
SI DONNEE_PIC>=MAXI ALORS
MAXI=DONNEE_PIC
DATEMAXI=RANGHISTO
SINON
SI DONNEE_CREUX<MAXI*(1-P2%) ALORS
TENDANCE=-1
//Tracer le segment montant
PENTE_ZAG=(MAXI-MINI)/(DATEMAXI-DATEMINI)
POUR (RANGHISTO-DATEMINI+1) COURS
ZAG=PENTE_ZAG*(RANGPOUR-1)+MINI
SI RANGPOUR>(DATEMAXI-DATEMINI) ALORS BREAK
FINPOUR

TRACE_ZZ = 1

//Mettre à jour
MINI_PRECEDENT=MINI
DATEMINI_PRECEDENT=DATEMINI
MINI=DONNEE_CREUX
DATEMINI=RANGHISTO
FINSI
FINSI
FINSI

//=======================================================
//6- EXAMINER LA TENDANCE BAISSIERE
// PASSER EN TENDANCE HAUSSIERE SI CONDITION SATISFAITE
// ALORS TRACER LE ZIG
//=======================================================
SI TENDANCE=-1
ALORS
SI DONNEE_CREUX<=MINI ALORS
MINI=DONNEE_CREUX
DATEMINI=RANGHISTO
SINON
SI DONNEE_PIC>MINI*(1+P2%) ALORS

SI RANGHISTO>=FINHISTO-40 ALORS
Afficher "ici"
Afficher "DONNEE_PIC = " & ctxt$(DONNEE_PIC,2)
Afficher "MINI*(1+P2%) = " & ctxt$(MINI*(1+P2%),2)
FINSI

TENDANCE=1
//Tracer le segment descendant
PENTE_ZIG=(MINI-MAXI)/(DATEMINI-DATEMAXI)
POUR (RANGHISTO-DATEMAXI+1) COURS
ZIG=PENTE_ZIG*(RANGPOUR-1)+MAXI
SI RANGPOUR>(DATEMINI-DATEMAXI) ALORS BREAK
FINPOUR

TRACE_ZZ = 0

//Mettre à jour
MAXI_PRECEDENT=MAXI
DATEMAXI_PRECEDENT=DATEMAXI
MAXI=DONNEE_PIC
DATEMAXI=RANGHISTO
FINSI
FINSI
FINSI

//Dernier zig ou dernier zag éventuel
SI RANGHISTO=FINHISTO ALORS
SI TENDANCE=1 ET TRACE_ZZ=0 ALORS
PENTE_ZAG=(MAXI-MINI)/(DATEMAXI-DATEMINI)
POUR (RANGHISTO-DATEMINI+1) COURS
ZAG=PENTE_ZAG*(RANGPOUR-1)+MINI
SI RANGPOUR>(DATEMAXI-DATEMINI) ALORS BREAK
FINPOUR
FINSI
SI TENDANCE=-1 ET TRACE_ZZ=1 ALORS
PENTE_ZIG=(MINI-MAXI)/(DATEMINI-DATEMAXI)
POUR (RANGHISTO-DATEMAXI+1) COURS
ZIG=PENTE_ZIG*(RANGPOUR-1)+MAXI
SI RANGPOUR>(DATEMINI-DATEMAXI) ALORS BREAK
FINPOUR
FINSI
FINSI

//=================================================
//7- TRACER LA FOURCHE DE ANDREW
// SUR L'AVANT-DERNIER ZAG OU L'AVANT-DERNIER ZIG
//=================================================
SI RANGHISTO=FINHISTO ALORS
SI TRACE_ZZ=1 ALORS //On termine le zigzag sur un zag
POUR (FINHISTO-DATEMINI_PRECEDENT+1) COURS
DERNIER_ZZ(0)=PENTE_ZAG*(RANGPOUR-1)+MINI_PRECEDENT
SI RANGPOUR>(DATEMAXI-DATEMINI_PRECEDENT) ALORS BREAK
FINPOUR

DATE_MILIEU = (DATEMINI_PRECEDENT+DATEMAXI)/2
ORDONNEE_MILIEU = (MINI_PRECEDENT+MAXI)/2
PENTE_FA = (ORDONNEE_MILIEU-MAXI_PRECEDENT)/(DATE_MILIEU-DATEMAXI_PRECEDENT)

POUR (FINHISTO-DATEMAXI_PRECEDENT+1) COURS
Y=PENTE_FA*(RANGPOUR-1)+MAXI_PRECEDENT
FINPOUR

POUR (FINHISTO-DATEMAXI+1) COURS
YSUP=PENTE_FA*(RANGPOUR-1)+MAXI
FINPOUR

POUR (FINHISTO-DATEMINI_PRECEDENT+1) COURS
YINF=PENTE_FA*(RANGPOUR-1)+MINI_PRECEDENT
FINPOUR

//Recherche de la limite de retour du cours sur la médiane
L1=DATEMINI_PRECEDENT-DATEMAXI_PRECEDENT
L2=DATEMAXI-DATEMINI_PRECEDENT
LIM=DATEMAXI+MAXVAL(L1,L2)
SI LIM<=FINHISTO ALORS
F_LIM(FINHISTO-LIM)= Y(FINHISTO-LIM)
SINON
Afficher "Retour sur la ligne médiane avant " & CTXT$(LIM-FINHISTO,0) & " périodes"
Afficher "au delà de la finhisto"
FINSI
SINON //On termine le zigzag sur un zig
POUR (FINHISTO-DATEMAXI_PRECEDENT+1) COURS
DERNIER_ZZ(0)=PENTE_ZIG*(RANGPOUR-1)+MAXI_PRECEDENT
SI RANGPOUR>(DATEMINI-DATEMAXI_PRECEDENT) ALORS BREAK
FINPOUR

DATE_MILIEU = (DATEMAXI_PRECEDENT+DATEMINI)/2
ORDONNEE_MILIEU = (MAXI_PRECEDENT+MINI)/2
PENTE_FA = (ORDONNEE_MILIEU-MINI_PRECEDENT)/(DATE_MILIEU-DATEMINI_PRECEDENT)

POUR (FINHISTO-DATEMINI_PRECEDENT+1) COURS
Y=PENTE_FA*(RANGPOUR-1)+MINI_PRECEDENT
FINPOUR

POUR (FINHISTO-DATEMAXI_PRECEDENT+1) COURS
YSUP=PENTE_FA*(RANGPOUR-1)+MAXI_PRECEDENT
FINPOUR

POUR (FINHISTO-DATEMINI+1) COURS
YINF=PENTE_FA*(RANGPOUR-1)+MINI
FINPOUR

//Recherche de la limite de retour du cours sur la médiane
L1=DATEMAXI_PRECEDENT-DATEMINI_PRECEDENT
L2=DATEMINI-DATEMAXI_PRECEDENT
LIM=DATEMINI+MAXVAL(L1,L2)
SI LIM<=FINHISTO ALORS
F_LIM(FINHISTO-LIM)= Y(FINHISTO-LIM)
SINON
//Voir les messages suivants dans la fenêtre d'affichage
Afficher "Retour sur la ligne médiane avant " & CTXT$(LIM-FINHISTO,0) & " périodes"
Afficher "au delà de la finhisto"
FINSI
FINSI
FINSI</pre>

Propriétés :
<center><img src='http://images.pro-at.com/200601/b/pitchfork_proprietes.gif' alt='' /></center>
Exemple de tracé d'un zigzag avec P1=4 (entre hauts et bas) et P2=5% :
<center><img src='http://images.pro-at.com/200601/b/zigzag2.gif' alt='' /></center>
Tracé de la fourchette :
<center><img src='http://images.pro-at.com/200601/b/pitchfork.gif' alt='' /></center>

Bonne et heureuse année 2006 à toutes et à tous.
Cordialement.

**FOKI** · 04/01/2006, 16:20

Bonjour Smallcaps

Tous mes voeux pour cette année 2006 <img src='http://www.pro-at.com/style/images/icones/icon_smile_wink.gif' border='0' alt='' title='' align='middle' />.

Merci encore pour ce programme sur les fourchettes dont le tracé me semble avoir fière allure .... <img src='http://www.pro-at.com/style/images/icones/Applaudissements03.gif' border='0' alt='' title='' align='middle' />

FOKI

**smallcaps90** · 06/01/2006, 16:07

Bonsoir FOKI,

J'ai résolu ton pb de support/résistance un peu "spécial".
Je rappelle les éléments de ton cahier des charges pour les amis qui seraient intéressés.
Tu veux voir apparaître une résistance et un support horizontaux sur les cours. La résistance doit passer par le plus haut des P2 dernières périodes (P2 à définir). Le support doit passer par le plus bas de ces P2 périodes.
Contrainte : si le cours de la période actuelle faisait un plus haut (ou un plus bas), il faudrait attendre qu'un creux (ou qu'un pic) se produise dans les périodes suivantes pour le valider (il faudrait donc ne pas en tenir compte à la période actuelle).

Programme :
<pre>//====
//SRH
//====

//Détermination du plus haut et du plus bas des cours sur P2 périodes
//le 06/01/2006
//V 1.0
//

SI RANGHISTO=FINHISTO ALORS

//Explorer les P2 dernières périodes de l'historique
I=P2
TANTQUE I>=0 FAIRE

//Chercher le plus haut et le plus bas des P1 périodes
//situées avant la période actuelle I
HG=Haut(I+1)
BG=Bas(I+1)
J=I+2
TANTQUE J<=I+P1 FAIRE
SI HAUT(J)>HG ALORS HG=HAUT(J)
SI BAS(J)<BG ALORS BG=BAS(J)
J=J+1
FINTANTQUE

//Chercher le plus haut et le plus bas des P1 périodes
//situées après de la période actuelle I
HD=HAUT(I-1)
BD=BAS(I-1)
K=I-2
TANTQUE K>=I-P1 FAIRE
SI HAUT(K)>HD ALORS HD=HAUT(K)
SI BAS(K)<BD ALORS BD=BAS(K)
K=K-1
FINTANTQUE

//Mémoriser le plus haut local s'il est valide
SI (HAUT(I)>=HG) ET (HAUT(I)>=HD) ALORS
H(I)=HAUT(I) //On les visualise sur les cours
FINSI

//Mémoriser le plus bas local s'il est valide
SI (BAS(I)<=BG) ET (BAS(I)<=BD)
ALORS
B(I)=BAS(I)
SINON
B(I)=100000
FINSI

I=I-1
FINTANTQUE

//Supprimer le dernier plus haut ou dernier plus bas non valide
i=0
TANTQUE I<=P2 FAIRE
SI H(I)<>0 ET B(I)=100000 ALORS
H(I)=0
BREAK
FINSI
SI H(I)=0 ET B(I)<>0 ALORS
B(I)=100000
BREAK
FINSI
I=I+1
FINTANTQUE

//Chercher le plus haut et le plus bas globaux
PH=MAX(H,P2)
PB=MIN(B,P2)
I=0
TANTQUE I<=P2 FAIRE
R(I)=PH
S(I)=PB
I=I+1
FINTANTQUE

FINSI</pre>

Propriétés :
<center><img src='http://images.pro-at.com/200601/b/proprietes_srh.gif' alt='' /></center>

Là encore j'utilise la méthode de Tom De Mark pour détecter les pics et les creux des cours.
Le paramètre P1 pris à 3 indique le nombre de barres explorées à gauche et à droite de la position étudiée pour valider un pic ou un creux.
Le paramètre P2 précise le nombre de barres prises en compte avant la FINHISTO.

Tu souhaitais également une stat qui puisse scanner une base pour afficher les valeurs dont la proximité à la résistance ou au support seraient < à une limite à préciser (paramètre PROX dans le programme ci-dessous).

Programme statistique :
<pre>//========
//PROX_SRH
//========

//Statistique de détermination de la proximité des cours
//par rapport aux support et résistance horizontales
//détectées par l'indic SRH
//le 06/01/2006
//

//Choisir le % de proximité
//
PROX = 2

//Calculs des distances en % du haut de la période courante à la résistance
//et du bas de la période courante au support
//
//
A = 100*(HAUT-SRH.R)/HAUT
B = 100*(BAS-SRH.S)/BAS

//1er cas : haut au-dessus de la résistance
//
SI A>0 et A<=PROX
ALORS
COLONNE1 = "Haut le plus proche de la résistance et au dessus à : " & ctxt$(A,2) & "%"
SELECTION
FINSI

//2ème cas : haut au-dessous de la résistance
//
SI A<0 ET B>0
ALORS
SI ABSOLU(A)<=PROX ET ABSOLU(A)<B
ALORS
COLONNE1 = "Haut le plus proche de la résistance et au dessous à : " & ctxt$(ABSOLU(A),2) & "%"
SELECTION
SINON
SI B<=PROX
ALORS
COLONNE1 = "Bas le plus proche du support et au dessus à : " & ctxt$(B,2) & "%"
SELECTION
FINSI
FINSI
FINSI

//3ème cas : bas au dessous du support
//
SI B<0 et ABSOLU(B)<=PROX
ALORS
COLONNE1 = "Bas le plus proche du support et au dessous à: " & ctxt$(ABSOLU(B),2) & "%"
SELECTION
FINSI</pre>

Propriétés de la stat :
<center><img src='http://images.pro-at.com/200601/b/proprietes_prox_srh.gif' alt='' /></center>

En date d'hier avec PROX=2% on obtient sur le CAC40 les résultats suivants :
Groupe : cac40 Date : 05/01/2006
Statistique de détermination de la proximité des cours
par rapport aux support et résistance horizontales

Bas le plus proche du support et au dessus à : 1,60% Casino Guichard
Haut le plus proche de la résistance et au dessous à : 0,14% Suez
Haut le plus proche de la résistance et au dessous à : 0,20% Dexia
Haut le plus proche de la résistance et au dessous à : 0,41% AGF
Haut le plus proche de la résistance et au dessous à : 0,62% Alcatel
Haut le plus proche de la résistance et au dessous à : 0,95% Pinault Printemps Redoute
Haut le plus proche de la résistance et au dessous à : 0,96% Thomson
Haut le plus proche de la résistance et au dessous à : 1,19% Air Liquide
Haut le plus proche de la résistance et au dessous à : 1,33% Pernod Ricard
Haut le plus proche de la résistance et au dessous à : 1,98% Vinci
Haut le plus proche de la résistance et au dessus à : 0,09% Societe Generale
Haut le plus proche de la résistance et au dessus à : 0,13% Lafarge
Haut le plus proche de la résistance et au dessus à : 0,25% STMicroelectronics
Haut le plus proche de la résistance et au dessus à : 0,41% Thales
Haut le plus proche de la résistance et au dessus à : 0,43% Publicis Group
Haut le plus proche de la résistance et au dessus à : 1,04% Veolia Environnement
Haut le plus proche de la résistance et au dessus à : 1,09% AXA
Haut le plus proche de la résistance et au dessus à : 1,19% Carrefour
Haut le plus proche de la résistance et au dessus à : 1,19% Credit agricole
Haut le plus proche de la résistance et au dessus à : 1,50% Lagardere
Haut le plus proche de la résistance et au dessus à : 1,66% Schneider

Un exemple, Schneider (le dernier de la liste ci-dessus) :
<center><img src='http://images.pro-at.com/200601/b/schneider_graphe.gif' alt='' /></center>

Cordialement.

**FOKI** · 06/01/2006, 17:21

Bonsoir Smallcaps

Je te remercie vivement, une fois de plus <img src='http://www.pro-at.com/style/images/icones/icon_smile_wink.gif' border='0' alt='' title='' align='middle' /> pour ce programme.

Quelques explications sur l'objet de ce programme un peu "Spécial" qui va peut être en faire sauter quelques un au plafond, car il fait apparaître des Supports et Résistances non conformes à la définition académique de ceux-ci.
En effet ces S/R ne tiennent pas compte du nombre d'impacts habituellement utilisés en AT.
En fait, c'est la particularité actuelle du marché qui m'a fait penser à cet outil. En effet, on voit partir comme des boulets de canon, tous les jours, des titres, dès qu'ils ont cassé leur résistance.
Je pense que le prog de stats nous permettra de repérer les prétendants au départ <img src='http://www.pro-at.com/style/images/icones/icon_smile_big.gif' border='0' alt='' title='' align='middle' />.
La vocation de ce programme est donc orientée "trading" ... et pour ceux qui travaillent sur du CT ils pourront peut être indiquer 30 périodes au lieu de 100 (Réglage P2), à chacun de faire ses essais.
Bien évidemment, je n'ai aucun recul sur la réelle efficacité de ce programme... qui est né d'une idée ... simpliste <img src='http://www.pro-at.com/style/images/icones/citrouille.gif' border='0' alt='' title='' align='middle' />.
FOKI

**FOKI** · 06/01/2006, 19:38

Bonsoir Smallcaps

Je viens de mettre ton prog SRH sur graph AT avec un réglage court
(P1 = 2 et P2 = 20) et le résulat est très surprenant visuellement, car il cadre bien les cours (voir ci-dessosu) et peut donc aider à mettre le niveau d'entrée en position avec un ASD, Il peut même servir de système de stop loss <img src='http://www.pro-at.com/style/images/icones/icon_smile_big.gif' border='0' alt='' title='' align='middle' /> sur les longs" trend" car ils sont caractérisés par des cours qui évoluent en escalier.
On verra à l'utilisation ... si d'autres personnes ont des remarques ...
Voici APRR avec vue ATD.
<center><img src='http://images.pro-at.com/200601/b/aprrsar.gif' alt='' /></center>

La même avec le prog SRH
<center><img src='http://images.pro-at.com/200601/b/aprr.gif' alt='' /></center>

Concernant les stats je ne suis pas très fan de voir apparaître les titres qui sont au dessus des résistance ou en dessous des supports (cas 1 et 3) sauf si on veut également observer les éventuels pullbacks.
Perso j'ai mis des // devant ces lignes pour éviter quelles ne s'appliquent dans la stat. Peut être une modif à faire "plus tard" en y intégrant un paramètre "Choix".
FOKI

**smallcaps90** · 07/01/2006, 11:31

Bonjour FOKI,
Je trouve une ressemblance entre ton idée et les Boîtes de Darvas. Dans ce dernier cas comme je le précisais page 70, le tracé de ces boîtes repose sur 3 règles :

R1 : le TOP potentiel de la boîte courante est trouvé s'il reste le plus haut pendant les 3 périodes qui le suivent au moins, c'est une résistance locale ;
R2 : le BOTTOM de la même boîte est trouvé ensuite s'il reste le plus bas pendant les 3 périodes qui le suivent au moins, c'est un support local ;
R3 : la recherche du BOTTOM doit commencer à la même période que celle où l'on a trouvé un TOP potentiel. Cette recherche peut très bien remettre en cause le choix du TOP potentiel s'il s'avère qu'un nouveau haut est trouvé pendant cette recherche, auquel cas il devient ce nouveau haut devient un nouveau TOP potentiel remplaçant le TOP précédemment trouvé.

Les boîtes ainsi définies introduisent une série de supports/résistances que l'on peut aussi utiliser pour placer des ordres ASD, voire des stops.
<center><img src='http://images.pro-at.com/200601/b/aprr1.gif' alt='' /></center>

D'accord avec toi pour modifier la stat.
En séparant les 4 types de proximités, le programme devient :

<pre>//========
//PROX_SRH
//========

//Statistique de détermination de la proximité des cours
//par rapport aux support et résistance horizontales
//détectées par l'indic SRH
//le 07/01/2006
//

//Choisir le type de statistique retenu
//
//CHOIX=1 détecte les possibilités de break out
//CHOIX=2 détecte les possibilités de break down
//CHOIX=3 détecte les possibilités de pull back/bull trap
//CHOIX=4 détecte les possibilités de pull back/bear trap

CHOIX = 4

//Choisir le % de proximité retenu
//
PROX = 2

//Calculs des distances en % du haut de la période courante à la résistance
//et du bas de la période courante au support
//
//
A = 100*(HAUT-SRH.R)/HAUT
B = 100*(BAS-SRH.S)/BAS

//Détecter les possibilités de break out
//
SI CHOIX=1 ET A<0 ET B>0 ET ABSOLU(A)<=PROX
ALORS
COLONNE1 = "Break out possible à " & ctxt$(ABSOLU(A),2) & "%" & " de la résistance " & ctxt$(SRH.R,2)
SELECTION
FINSI

//Détecter les possibilités de break down
//
SI CHOIX=2 ET A<0 ET B>0 ET B<=PROX
ALORS
COLONNE1 = "Break down possible à " & ctxt$(B,2) & "%" & " du support " & ctxt$(SRH.S,2)
SELECTION
FINSI

//Détecter les possibilités de pull back/bull trap
//
SI CHOIX=3 ET A>0 et A<=PROX
ALORS
COLONNE1 = "Haut au dessus de la résistance " & ctxt$(SRH.R,2) & " à " & ctxt$(A,2) & "%"
SELECTION
FINSI

//Détecter les possibilités de pull back/bear trap
//
SI CHOIX=4 ET B<0 et ABSOLU(B)<=PROX
ALORS
COLONNE1 = "Bas sous le support " & ctxt$(SRH.S,2) & " à " & ctxt$(ABSOLU(B),2) & "%"
SELECTION
FINSI</pre>

Il suffit de donner, en tête de programme, les valeurs que l'on souhaite aux 2 paramètres CHOIX et PROX.
la fenêtre Propriétés de la règle est inchangée.
Cordialement.

**FOKI** · 08/01/2006, 09:23

Bonjour Smallcaps

Diantre, tu as raison ... malgré que j"avais bien vu ce prog ... il ne m'avait pas pas "tilté" ... du moins je le pensais ... <img src='http://www.pro-at.com/style/images/icones/icon_smile_evil.gif' border='0' alt='' title='' align='middle' />
FOKI

RZ · 10/01/2006, 15:05

Magnifique cette file<img src='http://www.pro-at.com/style/images/icones/icon_smile_cool.gif' border='0' alt='' title='' align='middle' />

je viens juste de la découvrir sous le conseil de smallcaps, je n'utilise pas du tout graphat, mais vous présentez des indics très interessants.

Je m'en vais m'imprimer ces jolies 72 pages, ca me fera de la lecture pour ce week-end,<img src='http://www.pro-at.com/style/images/icones/icon_smile_tongue.gif' border='0' alt='' title='' align='middle' />

Merci et bonne continuation,
RZ

**michka** · 15/01/2006, 16:15

Bonjour Smallcaps,

Je viens de voir ton nouveau programme zz_pitchfork avec le tracé du zigzag et des fourchettes d’Andrew’s.
Sans vouloir abuser de ta générosité, serait-il possible de modifier celui-ci pour pouvoir afficher les 3 dernières fourchettes ?
J’ai essayé de faire quelques tentatives en modifiant ton programme, mais mon niveau de programmation n’est pas assez bon pour arriver à un résultat.
Je t’en remercie d’avance.

Michka

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire