[Graphe AT PRo : programmation]

[christol]

Bonjour à tous,

Les utilisateurs de GraphAt Pro connaissent tous la possibilité d'éditer 2 seuils pour les actions. Cette fonction que l'on retrouve dans les statistiques, est bien pratique pour visualiser rapidement, les franchissements de supports ou de résistances.

A votre avis, est-il possible d'utiliser ces seuils dans une fonction statistique, pour déterminer la PROXIMITE d'un support ou d'une résistance. Un peu comme ce que l'on trouve sur le site ZoneBourse.

Bien cordialement

<center><img src='http://images.pro-at.com/200510/b/seuils_zb1.jpg' alt='' /></center>

[kiki27]

Apparement oui ,

dans insertion fonction statistique tu as seuil1 et seuil2..tu peux donc les utiliser..... à condition d'avoir créer les seuils avant <img src='http://www.pro-at.com/style/images/icones/icon_smile_wink.gif' border='0' alt='' title='' align='middle' />

[smallcaps90]

Bonjour chctrader,

S'il s'agit uniquement d'afficher la proximité (distance), en %, de la clôture par rapport aux 2 seuils qui définissent le support et la résistance d'un groupe d'actions, voici ce que l'on pourrait faire en utilisant une règle statistique pour effectuer les calculs et afficher les résultats :

<pre>
//Détermination de la proximité cours/seuils
//le 25/10/2005
//

Proxi_S= 100*(CLOTURE-SEUIL1)/SEUIL1
Proxi_R= 100*(CLOTURE-SEUIL2)/SEUIL2

Colonne1 =
"Cloture = " & ctxt$(cloture,2) &
" Support : " & ctxt$(seuil1,2) &
" Prox/support : " & ctxt$(Proxi_S,2) & "%" &
" Résistance = " & ctxt$(seuil2,2) &
" Prox/résistance : " & ctxt$(Proxi_R,2) & "%"
</pre>
Propriétés :
<center><img src='http://images.pro-at.com/200510/b/proprietes_proxi.gif' alt='' /></center>

J'ai créé un groupe de 3 actions "Essai_Proxi" : France Télécom, Renault et Natexis.
Voici ce que cela donne comme résultats à la date d'hier avec des seuils prédéfinis :
<center><img src='http://images.pro-at.com/200510/b/resultats_proxi.gif' alt='' /></center>

On peut améliorer cela bien sûr...par exemple n'afficher que les valeurs du groupe dont l'une ou l'autre des proximités est inférieure à un delta choisi...

Comme le précise kiki27, il faut bien entendu entrer manuellement les 2 seuils choisis pour chaque action du groupe par le menu "Editer/ Action...", la visualisation des seuils sur le graphe s'effectuant par le menu "Option" en marquant la ligne "Afficher les seuils".

Cordialement.

[christol]

Merci Smallcaps et Kiki,

Je viens de découvrir les seuils dans le menu insérer "Fonctions d'information" du module statistique.

ça marche au poil, ton programme smallcaps. Exactement comme je le souhaite.

Bien cordialement

[sphinx]

afin d'automatiser (dans une certaine mesure) la détection des seuils et le delta (pourcentage), pourrait on combiner la détection des gaps (qui sont souvent des seuils et résistances naturelles) avec le dernier programme proposé par notre ami Smallcaps.
Il y a eu un programme sur cette file avec les gaps de rupture, continuation... qui pourrait donner une base de réflexion.

[sphinx]

pas réussi à faire cette stat en utilisant le programme "seuil" ci dessus de Smallcaps et le programme "gap" de Michka page 60. Désolé ((
La difficulté réside probablement dans l'identification du ou des 2 gaps (en support et en résistance) les plus proches en pourcentage du cours de cloture même s'ils se sont produit il y a 1 an et qu'il y a eu d'autres gaps entre temps.

[sphinx]

voilà, je fais le 1000ème message de cette file.
Cahier des charges : Ils'agit de déterminer le %age par rapport aux 2 gaps les plus proches en % du cours de cloture de la valeur. Exemple:
prenons une valeur appelée Sphinx, elle cloture à 10.
sur son graphe, gràce au programme de Michka Page 60, on identifie plusieurs gaps: un gap le 2/1/2005 à 11
un gap le 2/2/2005 à 12,5
un gap le 2/3/2005 à 13
un gap le 2/5/2004 à 8,5
un gap le 2/4/2004 à 7,3
un gap le 2/3/2004 à 6
cette valeur est donc montée comme une fusée en 2004.
Les gaps sont des zones de supports et de résistances naturelles.
la valeur cotant actuellement 10, il s'agirait de faire une stat permettant d'identifier les 2 gaps les plus proches en haut et en bas par rapport à la valeur 10 et d'afficher le pourcentage d'écart.
Dans notre exemple: valeur Sphinx cloture = 10
gap haut n°1= 11; delta =10%
gap haut n°2 = 12,5 ; delta = 25%
gap bas n°1 = 8,5 ; delta= -15%
gap bas n°2 = 7,3 ; delta= -27%
Je pensais pouvoir utiliser ce qui était déjà fait, mais j'y arrive pas.
Cordialement
Sphinx

[smallcaps90]

Bonjour Sphinx,

La statistique suivante répond-elle à ton attente?

<hr noshade size="1">Programme :
<pre>
//Statistique de recherche des 2 gaps hauts et des 2 gaps bas
//les plus proches de la cloture actuelle.
//le 02/11/2005
//

P1=200 //nb de périodes examinées, à modifier à volonté
C_ACTU=CLOTURE //clôture actuelle
CPTS=0 //compteur de supports
CPTR=0 //compteur de résistances

//Calculer les proximités en % et des positions des gaps
//qui existent dans les P1 périodes qui précèdent la FINHISTO
I=0
TANTQUE I<=P1 FAIRE
GB = GAPS.GAP_B(I)
GH = GAPS.GAP_H(I)
PROXI(0) = 100*(C_ACTU-HAUT(I)*(GB=1)-BAS(I)*(GH=1))/(HAUT(I)*(GB=1)+BAS(I)*(GH=1))
SI PROXI>0 ALORS
PROX_S(CPTS)=PROXI
S(CPTS)=I
CPTS=CPTS+1
FINSI
SI PROXI<0 ALORS
PROX_R(CPTR)=PROXI
R(CPTR)=I
CPTR=CPTR+1
FINSI
I=I+1
FINTANTQUE

//
//Calcul de la proximité du 1er support et de sa position
//
DS1=PROX_S(0)
S1=S(0)
POS=0
I=1
TANTQUE I<=CPTS-1 FAIRE
SI PROX_S(I)<DS1 ALORS
DS1=PROX_S(I)
S1=S(I)
POS=I
FINSI
I=I+1
FINTANTQUE
PROX_S(POS)=0

COLONNE1="proxi_s1 : " & ctxt$(DS1,2) & "% I=" & ctxt$(S1,0)
SI DS1=0 ET S1=0 ALORS COLONNE1="==================="

//
//Calcul de la proximité du 2ème support et de sa position
//
I=0
TANTQUE I<=CPTS-1 FAIRE
SI PROX_S(I)<>0 ALORS
DS2=PROX_S(I)
S2=S(I)
BREAK
FINSI
I=I+1
FINTANTQUE
I=0
TANTQUE I<=CPTS-1 FAIRE
SI PROX_S(I)<>0 ET PROX_S(I)<DS2 ALORS
DS2=PROX_S(I)
S2=S(I)
FINSI
I=I+1
FINTANTQUE

COLONNE2="proxi_s2 : " & ctxt$(DS2,2) & "% I=" & ctxt$(S2,0)
SI DS2=0 ET S2=0 ALORS COLONNE2="==================="

//
//Calcul de la proximité de la 1ère résistance et de sa position
//
DR1=PROX_R(0)
R1=R(0)
POS=0
I=1
TANTQUE I<=CPTR-1 FAIRE
SI PROX_R(I)>DR1 ALORS
DR1=PROX_R(I)
R1=R(I)
POS=I
FINSI
I=I+1
FINTANTQUE
PROX_R(POS)=0

COLONNE3="proxi_r1 : " & ctxt$(DR1,2) & "% I=" & ctxt$(R1,0)
SI DR1=0 ET R1=0 ALORS COLONNE3="==================="

//
//Calcul de la proximité de la 2ème résistance et de sa position
//
I=0
TANTQUE I<=CPTR-1 FAIRE
SI PROX_R(I)<>0 ALORS
DR2=PROX_R(I)
R2=R(I)
BREAK
FINSI
I=I+1
FINTANTQUE
I=0
TANTQUE I<=CPTR-1 FAIRE
SI PROX_R(I)<>0 ET PROX_R(I)>DR2 ALORS
DR2=PROX_R(I)
R2=R(I)
FINSI
I=I+1
FINTANTQUE

COLONNE4="proxi_r2 : " & ctxt$(DR2,2) & "% I=" & ctxt$(R2,0)
SI DR2=0 ET R2=0 ALORS COLONNE4="==================="
</pre>

Le programme récupère les variables GAP_B et GAP_H du programme de Michka (page 60 du forum). Ce programme se trouve dans la règle GAPS chez moi. Il suffit de modifier ceci dans les instructions :
GB=GAPS.GAP_B(I) et GH=GAPS.GAP_H(I) si tel n'est pas le cas chez toi.

<hr noshade size="1">Propriétés :
<center><img src='http://images.pro-at.com/200511/b/prop_stat_gaps1.gif' alt='' /></center>

La règle statistique précédente ne fait qu'effectuer les calculs de proximité nécessaires et en affiche les valeurs pour un groupe donné. Elle affiche également la position des gaps sélectionnés sous la forme "I=XX", XX étant le nombre de périodes où se trouvent les gaps par rapport à la dernière période. Ceci a été induit par l'emploi des boucles "TANTQUE" qui n'accèdent pas directement à la variable "datehisto$" dans le programme. On pourrait bien sûr transformer les valeurs de I en dates explicites....

Exemple de résultats pour le groupe suivant qui comporte les 10 valeurs suivantes : ALCATEL, APRR, CARREFOUR, DMC, FAURECIA, LOCINDUS, NOVARTIS, PENAUILLE, SANOFI et SOITEC :

<center><img src='http://images.pro-at.com/200511/b/resultats_stat_gaps.gif' alt='' /></center>

La 1ère colonne du tableau indique la plus petite proximité de la clôture actuelle par rapport au 1er gap_support : "proxi_s1= .... " et la position de ce gap-support en nombre de périodes précédant la période actuelle : "i=...".
La 2ème colonne affiche les résultats pour le 2ème gap-support, la 3ème et la 4ème colonne les affiche pour les 2 gaps_résistances les plus proches de la clôture actuelle.
Lorsqu'une colonne comporte les signes "======", cela signifie que le programme n'a pas trouvé de gap_support et/ou de gap_résistance dans les P1 périodes scannées.
Pour APRR par exemple aucun gap n'a été trouvé.

Cordialement.

[sphinx]

tel le bon génie du conte des 1001 nuits, notre ami Smallcaps nous gratifie de la 1001ème réponse de cette fabuleuse file.Pour moi ça marche parfaitement. Je t'en remercie grandement. Si j'ai des idées de modifications , je t'en ferai part.
Avec tous mes remerciements
Sphinx
PS: les gaps servant de support et de résistances, ça peut aussi servir de règle de money management pour les stops( ne pas être trop loin). Je crois que beaucoup y verront un avantage certain à cette stat. Encore merci.

[smallcaps90]

Bonjour,

Ci-dessous, une autre petite statistique pour détecter les derniers gaps qui se seraient produits dans les N plus récentes périodes d'un groupe donné.

<u>Programme.</u>
<pre>
//Stat de recherche des gaps les plus récents
//le 02/10/2005
//

N=5 //nb de périodes à explorer

POUR N COURS

//Gaps communs
SI GAPS.COMM=-1 ET GAPS.GAP_H ALORS
COLONNE1="GAP COMMUN "
COLONNE2="à la hausse"
COLONNE3=datehisto$
SELECT=1
FINSI
SI GAPS.COMM=-1 ET GAPS.GAP_B ALORS
COLONNE1="GAP COMMUN "
COLONNE2="à la baisse"
COLONNE3=datehisto$
SELECT=1
FINSI

//Gaps de rupture
SI GAPS.RUPT=-1 ET GAPS.GAP_H ALORS
COLONNE1="GAP DE RUPTURE "
COLONNE2="à la hausse"
COLONNE3=datehisto$
SELECT=1
FINSI
SI GAPS.RUPT=-1 ET GAPS.GAP_B ALORS
COLONNE1="GAP DE RUPTURE "
COLONNE2="à la baisse"
COLONNE3=datehisto$
SELECT=1
FINSI

//Gaps de continuation
SI GAPS.CONT=-1 ET GAPS.GAP_H ALORS
COLONNE1="GAP DE CONTINUATION"
COLONNE2="à la hausse"
COLONNE3=datehisto$
SELECT=1
FINSI
SI GAPS.CONT=-1 ET GAPS.GAP_B ALORS
COLONNE1="GAP DE CONTINUATION"
COLONNE2="à la baisse"
COLONNE3=datehisto$
SELECT=1
FINSI

//Gaps de terminaison
SI GAPS.TERM=-1 ET GAPS.GAP_H ALORS
COLONNE1="GAP DE TERMINAISON"
COLONNE2="à la hausse"
COLONNE3=datehisto$
SELECT=1
FINSI
SI GAPS.TERM=-1 ET GAPS.GAP_B ALORS
COLONNE1="GAP DE TERMINAISON"
COLONNE2="à la baisse"
COLONNE3=datehisto$
SELECT=1
FINSI

//Gaps de confirmation
SI GAPS.CONF=-1 ET GAPS.GAP_H ALORS
COLONNE1="GAP DE CONFIRMATION"
COLONNE2="à la hausse"
COLONNE3=datehisto$
SELECT=1
FINSI
SI GAPS.CONF=-1 ET GAPS.GAP_B ALORS
COLONNE1="GAP DE CONFIRMATION"
COLONNE2="à la baisse"
COLONNE3=datehisto$
SELECT=1
FINSI
FINPOUR


SI SELECT=1 ALORS SELECTION
</pre>

<u>Propriétés.</u>
<center><img src='http://images.pro-at.com/200511/b/prop.gif' alt='' /></center>

J'ai trié les résultats suivant les dates croissantes (voir colonne3). On peut imaginer d'autres critères de tri...
Pour le CAC40 en date d'hier :
<center><img src='http://images.pro-at.com/200511/b/r%e9sultats.gif' alt='' /></center>
Cordialement.

[lego]

Merci Sphinx et Smallcaps

Pour les idées et les programmes sur les Gaps
Comme d'habitude je ne comprends pas encore grand chose, il faut que je regarde ça de près

Bon Week-end

[jlr]

je voudrais calculer une variable non historisée du type :

ecart = ECARTYPE((Haut(0)+Bas(0)+Cloture(0))/3,20)

quand je teste, la variable ecart est historisée.

où est le pb ?

PS : j'ai terminé une 1ère version des indicateurs GrapheATPro 2005.
Envoyez-moi un MP avec votre adresse si vous êtes intéressés.

jlr



Je viens de trouver l'erreur : je voulais tracer la variable ecart ( Je suppose que GrapheAT l'historise automatiquement ?). En supprimant la variable des courbes, elle (re)devient non historisée.

[Bomdu]

Bonjour,

Depuis quelque temps, en téléchargement intraday je reçois le message error "File C:PROGRAMA~GRAPHE~basedroiteCAC40FR0003500008.i05
access error " et "File
C:PROGRA~1GRAPHE~1BaseGroupeAll.txt create error" les cours apparaissent bien sur les graphiques mais à chaque téléchargement j'ai ces fenêtres d'erreur que me pourrissent la vie. Savez vous comment resoudre ce probléme?
Merci

[sphinx]

comment parametrer une stat qui détecte un croisement du stochastique avec son signal en dayly ET un redressement du stochastique weekly même si celui-ci n'a pas croiser sa ligne?
exemple avec un stoch (10,3,3) dayly et weekly pour la valeur Passat : on constate un croisement dayly (depuis un moment) alors qu'en weekly, le stoch se redresse mais n'a pas encore croisé sa ligne.
Merci

[smallcaps90]

Bonsoir Sphinx,

Il est possible de créer très facilement avec GrapheAT Pro une règle statistique qui utilise des conditions différentes en daily, weekly (et même monthly). Il suffit pour ce faire d'écrire les règles ad-hoc dans les fenêtres accessibles sous les onglets "Jour", Semaine" ( et si nécessaire, "Mois") dans la fenêtre "Règle statistique".
Les valeurs sélectionnées par le scan sont celles qui vont satisfaire <b>simultanément</b> les conditions énoncées dans ces fenêtres.

Pour le pb qui t'intéresse ici, il faut que tu crées une règle sous l'onglet "Jour" qui détecte que le Stoch Daily est bien supérieur à son signal au dernier jour de l'historique, ce qui prouve donc qu'il a croisé son signal à la hausse précédemment. Voir condition1 en commentaire dans le programme ci-dessous.
On pourrait aussi imposer qu'il l'ait croisé dans la zone de survente <20 et depuis "peu", je ne l'ai pas fait ici.
Par contre j'impose que le Stoch Daily actuel soit supérieur au Stoch Daily précédent. Ceci évite des cas du genre "Gaz de France"...Voir condition 2 dans les commentaires du programme.

Ensuite il te faut créer la règle dans l'onglet "Semaine".
On y impose, Condition3, que le Stoch Weekly se redresse.
Puis qu'il n'ait pas encore croisé son signal, Condition 4.
Enfin, si tu le souhaites, on impose qu'il soit encore situé sous la valeur de survente=20, c'est la Condition 5.

Programme à entrer sous l'onglet "Jour"
<pre>
========================================
//STOCH_ATD > A SON SIGNAL EN DAILY
//REDRESSEMENT DU STOCH_ATD EN WEEKLY
//le 19/11/05
//

SI STOCH_ATD.D>STOCH_ATD.SLOW_D //Condition 1- Stoch Daily a croisé son signal à la hausse auparavant
ET STOCH_ATD.D>STOCH_ATD.D(1) //Condition 2- Stoch Daily croissant
ALORS
SELECTION
FINSI
========================================
</pre>
Programme à entrer sous l'onglet "Semaine" :
<pre>
========================================
//STOCH_ATD > A SON SIGNAL EN DAILY
//REDRESSEMENT DU STOCH_ATD EN WEEKLY
//le 19/11/05
//

SI STOCH_ATD.D>STOCH_ATD.D(1) //Condition 3- Stoch Weekly se redresse
ET STOCH_ATD.D<STOCH_ATD.SLOW_D //Condition 4- Stoch Weekly n'a pas encore croisé son signal
ET STOCH_ATD.D<STOCH_ATD.L_SURVENTE //Condition 5- Stoch Weekly sous la ligne de survente = 20
ALORS
SELECTION
FINSI
========================================
</pre>
Mon Stoch est situé dans la règle indicateur STOCH_ATD que tu dois avoir créée également.

La fenêtre "Propriétés" de la règle ne comporte pas de colonnes.

Avec mon groupe "All" on trouve en date d'aujourd'hui :

<font size="1">Groupe : All Date : 19/11/2005
STOCH_ATD > A SON SIGNAL EN DAILY
REDRESSEMENT DU STOCH_ATD EN WEEKLY
le 19/11/05

Bernard loiseau sa
Crcam aquitainecci
General Motors
Groupe ares
Groupe euromedis
Orapi
Passat
Socim
Thermocompact
Tivoly s.a.
Valtech</font id="size1">

qui contient bien Passat que tu utilisais comme exemple (et pas Gaz de France...).

Bon dimanche.
Cordialement.