[Graphe AT PRo : programmation]

[nazedoc]

bonjour Smallcaps et merci pour ta reponse et ta rapidite comme d'hab
effectivement, en recopiant le programme p53 , il n'y a plus de probleme.
tu vois meme recopier le bon programme est au dessus de mes forces, quel boulet !
encore merci pour tes competences et ta disponibilte
Olivier

[FOKI]

Bonjour

Smallcaps nous avait fait une stat pour détecter la présence d'un marteau suivi d'un marteau inversé (et l'inverse)... j'ai repris ce programme pour en faire un nouveau qui va nous faire simplement apparaître les marteaux et les marteaux inversés ... isolément.
Il ne me semble pas avoir vu cet outil <img src='http://www.pro-at.com/style/images/icones/Vache01.gif' border='0' alt='' title='' align='middle' />

La stat est faite sur le jour en cours en version de base, mais j'ai laissé la fonction <font color="red">// POUR 50 COURS</font id="red"> et le <font color="red">//FINPOUR</font id="red"> pour ceux qui souhaitent faire une recherche sur les 50 derniers jours (dans ce cas il faut supprimer les // devant ces 2 fonctions afin qu'elles soient prises en compte).

Programme :

<i><font color="blue"><font size="2">// Statistique de reconnaissance de marteaux et marteaux inversés


//PARAMETRES :

// Rapport maxi tolérable entre ombre haute du marteau
// (et de l'ombre basse du marteau inversé) et le chandelier complet
T=0

// Rapport mini entre ombre basse et hauteur du corps plein
// pour marteau et entre ombre haute et corps plein pour marteau inversé
R=2


//POUR 50 COURS

MARTEAU =
Corps(0)<>0 ET
OmbreBas(0)>R*Corps(0) ET
BasCorps(0)<=Cloture(0) ET
OmbreHaut(0)=T

MARTEAU_INVERSE =
Corps(0)<>0 ET
OmbreHaut(0)>R*Corps(0) ET
BasCorps(0)<=Cloture(0) ET
OmbreBAS(0)=T

SI MARTEAU ALORS
COLONNE1 = "Marteau le : " & datehisto$
SELECTION
FINSI

SI MARTEAU_INVERSE ALORS
COLONNE1 = "Marteau inversé le : " & datehisto$
SELECTION
FINSI


//FINPOUR</font id="size2"></font id="blue"></i>

Propriétés
<center><img src='http://images.pro-at.com/200601/b/marteau.png' alt='' /></center>


Résultats du programme sur le SRD en date du 27/01/06

<font size="2"><i>Groupe : SRD Date : 27/01/2006
Détection de Marteaux et Marteaux inversés

Marteau inversé le : 27/01/2006 Geophysique
Marteau inversé le : 27/01/2006 Rhodia
Marteau inversé le : 27/01/2006 Spir Communication
Marteau inversé le : 27/01/2006 Tracks msci mat
Marteau le : 27/01/2006 Cap Gemini
Marteau le : 27/01/2006 Euro stoxx 50 ldrs
Marteau le : 27/01/2006 Eurostoxx 50 ex
Marteau le : 27/01/2006 Provimi
Marteau le : 27/01/2006 Tracks msci hlt
Marteau le : 27/01/2006 Easyetf euro ene
Marteau le : 27/01/2006 Easyetf euro hlt</i></font id="size2">

Nota : pour les Fouchettes .... j'ai gardé les anciens prog et stat <img src='http://www.pro-at.com/style/images/icones/icon_smile_blush.gif' border='0' alt='' title='' align='middle' />

[providence]

Graphe AT 3.08 vient de sortir.

[alexandre]

<blockquote id="quote"><font size="1" id="quote">citation :<hr height="1" noshade id="quote"><i>Citation de providence</i>
<br />Graphe AT 3.08 vient de sortir.
<hr height="1" noshade id="quote"></blockquote id="quote"></font id="quote">

je viens de l'installer dans le répertoire existant sur mon disque dur.
A ma grande surprise, les indicateurs et statistiques personnels n'ont pas été récupérés. Par ailleurs, la programmation de ces indicateurs et stat n'est plus accessible par menu déroulant.

Merci d'avance pour ton attention

[FOKI]

Bonjour

Attention, il y a 2 soft : Graph AT ...et Graph AT Pro qui n'ont pas les mêmes fonctionnalités.

Juste cette idée car perso pas encore téléchargé la 3.08, je verrai cela durant le week-end.

FOKI

[alexandre]

<blockquote id="quote"><font size="1" id="quote">citation :<hr height="1" noshade id="quote"><i>Citation de FOKI</i>
<br />Bonjour

Attention, il y a 2 soft : Graph AT ...et Graph AT Pro qui n'ont pas les mêmes fonctionnalités.

Juste cette idée car perso pas encore téléchargé la 3.08, je verrai cela durant le week-end.

FOKI
<hr height="1" noshade id="quote"></blockquote id="quote"></font id="quote">

Effectivement je viens de le voir et j'ai télécharger . Le problème est résolu.
Thank you

UpdateGraphePro308.exe [2.95 Mo]

Ci joint le lien.

[FOKI]

Bonsoir

Bondiou !! Il va bien falloir s'attaquer un jour à la modélisation sur Graph AT ... du non croisement sur indicateur <img src='http://www.pro-at.com/style/images/icones/Hein33.gif' border='0' alt='' title='' align='middle' />.
C'est pas une bonne idée ça <img src='http://www.pro-at.com/style/images/icones/icon_smile_big.gif' border='0' alt='' title='' align='middle' />.
FOKI

[_fredcom_]

<blockquote id="quote"><font size="1" id="quote">citation :<hr height="1" noshade id="quote"><i>Citation de FOKI</i>
<br />Bonsoir

Bondiou !! Il va bien falloir s'attaquer un jour à la modélisation sur Graph AT ... du non croisement sur indicateur <img src='http://www.pro-at.com/style/images/icones/Hein33.gif' border='0' alt='' title='' align='middle' />.
C'est pas une bonne idée ça <img src='http://www.pro-at.com/style/images/icones/icon_smile_big.gif' border='0' alt='' title='' align='middle' />.
FOKI
<hr height="1" noshade id="quote"></blockquote id="quote"></font id="quote">

SmallCaps90 a déja attaqué le sujet.
J'ai proposé des codes dans le post "Non-croisement , Faux-croisement, croisement anticipé qui échoue et Détermination des valeurs qui donneraient un croisement"
: <a href='/ref.php?uri=http%3A%2F%2Fwww.pro-at.com%2Fforums%2Ftopic.asp%3FTOPIC_ID%3D18419%26whichpage%3D4' target="_blank">http://www.pro-at.com/forums/topic.asp?TOPIC_ID=18...</a>

Il y a quelques développements et compléments dans les messages qui suivent ce post, notamment au cours des échanges avec SmallCaps90.

[smallcaps90]

Bonjour,

Pour complèter les programmes indicateurs et statistiques sur les divergences régulières présentés plus haut dans cette file, voici un programme qui détecte et trace les éventuelles divergences cachées qui peuvent exister dans les limites définies par les valeurs des paramètres que l'utilisateur doit introduire.
Afin de limiter l'encombrement de ces programmes j'ai choisi l'option qui consiste à écrire un seul programme indicateur pour traiter les 2 types de divergences cachées (en marché haussier d'une part et en marché baissier d'autre part) et les indicateurs déjà utilisés dans les programmes qui concernent les divergences régulières, à savoir : MACD, STOCH, RSI et REPULSE_NJ. Chaque utilisateur pouvant très facilement introduire son indicateur préféré s'il n'existe parmi les précédents.
Voici le programme indicateur qui détecte les dites divergences et trace le segment de la divergence sur l'indicateur :
<pre>//===========
//DIV_CACHEES
//===========

//Rechercher la divergence cachée éventuelle la plus récente
//entre les cours et la MACD ou la STOCH ou le RSI ou le REPULSE
//V 1.0 du 08/02/2006
//

//-----------------------------------------------------------
//PARAMETRES P1 à P5 :
//
//La divergence potentielle devra se trouver
//P4 périodes avant la FINHISTO.
//
//Le 1er creux (ou le 1er sommet) sur l'indicateur
//devra se trouver dans les P1 périodes qui précèdent
//FINHISTO-P4.
//
//Le 2ème creux (ou le 2ème sommet) sur les cours devra
//se trouver dans les P2 périodes qui précèdent le 1er
//
//Chaque creux (ou sommet) sur les cours devra se trouver
//dans les P3 périodes précédant les creux (ou les sommets)
//sur l'indicateur
//
//P5=0 permet d'accepter les divergences cachées dont
//les segments présentent des intersections avec les
//cours et/ou l'indicateur
//P5=1 ne les accepte pas
//
//PARAMETRES A DEFINIR EN TÊTE DE PROGRAMME
//
//CHOIX_INDIC=1----->MACD
//CHOIX_INDIC=2----->STOCH
//CHOIX_INDIC=3----->RSI
//CHOIX_INDIC=4----->REPULSE_NJ //On peut en ajouter d'autres
//
//TYPE_DIV=1----->Divergence cachée en tendance haussière
//TYPE_DIV=2----->Divergence cachée en tendance baissière
//-----------------------------------------------------------

//Initialisations
//
CHOIX_INDIC=1
TYPE_DIV=2

IND(0)=MACD*(CHOIX_INDIC=1)
+STOCH_ATD.SLOW_D*(CHOIX_INDIC=2)
+RSI*(CHOIX_INDIC=3)
+REPULSE_NJ.REPULSE_NJ*(CHOIX_INDIC=4)

MINI=10000
MAXI=0

//Rechercher la divergence cachée éventuelle
//avant les P4 périodes qui pécèdent la FINHISTO
//
SI RANGHISTO=FINHISTO-P4 ALORS

//Rechercher un 1er creux (ou un 1er sommet) EI1
//sur l'indicateur et sa date DATE_EI1
//
I=0
EI1=MINI*(TYPE_DIV=1)+MAXI*(TYPE_DIV=2)
TANTQUE I<=P1 FAIRE
SI (IND(I+2)>IND(I+1) ET IND(I+1)<IND(I))*(TYPE_DIV=1)
OU (IND(I+2)<IND(I+1) ET IND(I+1)>IND(I))*(TYPE_DIV=2) ALORS
SI (IND(I+1)<=EI1)*(TYPE_DIV=1) OU (IND(I+1)>=EI1)*(TYPE_DIV=2) ALORS
EI1=IND(I+1)
DATE_EI1=FINHISTO-P4-(I+1)
D1=I+1
FINSI
FINSI
I=I+1
FINTANTQUE

SI D1=0 ALORS
AFFICHER "======PAS DE 1ER CREUX RECENT SUR L'INDICATEUR======="
AFFICHER "===============MODIFIEZ P1 ET/OU P4 ================="
STOP
FINSI

//Rechercher le 1er creux (ou le 1er sommet) correspondant EC1
//sur les cours et sa date DATE_EC1
//
EC1=BAS(FINHISTO-P4-DATE_EI1)*(TYPE_DIV=1)
+HAUT(FINHISTO-P4-DATE_EI1)*(TYPE_DIV=2)
DATE_EC1=DATE_EI1
K=FINHISTO-P4-DATE_EI1+1
TANTQUE K<=FINHISTO-P4-DATE_EI1+P3 FAIRE
SI (BAS(K)<=EC1)*(TYPE_DIV=1) OU (HAUT(K)>=EC1)*(TYPE_DIV=2) ALORS
EC1=(BAS(K))*(TYPE_DIV=1)+(HAUT(K))*(TYPE_DIV=2)
DATE_EC1=FINHISTO-K-P4
FINSI
K=K+1
FINTANTQUE

//Rechercher un 2ème creux (ou un 2ème sommet) EI2
//sur l'indicateur et sa date DATE_EI2
//
I=D1+1
EI2=EI1
TANTQUE I<=P2+D1 FAIRE
SI (IND(I+2)>IND(I+1) ET IND(I+1)<IND(I))*(TYPE_DIV=1)
OU (IND(I+2)<IND(I+1) ET IND(I+1)>IND(I))*(TYPE_DIV=2) ALORS
SI (IND(I+1)>=EI1)*(TYPE_DIV=1) OU (IND(I+1)<=EI1)*(TYPE_DIV=2) ALORS
EI2=IND(I+1)
DATE_EI2=FINHISTO-P4-(I+1)
D2=1
FINSI
FINSI

SI D2=1 //On a trouvé un creux (un sommet) EI2 possible
ALORS

SI P5=1 ALORS //La droite EI1--EI2 ne doit pas intersecter l'indicateur
PENTE_I=(EI1-EI2)/(DATE_EI1-DATE_EI2)
POUR (FINHISTO-P4-DATE_EI2+1) COURS
POINT_I(0)= PENTE_I*(RANGPOUR-1)+EI2
SI (POINT_I>IND)*(TYPE_DIV=1) OU (POINT_I<IND)*(TYPE_DIV=2) ALORS
N=1
BREAK
FINSI
SI RANGPOUR>(DATE_EI1-DATE_EI2) ALORS BREAK
FINPOUR
FINSI

SI N=0 ALORS //Droite de divergence correcte sur l'indicateur
//Rechercher le 2ème creux (ou le 2ème sommet) correspondant EC2
//sur les cours et sa date DATE_EC2
//
EC2=(BAS(FINHISTO-P4-DATE_EI2))*(TYPE_DIV=1)
+(HAUT(FINHISTO-P4-DATE_EI2))*(TYPE_DIV=2)
DATE_EC2=DATE_EI2
K=FINHISTO-P4-DATE_EI2+1
TANTQUE K<FINHISTO-P4-DATE_EI2+P3 FAIRE
SI (BAS(K)<=EC2)*(TYPE_DIV=1) OU (HAUT(K)>=EC2)*(TYPE_DIV=2) ALORS
EC2=BAS(K)*(TYPE_DIV=1)+HAUT(K)*(TYPE_DIV=2)
DATE_EC2=FINHISTO-K-P4
FINSI
K=K+1
FINTANTQUE

SI (EC2<=EC1)*(TYPE_DIV=1) OU (EC2>=EC1)*(TYPE_DIV=2) ALORS
SI P5=1 ALORS //La droite EC1--EC2 ne doit pas intersecter les cours
PENTE_C=(EC1-EC2)/(DATE_EC1-DATE_EC2)
POUR (FINHISTO-P4-DATE_EC2+1) COURS
POINT_C(0)=PENTE_C*(RANGPOUR-1)+EC2
SI (POINT_C>BAS)*(TYPE_DIV=1) OU (POINT_C<HAUT)*(TYPE_DIV=2) ALORS
M=1
BREAK
FINSI
SI RANGPOUR>(DATE_EC1-DATE_EC2) ALORS BREAK
FINPOUR
FINSI
SI M=0 ALORS //Droite correcte sur les cours
I=P2+D1+1
SINON
D2=0
FINSI
SINON
D2=0
FINSI
SINON
D2=0
FINSI
FINSI
N=0
M=0
I=I+1
FINTANTQUE

SI D1<>0 ET D2=0 OU EC2=0
ALORS
AFFICHER "============PAS DE DIVERGENCE POTENTIELLE============="
AFFICHER "======AVEC LES VALEURS ACTUELLES DES PARAMETRES======="
AFFICHER "===MAIS IL Y A UN 1ER CREUX SUR L'INDIC ET LES COURS=="
AFFICHER "==============MODIFIEZ EVENTUELLEMENT P2=============="
STOP
FINSI


//Déterminer les points des segments de la divergence
//cachée potentielle sur l'indicateur et les cours
//
SI DATE_EC1-DATE_EC2<5 ALORS //La valeur 5 peut être modifiée
AFFICHER "=============DIVERGENCE POTENTIELLE============"
AFFICHER "==========TROP PETITE POUR ETRE TRACEE========="
AFFICHER "===========MODIFIEZ EVENTUELLEMENT P4=========="
SINON
PENTE_I=(EI1-EI2)/(DATE_EI1-DATE_EI2)
POUR (FINHISTO-P4-DATE_EI2+1) COURS
SEG_I(0)=PENTE_I*(RANGPOUR-1)+EI2
SI RANGPOUR>(DATE_EI1-DATE_EI2) ALORS BREAK
FINPOUR

PENTE_C=(EC1-EC2)/(DATE_EC1-DATE_EC2)
POUR (FINHISTO-P4-DATE_EC2+1) COURS
SEG_C(0)=PENTE_C*(RANGPOUR-1)+EC2
SI RANGPOUR>(DATE_EC1-DATE_EC2) ALORS BREAK
FINPOUR
FINSI

FINSI
</pre>
Fenêtre "Propriétés" :
<center><img src='http://images.pro-at.com/200602/b/prop_indic.gif' alt='' /></center>

Comme j'utilise les 5 paramètres dispos dans GrapheAT Pro, les paramètres CHOIX_INDIC et TYPE_DIV qui permettent respectivement de choisir l'indicateur à associer aux cours et le type de divergence auquel on s'intéresse, sont à fixer en tête de programme.
Il est possible d'ajouter d'autres indicateurs que ceux dispos dans le listing du programme en compètant l'instruction :
IND(0)=MACD*(CHOIX_INDIC=1)
+STOCH_ATD.SLOW_D*(CHOIX_INDIC=2)
+RSI*(CHOIX_INDIC=3)
+REPULSE_NJ.REPULSE_NJ*(CHOIX_INDIC=4)
de la manière suivante :
IND(0)=MACD*(CHOIX_INDIC=1)
+STOCH_ATD.SLOW_D*(CHOIX_INDIC=2)
+RSI*(CHOIX_INDIC=3)
+REPULSE_NJ.REPULSE_NJ*(CHOIX_INDIC=4)
<font color="blue"> +NOM_REGLE_INDIC.NOM_INDIC*(CHOIX_INDIC=5)</font id="blue">

etc...

Voici maintenant le programme qui trace le segment de la divergence sur les cours :
<pre>//=================
//DIV_CACHEES_COURS
//=================

//V1.0 du 08/02/2006
//

//Tracer le segment de la divergence cachée sur les cours
//

SEG_COURS=SEG_C</pre>
Sa fenêtre "Propriétés" :
<center><img src='http://images.pro-at.com/200602/b/prop_r%e8gle_r%e9rivee.gif' alt='' /></center>
Cette règle doit être définie comme règle dérivée de la précédente.

A l'instar de ce que j'avais proposé précédemment, la découverte d'éventuelles divergences cachées dépend des valeurs que vous choisirez pour définir les paramètres P1 à P5. Les valeurs indiquées dans la fenêtre ci-dessus ne constituant pas forcément le bon choix.
Les valeurs indiquées dans la fenêtre ci-dessus ne constituant pas forcément le bon choix.
A toutes fins utiles le schéma suivant rappelle le rôle joué par chacun de ces paramètres :
<center><img src='http://images.pro-at.com/200602/b/role_des_parametres.gif' alt='' /></center>
Le paramètres P5 autorise par sa valeur 0 que les segments de la divergence cachée intersectent, éventuellement, l'indicateur et/ou les cours.
P5=1 interdit cela.

Un exemple de divergence cachée entre MACD et cours allant dans le sens de la tendance haussière et ayant confirmé celle-ci :
<center><img src='http://images.pro-at.com/200602/b/sodexho_macd+.gif' alt='' /></center>
Un autre exemple d'une divergence cachée plus ancienne cette fois-ci, en tendance baissière et l'ayant également confirmé :
<center><img src='http://images.pro-at.com/200602/b/rallye_cathiard_macd_-.gif' alt='' /></center>
Les valeurs choisies pour les paramètres P1 à P5 sont indiquées entre parenthèses après l'indicatif "Div_cachées" à gauche sur le graphe de l'indicateur.

Le programme de la statistique permettant de scanner un groupe à la recherche de ces types de divergences suit....

Cordialement.

[FOKI]

Merci Smallcaps pour ce nouveau programme

Pour Info, Roque nous avez fait un post sur les divergences cachées, il y a quelques temps.
<a href='/ref.php?uri=http%3A%2F%2Fwww.pro-at.com%2Fanalyse%2Ftechnique-1-6072.html' target="_blank">http://www.pro-at.com/analyse/technique-1-6072.html</a>
FOKI

[smallcaps90]

Bonjour FOKI,
Merci pour l'info, je ne l'avais pas vue...

Pour complèter le programme de détection des divergences cachées posté hier, je vous propose la statistique associée :

<pre>//=============
//V_DIV_CACHEES
//=============

//
//Statistique de Sélection/Validation
//des divergences cachées potentielles
//détectées par le programme DIV_CACHEES
//V1.0 du 09/02/2006

//----------------------------------------------------------------------------
//PARAMETRES A DEFINIR CI-DESSOUS
//
//EI : seuil relatif mini des écarts entre creux (sommets) sur l'indicateur
//EC : seuil relatif mini des écarts entre creux (sommets) sur les cours
//
//CHOIX=1 : sélectionne les divergences cachées potentielles dérectées
// par le programme indicateur "DIV_CACHEES"
//
//CHOIX=2 : sélectionne les divergences cachées validées
// ce sont celles qui vérifient les écarts imposés : EI et EC
//----------------------------------------------------------------------------

EI=0.05
EC=0.05
CHOIX=1

//ATTENTION :
//la valeur de N ci-dessous doit être >= à la somme P1+P2+P4
//des paramètres du programme indicateur "DIV_CACHEES"

N=100

POUR N COURS

//Récupérer le valeur de l'indicateur au creux (sommet) le plus récent
//
SI DIV_CACHEES.SEG_I(1)<>0 ET DIV_CACHEES.SEG_I=0
ALORS
E1_INDIC=DIV_CACHEES.SEG_I(1)

FINSI

//Récupérer le valeur du cours au creux (sommet) le plus récent
//
SI DIV_CACHEES.SEG_C(1)<>0 ET DIV_CACHEES.SEG_C=0
ALORS
E1_COURS=DIV_CACHEES.SEG_C(1)
FINSI

//Récupérer le valeur de l'indicateur au creux (sommet) le plus ancien
//
SI DIV_CACHEES.SEG_I(1)=0 ET DIV_CACHEES.SEG_I<>0
ALORS
E2_INDIC=DIV_CACHEES.SEG_I
FINSI

//Récupérer le valeur de l'indicateur au creux (sommet) le plus ancien
//
SI DIV_CACHEES.SEG_C(1)=0 ET DIV_CACHEES.SEG_C<>0
ALORS
E2_COURS=DIV_CACHEES.SEG_C
FINSI

//Rechercher les divergences cachées potentielles éventuelles
//
SI E1_INDIC<>0 ET E1_COURS<>0 ET E2_INDIC<>0 ET E2_COURS<>0
ALORS
SI CHOIX = 1
ALORS
COLONNE1 = "DIVERGENCE CACHEE POTENTIELLE SUR :"
VARSELECT = 1
BREAK
FINSI

//Rechercher les divergences cachées validées
//
SI (ABSOLU(E2_INDIC-E1_INDIC)/E2_INDIC)>=EI ET (ABSOLU(E2_COURS-E1_COURS)/E2_COURS)>=EC
ALORS
SI CHOIX = 2
ALORS
COLONNE1 = "DIVERGENCE CACHEE VALIDEE SUR :"
VARSELECT = 1
BREAK
FINSI
FINSI
FINSI

FINPOUR

SI VARSELECT=1
ALORS
SELECTION
FINSI
</pre>
Fenêtre "Propriétés" :
<center><img src='http://images.pro-at.com/200602/b/pro_stat.gif' alt='' /></center>

Rien de nouveau dans le principe.
Il suffit pour l'utiliser d'aller préalablement dans le programme "DIV_CACHEES" dans lequel vous devez règler vos paramètres dans la fenêtre Propriétés et sélectionner dans le corps du programme les valeurs que vous souhaitez pour les constantes CHOIX_INDIC et TYPE_DIV.
PUis de choisir dans la stat elle-même les valeurs que vous donnerez à EI, EC et CHOIX.
Ici : P1P2P3P4P5 = 20,20,4,5,1
CHOIX_INDIC=1, TYPE_DIV=1 dans DIV_CACHEES
et dans la stat CHOIX=1 (les valeurs de EI et EC ne sont prises en compte que lorsque CHOIX=2).

Résultats obtenus avec le groupe CAC40 pour la MACD et les divergences de type 1 (haussières) :

<font size="1">Groupe : cac40 Date : 09/02/2006
Sélection/Validation des divergences cachées
entre cours et MACD (ou STOCH ou RSI ou REPULSE_NJ)

DIVERGENCE CACHEE POTENTIELLE SUR : AGF
DIVERGENCE CACHEE POTENTIELLE SUR : Arcelor
DIVERGENCE CACHEE POTENTIELLE SUR : Bnp Paribas
DIVERGENCE CACHEE POTENTIELLE SUR : Credit agricole
DIVERGENCE CACHEE POTENTIELLE SUR : Dexia
DIVERGENCE CACHEE POTENTIELLE SUR : L'Oreal
DIVERGENCE CACHEE POTENTIELLE SUR : Thales
DIVERGENCE CACHEE POTENTIELLE SUR : Veolia Environnement
DIVERGENCE CACHEE POTENTIELLE SUR : Vinci</font id="size1">

Une petite illustration :
<center><img src='http://images.pro-at.com/200602/b/ca_1_divmacd+.gif' alt='' /></center>
Les valeurs des paramètres sont indiquées sur le graphe.

La recherche avec les mêmes paramètres sur le CAC40 des divergences cachées de type 2 (baissières), moins fréquentes actuellement, ne donne rien.
Sur le SRD avec :
P1P2P3P4P5=5,20,5,0,1
CHOIX_INDIC=1
TYPE_DIV=2 dans l'indicateur et
CHOIX=1 dans la stat.

<font size="1">Groupe : SRD Date : 09/02/2006
Sélection/Validation des divergences cachées
entre cours et MACD (ou STOCH ou RSI ou REPULSE_NJ)

DIVERGENCE CACHEE POTENTIELLE SUR : Bollore
DIVERGENCE CACHEE POTENTIELLE SUR : Bonduelle
DIVERGENCE CACHEE POTENTIELLE SUR : Euro Disney
DIVERGENCE CACHEE POTENTIELLE SUR : Faurecia</font id="size1">

<center><img src='http://images.pro-at.com/200602/b/faurecia.gif' alt='' /></center>

Cordialement.

[spider]

Bonjour à tous
Suite au message de cette file, j'ai essayé de la programmer l'auto force relative mais je ne sais pas si c'est correct.
La file en question
<a href='/ref.php?uri=http%3A%2F%2Fwww.pro-at.com%2Fforums%2Fbourse-1-20368.html' target="_blank">http://www.pro-at.com/forums/bourse-1-20368.html</a>
Vos avis ?? ça vous parait juste ou vous avez mieux ? <img src='http://www.pro-at.com/style/images/icones/icon_smile_wink.gif' border='0' alt='' title='' align='middle' />
C'est un peu long à charger quand on met le graph. <img src='http://www.pro-at.com/style/images/icones/icon_smile_dead.gif' border='0' alt='' title='' align='middle' />

<center><img src='http://images.pro-at.com/200602/b/fr1.gif' alt='' /></center>

<center><img src='http://images.pro-at.com/200602/b/fr2.gif' alt='' /></center>

Merci d'avance pour vos éventuelles réponses.

[smallcaps90]

Bonsoir Spider,

Ta boucle POUR est inutile ici puisque GrapheAT Pro calcule automatiquement H et L à chaque période sur les 245 périodes précédentes à l'aide des fonctions MAX et MIN et aussi tes sorties AUTOR1 et AUTOR2.

Par contre pour visualiser la position de la valeur (j'ai choisi la clöture ici), par rapport à sont range annuel comme le fait F. Baron, on peut envisager cela de différentes façons.
Voici un programme possible :

<pre>//Calcul de l'AFR (Auto Force Relative de F. Baron)
//

MAXI=MAX(HAUT,P1)
MINI=MIN(BAS,P1)
AFR(0)=(Cloture-Mini)/(Maxi-Mini)

NB=P2
NH=P3

//Eventuellement
//SI AFR>P3 ALORS AFR_HAUT=AFR
//SI AFR<=P3 ET AFR>=P2 ALORS AFR_INTERM=AFR
//SI AFR<P2 ALORS AFR_BAS=AFR</pre>
Fenêtre "Propriétés" :
<center><img src='http://images.pro-at.com/200602/b/prop.gif' alt='' /></center>

Ce qui donne :
<center><img src='http://images.pro-at.com/200602/b/afr_seule.gif' alt='' /></center>

On peut aussi colorier la courbe de l'AFR de telle sorte que les parties supérieures à 0.66 soient visualisées en vert, celles comprises entre 0.33 et 0.66 le soient en orange et celles inférieures à 0.33 en rouge. Pour ceci règler la fenêtre Propriétés de l'indic de la façon suivante :
<center><img src='http://images.pro-at.com/200602/b/prop2.gif' alt='' /></center>
Et décocher les // devant les 3 dernières lignes du programme.
Ce qui donne :
<center><img src='http://images.pro-at.com/200602/b/arf_color.gif' alt='' /></center>
On a qq petits pb de représentations (absence de portions de courbes) qui ne nuisent pas trop à la compréhension au passage des 2 limites 0.33 et 0.66 du fait de l'utilisation du type Segments pour représenter les portions de courbes. On pourrait améliorer çà facilement, je te laisse le soin de le faire....

Cordialement.

[spider]

Merci beaucoup smallcaps90.
Je préfère vraiment ta formule avec affichage sous le graph.
Je vais tout de suite mettre ça dans mon log <img src='http://www.pro-at.com/style/images/icones/icon_smile_wink.gif' border='0' alt='' title='' align='middle' />

[jelofe]

bonjour
je suis neophyte et ai un petit probleme pour l'affichage des diverges cachées. Sur le graphe du cours tout est décalé vers le haut ainsi qu'un trait rouge sur l'axe du zéro!
Sur l'oscillateur j'ai bien la divergence mais ensuite le trait revient sur l'axe du zéro.
Est ce un probleme de configuration de mes parametres?
merci