[Graphe AT PRo : programmation]

[smallcaps90]

Effectivement Alexandre, c'est bien plus facile ainsi...
A propos, bravo pour ton palmarès sur abcbourse!

Cordialement

[alexandre]

<img src='http://www.pro-at.com/style/images/icones/icon_smile.gif' border='0' alt='' title='' align='middle' /> merci
Bonne journée

[Papy29]

Bonjour Smallcaps et Merci c’est exactement ce que je recherchai
ta suggestion de règles statistiques me tente, je vais essayer

Cordialement

[Papy29]

Bonjour Smallcaps
Suite a ta suggestion du 07/03/08 pour balayer une série d’actions j’ai tenté sans succès de construire une règle statistique avec les indicateurs du Zerolagmacd sur la base des « flèche haute, flèche basse »
Si ce n’est pas trop compliqué merci de m’apporté ton aide

Cordialement

[Gilda56]

Transfert d'un indicateur Graphe AT Pro sur le logiciel Graphe de IGM Market's sans doute Pro Real Time

Bonjour à TOUS

Je suis un fidèle du forum mais j'ai pris un abonnement sur ABC bourse pour la mise à jour des cours Intraday mais ce site ne propose qu'une mise à jour toutes les 5 minutes or j'ai ouvert un compte chez IGM Market pour faire des CFD et il y a là les cours en direct au tic près et je voudrais donc transférer un indicateur que SMALLCAPS m'a bricolé et qui finalement me convient sur Graphe At Pro Voilà

Alors si qq'un pouvait m'aider car je suis nul en programmation surtout qu'il y a des implications entre certains indic Je ferai une capture d'écran et donnerai la programmation de Small

Bonne journée

[fredifly]

Bonjour à toutes et a tous,

Sur le blog de hk lisse il y a un indicateur qui a l'air de donner de bons signaux de divergences c'est l'oscillateur SVAPO Price-Only de Sylvain Vervoort.

Voici le lien pour ceux ou celles qui serait interressé:
<a href='/ref.php?uri=http%3A%2F%2Fhk-lisse.over-blog.com%2Farticle-17160379.html' target="_blank">http://hk-lisse.over-blog.com/article-17160379.html</a>

Ne connaissant pas le language de programmation prorealtime est il possible de pouvoir le programmer sans trop de mal sur graphatpro?

Merci d'avance pour vos réponses.

Cordialement.

Fredifly.

[smallcaps90]

Bonjour Papy29,

La statistique que tu souhaites est prête.
Voici son programme :



//=======================
//STAT_CROISEMENTS_ZLMACD
//=======================

//v .0
//smallcaps90
//le 13/03/2007

//Statistique de recherche des derniers croisements du "ZeroLagMACD"
//avec son signal situés dans les N dernières périodes de l'historique

//---------1 Fixer le nb N de barres à explorer
//
N=2


//---------2 Scanner le groupe choisi
//
Pour N Cours

Si ZLMACD_Croisements.Hausse<>0
Alors
COLONNE1="Signal de hausse détecté le : " & datehisto$(1)
SELECT=1
FinSi

Si ZLMACD_Croisements.Baisse<>0
Alors
COLONNE1="Signal de baisse détecté le : " & datehisto$(1)
SELECT=1
FinSi

FinPour

//---------3 Afficher résultats
//
SI SELECT=1 ALORS SELECTION

//fin du code



Pour que la stat fonctionne, il faut bien entendu que tu aies créé les deux indicateurs : "ZeroLagMACD" et son dérivé : "ZLMACD_Croisements" décrits dans mon précédent post puisque la stat récupère les valeurs de variables "HAUSSE" et "BAISSE" de ce dernier.

Tu peux installer le programme en faisant un simple "copier/coller" sous l'onglet "Jour" ou l'onglet "Semaine" ou encore l'onglet "Mois" de la fenêtre "Règle statistique" dans GrapheAT Pro suivant ton horizon de trading.

Le seul paramètre à indiquer en tête de programme est N qui fixe le nombre de périodes que tu souhaites scanner sur les actions de ton groupe test.
Tu peux faire N=1 si tu veux connaître les plus récents croisements ou choisir toute autre valeur si tu souhaites voir comment se comporte ton système dans le temps.

Fenêtre "Propriétés" de la règle statistique :
<center><img src='http://images.pro-at.com/forums-bourse/0308/3668_131635.png' alt='' /></center>

A titre d'exemple pour le CAC40 en date d'hier voici ce que cela donne avec P4=1.5 dans la règle "ZeroLagMACD" et N=2 (autres paramètres inchangés) :

=============
Groupe : cac40 Date : 12/03/2008
Statistique de recherche des derniers croisements du ZeroLagMACD
avec son signal situés dans les N dernières périodes de l'historique

Signal de HAUSSE détecté le : 11/03/2008 Alstom
=============

En étant moins sévère sur P4, (P4=0.5) et toujours N=2 :

=============
Groupe : cac40 Date : 12/03/2008
Statistique de recherche des derniers croisements du ZeroLagMACD
avec son signal situés dans les N dernières périodes de l'historique

Signal de HAUSSE détecté le : 10/03/2008 Bouygues
Signal de HAUSSE détecté le : 11/03/2008 Accor
Signal de HAUSSE détecté le : 11/03/2008 Alstom
Signal de HAUSSE détecté le : 11/03/2008 Cap Gemini
Signal de HAUSSE détecté le : 11/03/2008 PPR
=============

N'hésite pas si tu as de difficultés...

Cordialement.

[smallcaps90]

Bonsoir Fred,


La moyenne expo "Zero Lag" que Sylvain Vervoort utilise n'est autre qu'une DEMA déjà présentée :
<a href='/ref.php?uri=http%3A%2F%2Fwww.pro-at.com%2Fforums-bourse%2Ftopic.php%3Fwhichpage%3D2%26TOPIC_ID%3D11111' target="_blank">http://www.pro-at.com/forums-bourse/topic.php?whic...</a>

Pour ce qui est de la traduction en langage GrapheAT Pro de son indicateur "SVAPO Price-Only" présenté ds TASC de février 2008 et auquel hk_lisse fait référence, ainsi que les divergences qu'il peut présenter avec les cours, je pourrais regarder çà dès mon retour de Suisse samedi ou dimanche prochain.
Demain concert James Blunt au Zénith à Strasbourg...il n'y a pas que la bourse dans la vie...

Où en es-tu de tes développements de la méthode de Raghee Horner?

Cordialement.

[fredifly]

<blockquote><strong>Citation de : smallcaps90</strong> <em>(au 13-03-2008 17:07:15)</em>

Bonsoir Fred,


La moyenne expo "Zero Lag" que Sylvain Vervoort utilise n'est autre qu'une DEMA déjà présentée :
<a href='/ref.php?uri=http%3A%2F%2Fwww.pro-at.com%2Fforums-bourse%2Ftopic.php%3Fwhichpage%3D2%26TOPIC_ID%3D11111' target="_blank">http://www.pro-at.com/forums-bourse/topic.php?whic...</a>

Pour ce qui est de la traduction en langage GrapheAT Pro de son indicateur "SVAPO Price-Only" présenté ds TASC de février 2008 et auquel hk_lisse fait référence, ainsi que les divergences qu'il peut présenter avec les cours, je pourrais regarder çà dès mon retour de Suisse samedi ou dimanche prochain.
Demain concert James Blunt au Zénith à Strasbourg...il n'y a pas que la bourse dans la vie...

Où en es-tu de tes développements de la méthode de Raghee Horner?

Cordialement.
</blockquote><hr />

Bonsoir Daniel,

Je n'ai pas abandonné la méthode kosta je cherches actuellement du coté des moyennes type butterworth. J'expérimente, je teste, j'analyse mais pour l'instant rien de bien probant à mon gout. De plus j'ai du formater mon pc ce qui n'a pas arrangé les choses car j'ai tout perdu... <img src='http://www.pro-at.com/style/images/icones/icon_smile_angry.gif' border='0' alt='' title='' align='middle' />

En attendant je te souhaite un bon concert. Amuse toi bien et a bientot.

Fred

[Papy29]

Bonsoir Smallcaps

Formidable ça marche, je ne pouvais rêver mieux un grand merci a toi
Comment fais-tu pour réagir si vite et si bien ?
Avec ta méthode je vais pouvoir balayer plus vite des séries d’actions

Cordialement et Bonne soirée

[fredifly]

Bonjour a tous,

Voila j'ai un petit soucis avec l'outils téléchargement de graph at pro. J'ai voulu télécharger les cours du lundi 17 mars et il me dis que "la liste de valeurs à télécharger est vide".

J'ai regardé dans la liste (dans le dossier importation) le fichier n'est pas vide.

J'ai essayé toute les possibilités (format avec ou sans libellé, avec ou sans téléchargement séparé des marchés).

Je n'arrives pas a savoir d'ou ca vient...

Merci d'avance pour votre aide.

Fredifly.

[smallcaps90]

Bonsoir Fred,


Excuse le retard mis à te répondre, j'ai prolongé un peu mon séjour "helvétique"...

Pour ce qui concerne les cours, je ne peux pas te répondre car je passe par la commande "Importation des cours" que je vais chercher sur abcbourse et je n'ai jamais eu aucun pb pour le faire.

J'ai programmé le "Short-Term Volume and Price Oscillator Price Only" présenté dans TASC de fev. 2008 par Sylvain Vervoort mais pas encore adapté mes prog. sur les divergences régulières et cachées avec cet indicateur. Je le ferai sous peu si tu es intéressé.

//=====
//SVAPO
//=====

//Short-Term Volume and Price Oscillator Price Only
//d'après Sylvain Vervoort (TASC fev 2008)
//smallcaps90
//le 15/03/2008


//TotalPrice
//
ap(0)=(Ouverture+Haut+Bas+Cloture)/4

//Lissage de Vervoort type Heiken Ashi
//
hao(0)=(ap(1)+hao(1))/2
hacl=(ap+hao+Maxval(Haut,MaxVal(ap,hao))+MinVal(Bas,MinVal(ap,hao)))/4

//Lissage TEMA
//
P11=P1/1.6
ME1=Exposuiv(ME1,hacl,P11)
ME2=Exposuiv(ME2,ME1,P11)
ME3=Exposuiv(ME3,ME2,P11)
hac(0)=3*ME1-3*ME2+ME3

//Moyenne moyen terme
//
vave=Moyenne(Cloture(1),5*P1)

//Trend de base
//
//Pente de la régression linéaire des clotures
//
somx = 0
somy = 0
somxx = 0
somxy = 0
somx2 = 0
somy2 = 0
somxx2 = 0
somxy2 = 0
Pour P1 Cours
somx = somx+RANGPOUR
somy = somy+Cloture
somxx = somxx+RANGPOUR*RANGPOUR
somxy = somxy+RANGPOUR*Cloture
FinPour
pente = (P1*somxy-somx*somy)/(P1*somxx-somx*somx)

//Lissage TEMA
//
ME4=Exposuiv(ME4,pente,P1)
ME5=Exposuiv(ME5,ME4,P1)
ME6=Exposuiv(ME6,ME5,P1)
vtrend(0)=3*ME4-3*ME5+ME6

//6 SAVPO
//
cutmul=0.0001*P2
c3(0)=(vtrend>vtrend(1)) OU (vtrend(1)>vtrend(2))
c4(0)=(vtrend>=vtrend(1)) OU (vtrend(1)>=vtrend(2))
c1(0)=(hac>hac(1)*(1+cutmul) ET c4)
c2(0)=(hac<hac(1)*(1-cutmul) ET c3)

som=0
i=0
TantQue i<=P1-1 Faire
Si c1(i)
Alors
som=som+cloture(i)
Sinon
Si c2(i)
Alors
som=som-cloture(i)
FinSi
FinSi
i=i+1
FinTantQue

svap=som/(vave+1)

//Lissage TEMA
//
ME7=Exposuiv(ME7,svap,P1)
ME8=Exposuiv(ME8,ME7,P1)
ME9=Exposuiv(ME9,ME8,P1)
svapo=3*ME7-3*ME8+ME9

//Canal
//
ht=P3*Ecartype(svapo,P5)
bs=-P4*Ecartype(svapo,P5)

//fin du code

Propriétés :

<center><img src='http://images.pro-at.com/forums-bourse/0308/3668_202141.png' alt='' /></center>

Exemple avec le CAC40 ce soir :


<center><img src='http://images.pro-at.com/forums-bourse/0308/3668_202144.png' alt='' /></center>


PS1 : j'ai les pdf des 3 articles TASC de S. Vervoort sur ce sujet si cela t'intéresse...

PS2 : le concert de James Blunt au Zénith de Strasbourg vendredi dernier était tout simplement génial!

Cordialement.

[fredifly]

Bonjour et merci pour tes réponses smallcaps <img src='http://www.pro-at.com/style/images/icones/icon_smile.gif' border='0' alt='' title='' align='middle' />

Pour ce qui est de l'importation des cours je vais essayer de passer par ABC bourse comme tu le fais.

Je te remercie pour le programme SVAPO.J'ai remarqué qu'il donnait d'assez bonnes divergences.

J'ai réussi à programmé le SVAPO pour les divergences cachées (pour ceux à qui ça interresse). Ca t'éviteras de faire un post Smallcaps <img src='http://www.pro-at.com/style/images/icones/icon_smile.gif' border='0' alt='' title='' align='middle' />.

Voici le code pour les divergences cachées positives entre le SVAPO et les cours:

<font color='#0000FF'></font>//===========
//DCP_SVAPO
//===========

//Rechercher la divergence cachée éventuelle la plus récente
//entre les cours et le SVAPO
//V 1.0 du 08/02/2006
//

//-----------------------------------------------------------
//PARAMETRES P1 à P5 :
//
//La divergence potentielle devra se trouver
//P4 périodes avant la FINHISTO.
//
//Le 1er creux (ou le 1er sommet) sur l'indicateur
//devra se trouver dans les P1 périodes qui précèdent
//FINHISTO-P4.
//
//Le 2ème creux (ou le 2ème sommet) sur les cours devra
//se trouver dans les P2 périodes qui précèdent le 1er
//
//Chaque creux (ou sommet) sur les cours devra se trouver
//dans les P3 périodes précédant les creux (ou les sommets)
//sur l'indicateur
//
//P5=0 permet d'accepter les divergences cachées dont
//les segments présentent des intersections avec les
//cours et/ou l'indicateur
//P5=1 ne les accepte pas
//
//PARAMETRES A DEFINIR EN TÊTE DE PROGRAMME
//
//CHOIX_INDIC=1----->SVAPO
//
//TYPE_DIV=1----->Divergence cachée en tendance haussière
//TYPE_DIV=2----->Divergence cachée en tendance baissière
//-----------------------------------------------------------

//Initialisations
//
CHOIX_INDIC=1
TYPE_DIV=1

IND(0)=SVAPO.SVAPO*(CHOIX_INDIC=1)
LIGNE1=SVAPO.HT
LIGNE2=SVAPO.BS


MINI=10000
MAXI=0

//Rechercher la divergence cachée éventuelle
//avant les P4 périodes qui pécèdent la FINHISTO
//
SI RANGHISTO=FINHISTO-P4 ALORS

//Rechercher un 1er creux (ou un 1er sommet) EI1
//sur l'indicateur et sa date DATE_EI1
//
I=0
EI1=MINI*(TYPE_DIV=1)+MAXI*(TYPE_DIV=2)
TANTQUE I<=P1 FAIRE
SI (IND(I+2)>IND(I+1) ET IND(I+1)<IND(I))*(TYPE_DIV=1)
OU (IND(I+2)<IND(I+1) ET IND(I+1)>IND(I))*(TYPE_DIV=2) ALORS
SI (IND(I+1)<=EI1)*(TYPE_DIV=1) OU (IND(I+1)>=EI1)*(TYPE_DIV=2) ALORS
EI1=IND(I+1)
DATE_EI1=FINHISTO-P4-(I+1)
D1=I+1
FINSI
FINSI
I=I+1
FINTANTQUE

SI D1=0 ALORS
AFFICHER "======PAS DE 1ER CREUX RECENT SUR L'INDICATEUR======="
AFFICHER "===============MODIFIEZ P1 ET/OU P4 ================="
STOP
FINSI

//Rechercher le 1er creux (ou le 1er sommet) correspondant EC1
//sur les cours et sa date DATE_EC1
//
EC1=BAS(FINHISTO-P4-DATE_EI1)*(TYPE_DIV=1)
+HAUT(FINHISTO-P4-DATE_EI1)*(TYPE_DIV=2)
DATE_EC1=DATE_EI1
K=FINHISTO-P4-DATE_EI1+1
TANTQUE K<=FINHISTO-P4-DATE_EI1+P3 FAIRE
SI (BAS(K)<=EC1)*(TYPE_DIV=1) OU (HAUT(K)>=EC1)*(TYPE_DIV=2) ALORS
EC1=(BAS(K))*(TYPE_DIV=1)+(HAUT(K))*(TYPE_DIV=2)
DATE_EC1=FINHISTO-K-P4
FINSI
K=K+1
FINTANTQUE

//Rechercher un 2ème creux (ou un 2ème sommet) EI2
//sur l'indicateur et sa date DATE_EI2
//
I=D1+1
EI2=EI1
TANTQUE I<=P2+D1 FAIRE
SI (IND(I+2)>IND(I+1) ET IND(I+1)<IND(I))*(TYPE_DIV=1)
OU (IND(I+2)<IND(I+1) ET IND(I+1)>IND(I))*(TYPE_DIV=2) ALORS
SI (IND(I+1)>=EI1)*(TYPE_DIV=1) OU (IND(I+1)<=EI1)*(TYPE_DIV=2) ALORS
EI2=IND(I+1)
DATE_EI2=FINHISTO-P4-(I+1)
D2=1
FINSI
FINSI

SI D2=1 //On a trouvé un creux (un sommet) EI2 possible
ALORS

SI P5=1 ALORS //La droite EI1--EI2 ne doit pas intersecter l'indicateur
PENTE_I=(EI1-EI2)/(DATE_EI1-DATE_EI2)
POUR (FINHISTO-P4-DATE_EI2+1) COURS
POINT_I(0)= PENTE_I*(RANGPOUR-1)+EI2
SI (POINT_I>IND)*(TYPE_DIV=1) OU (POINT_I<IND)*(TYPE_DIV=2) ALORS
N=1
BREAK
FINSI
SI RANGPOUR>(DATE_EI1-DATE_EI2) ALORS BREAK
FINPOUR
FINSI

SI N=0 ALORS //Droite de divergence correcte sur l'indicateur
//Rechercher le 2ème creux (ou le 2ème sommet) correspondant EC2
//sur les cours et sa date DATE_EC2
//
EC2=(BAS(FINHISTO-P4-DATE_EI2))*(TYPE_DIV=1)
+(HAUT(FINHISTO-P4-DATE_EI2))*(TYPE_DIV=2)
DATE_EC2=DATE_EI2
K=FINHISTO-P4-DATE_EI2+1
TANTQUE K<FINHISTO-P4-DATE_EI2+P3 FAIRE
SI (BAS(K)<=EC2)*(TYPE_DIV=1) OU (HAUT(K)>=EC2)*(TYPE_DIV=2) ALORS
EC2=BAS(K)*(TYPE_DIV=1)+HAUT(K)*(TYPE_DIV=2)
DATE_EC2=FINHISTO-K-P4
FINSI
K=K+1
FINTANTQUE

SI (EC2<=EC1)*(TYPE_DIV=1) OU (EC2>=EC1)*(TYPE_DIV=2) ALORS
SI P5=1 ALORS //La droite EC1--EC2 ne doit pas intersecter les cours
PENTE_C=(EC1-EC2)/(DATE_EC1-DATE_EC2)
POUR (FINHISTO-P4-DATE_EC2+1) COURS
POINT_C(0)=PENTE_C*(RANGPOUR-1)+EC2
SI (POINT_C>BAS)*(TYPE_DIV=1) OU (POINT_C<HAUT)*(TYPE_DIV=2) ALORS
M=1
BREAK
FINSI
SI RANGPOUR>(DATE_EC1-DATE_EC2) ALORS BREAK
FINPOUR
FINSI
SI M=0 ALORS //Droite correcte sur les cours
I=P2+D1+1
SINON
D2=0
FINSI
SINON
D2=0
FINSI
SINON
D2=0
FINSI
FINSI
N=0
M=0
I=I+1
FINTANTQUE

SI D1<>0 ET D2=0 OU EC2=0
ALORS
AFFICHER "============PAS DE DIVERGENCE POTENTIELLE============="
AFFICHER "======AVEC LES VALEURS ACTUELLES DES PARAMETRES======="
AFFICHER "===MAIS IL Y A UN 1ER CREUX SUR L'INDIC ET LES COURS=="
AFFICHER "==============MODIFIEZ EVENTUELLEMENT P2=============="
STOP
FINSI


//Déterminer les points des segments de la divergence
//cachée potentielle sur l'indicateur et les cours
//
SI DATE_EC1-DATE_EC2<5 ALORS //La valeur 5 peut être modifiée
AFFICHER "=============DIVERGENCE POTENTIELLE============"
AFFICHER "==========TROP PETITE POUR ETRE TRACEE========="
AFFICHER "===========MODIFIEZ EVENTUELLEMENT P4=========="
SINON
PENTE_I=(EI1-EI2)/(DATE_EI1-DATE_EI2)
POUR (FINHISTO-P4-DATE_EI2+1) COURS
SEG_I(0)=PENTE_I*(RANGPOUR-1)+EI2
SI RANGPOUR>(DATE_EI1-DATE_EI2) ALORS BREAK
FINPOUR

PENTE_C=(EC1-EC2)/(DATE_EC1-DATE_EC2)
POUR (FINHISTO-P4-DATE_EC2+1) COURS
SEG_C(0)=PENTE_C*(RANGPOUR-1)+EC2
SI RANGPOUR>(DATE_EC1-DATE_EC2) ALORS BREAK
FINPOUR
FINSI

FINSI
<font color='#0000FF'></font>

Et la fenêtre propriétés:

<center><a href='http://images.pro-at.com/forums-bourse/0308/20110_210800.png' target='_blank' style='display:block; width:600px; border:2px dashed #888; padding:10px'><img src="http://images.pro-at.com/forums-bourse/0308/20110_210800.png" alt='' width='600' height='450' /><em style='display:block; text-align: right'>Cliquez pour agrandir</em></a></center>

Voici le programme de divergences cachées sur cours (indicateur dérivé):


<font color='#0000FF'></font>//=================
//DCPC_SVAPO
//=================

//V1.0 du 08/02/2006
//

//Tracer le segment de la divergence cachée sur les cours
//

SEG_COURS=SEG_C
<font color='#0000FF'></font>

Et la fenêtre propriétés:

<center><a href='http://images.pro-at.com/forums-bourse/0308/20110_210802.png' target='_blank' style='display:block; width:600px; border:2px dashed #888; padding:10px'><img src="http://images.pro-at.com/forums-bourse/0308/20110_210802.png" alt='' width='600' height='450' /><em style='display:block; text-align: right'>Cliquez pour agrandir</em></a></center>


Voici un exemple de divergences cachées positive entre le SVAPO et les cours:

<center><a href='http://images.pro-at.com/forums-bourse/0308/20110_210803.png' target='_blank' style='display:block; width:600px; border:2px dashed #888; padding:10px'><img src="http://images.pro-at.com/forums-bourse/0308/20110_210803.png" alt='' width='600' height='450' /><em style='display:block; text-align: right'>Cliquez pour agrandir</em></a></center>


Maintenant passons au programme de divergences cachées négatives entre le SVAPO et les cours.

Voici le programme:

<font color='#0000FF'></font>
//===========
//DCN_SVAPO
//===========

//Rechercher la divergence cachée éventuelle la plus récente
//entre les cours et le SVAPO
//V 1.0 du 08/02/2006
//

//-----------------------------------------------------------
//PARAMETRES P1 à P5 :
//
//La divergence potentielle devra se trouver
//P4 périodes avant la FINHISTO.
//
//Le 1er creux (ou le 1er sommet) sur l'indicateur
//devra se trouver dans les P1 périodes qui précèdent
//FINHISTO-P4.
//
//Le 2ème creux (ou le 2ème sommet) sur les cours devra
//se trouver dans les P2 périodes qui précèdent le 1er
//
//Chaque creux (ou sommet) sur les cours devra se trouver
//dans les P3 périodes précédant les creux (ou les sommets)
//sur l'indicateur
//
//P5=0 permet d'accepter les divergences cachées dont
//les segments présentent des intersections avec les
//cours et/ou l'indicateur
//P5=1 ne les accepte pas
//
//PARAMETRES A DEFINIR EN TÊTE DE PROGRAMME
//
//CHOIX_INDIC=1----->SVAPO
//
//TYPE_DIV=1----->Divergence cachée en tendance haussière
//TYPE_DIV=2----->Divergence cachée en tendance baissière
//-----------------------------------------------------------

//Initialisations
//
CHOIX_INDIC=1
TYPE_DIV=2

IND(0)=SVAPO.SVAPO*(CHOIX_INDIC=1)
LIGNE1=SVAPO.HT
LIGNE2=SVAPO.BS


MINI=10000
MAXI=0

//Rechercher la divergence cachée éventuelle
//avant les P4 périodes qui pécèdent la FINHISTO
//
SI RANGHISTO=FINHISTO-P4 ALORS

//Rechercher un 1er creux (ou un 1er sommet) EI1
//sur l'indicateur et sa date DATE_EI1
//
I=0
EI1=MINI*(TYPE_DIV=1)+MAXI*(TYPE_DIV=2)
TANTQUE I<=P1 FAIRE
SI (IND(I+2)>IND(I+1) ET IND(I+1)<IND(I))*(TYPE_DIV=1)
OU (IND(I+2)<IND(I+1) ET IND(I+1)>IND(I))*(TYPE_DIV=2) ALORS
SI (IND(I+1)<=EI1)*(TYPE_DIV=1) OU (IND(I+1)>=EI1)*(TYPE_DIV=2) ALORS
EI1=IND(I+1)
DATE_EI1=FINHISTO-P4-(I+1)
D1=I+1
FINSI
FINSI
I=I+1
FINTANTQUE

SI D1=0 ALORS
AFFICHER "======PAS DE 1ER CREUX RECENT SUR L'INDICATEUR======="
AFFICHER "===============MODIFIEZ P1 ET/OU P4 ================="
STOP
FINSI

//Rechercher le 1er creux (ou le 1er sommet) correspondant EC1
//sur les cours et sa date DATE_EC1
//
EC1=BAS(FINHISTO-P4-DATE_EI1)*(TYPE_DIV=1)
+HAUT(FINHISTO-P4-DATE_EI1)*(TYPE_DIV=2)
DATE_EC1=DATE_EI1
K=FINHISTO-P4-DATE_EI1+1
TANTQUE K<=FINHISTO-P4-DATE_EI1+P3 FAIRE
SI (BAS(K)<=EC1)*(TYPE_DIV=1) OU (HAUT(K)>=EC1)*(TYPE_DIV=2) ALORS
EC1=(BAS(K))*(TYPE_DIV=1)+(HAUT(K))*(TYPE_DIV=2)
DATE_EC1=FINHISTO-K-P4
FINSI
K=K+1
FINTANTQUE

//Rechercher un 2ème creux (ou un 2ème sommet) EI2
//sur l'indicateur et sa date DATE_EI2
//
I=D1+1
EI2=EI1
TANTQUE I<=P2+D1 FAIRE
SI (IND(I+2)>IND(I+1) ET IND(I+1)<IND(I))*(TYPE_DIV=1)
OU (IND(I+2)<IND(I+1) ET IND(I+1)>IND(I))*(TYPE_DIV=2) ALORS
SI (IND(I+1)>=EI1)*(TYPE_DIV=1) OU (IND(I+1)<=EI1)*(TYPE_DIV=2) ALORS
EI2=IND(I+1)
DATE_EI2=FINHISTO-P4-(I+1)
D2=1
FINSI
FINSI

SI D2=1 //On a trouvé un creux (un sommet) EI2 possible
ALORS

SI P5=1 ALORS //La droite EI1--EI2 ne doit pas intersecter l'indicateur
PENTE_I=(EI1-EI2)/(DATE_EI1-DATE_EI2)
POUR (FINHISTO-P4-DATE_EI2+1) COURS
POINT_I(0)= PENTE_I*(RANGPOUR-1)+EI2
SI (POINT_I>IND)*(TYPE_DIV=1) OU (POINT_I<IND)*(TYPE_DIV=2) ALORS
N=1
BREAK
FINSI
SI RANGPOUR>(DATE_EI1-DATE_EI2) ALORS BREAK
FINPOUR
FINSI

SI N=0 ALORS //Droite de divergence correcte sur l'indicateur
//Rechercher le 2ème creux (ou le 2ème sommet) correspondant EC2
//sur les cours et sa date DATE_EC2
//
EC2=(BAS(FINHISTO-P4-DATE_EI2))*(TYPE_DIV=1)
+(HAUT(FINHISTO-P4-DATE_EI2))*(TYPE_DIV=2)
DATE_EC2=DATE_EI2
K=FINHISTO-P4-DATE_EI2+1
TANTQUE K<FINHISTO-P4-DATE_EI2+P3 FAIRE
SI (BAS(K)<=EC2)*(TYPE_DIV=1) OU (HAUT(K)>=EC2)*(TYPE_DIV=2) ALORS
EC2=BAS(K)*(TYPE_DIV=1)+HAUT(K)*(TYPE_DIV=2)
DATE_EC2=FINHISTO-K-P4
FINSI
K=K+1
FINTANTQUE

SI (EC2<=EC1)*(TYPE_DIV=1) OU (EC2>=EC1)*(TYPE_DIV=2) ALORS
SI P5=1 ALORS //La droite EC1--EC2 ne doit pas intersecter les cours
PENTE_C=(EC1-EC2)/(DATE_EC1-DATE_EC2)
POUR (FINHISTO-P4-DATE_EC2+1) COURS
POINT_C(0)=PENTE_C*(RANGPOUR-1)+EC2
SI (POINT_C>BAS)*(TYPE_DIV=1) OU (POINT_C<HAUT)*(TYPE_DIV=2) ALORS
M=1
BREAK
FINSI
SI RANGPOUR>(DATE_EC1-DATE_EC2) ALORS BREAK
FINPOUR
FINSI
SI M=0 ALORS //Droite correcte sur les cours
I=P2+D1+1
SINON
D2=0
FINSI
SINON
D2=0
FINSI
SINON
D2=0
FINSI
FINSI
N=0
M=0
I=I+1
FINTANTQUE

SI D1<>0 ET D2=0 OU EC2=0
ALORS
AFFICHER "============PAS DE DIVERGENCE POTENTIELLE============="
AFFICHER "======AVEC LES VALEURS ACTUELLES DES PARAMETRES======="
AFFICHER "===MAIS IL Y A UN 1ER CREUX SUR L'INDIC ET LES COURS=="
AFFICHER "==============MODIFIEZ EVENTUELLEMENT P2=============="
STOP
FINSI


//Déterminer les points des segments de la divergence
//cachée potentielle sur l'indicateur et les cours
//
SI DATE_EC1-DATE_EC2<5 ALORS //La valeur 5 peut être modifiée
AFFICHER "=============DIVERGENCE POTENTIELLE============"
AFFICHER "==========TROP PETITE POUR ETRE TRACEE========="
AFFICHER "===========MODIFIEZ EVENTUELLEMENT P4=========="
SINON
PENTE_I=(EI1-EI2)/(DATE_EI1-DATE_EI2)
POUR (FINHISTO-P4-DATE_EI2+1) COURS
SEG_I(0)=PENTE_I*(RANGPOUR-1)+EI2
SI RANGPOUR>(DATE_EI1-DATE_EI2) ALORS BREAK
FINPOUR

PENTE_C=(EC1-EC2)/(DATE_EC1-DATE_EC2)
POUR (FINHISTO-P4-DATE_EC2+1) COURS
SEG_C(0)=PENTE_C*(RANGPOUR-1)+EC2
SI RANGPOUR>(DATE_EC1-DATE_EC2) ALORS BREAK
FINPOUR
FINSI

FINSI
<font color='#0000FF'></font>

Et la fenetre propriétés:

<center><a href='http://images.pro-at.com/forums-bourse/0308/20110_210805.jpg' target='_blank' style='display:block; width:600px; border:2px dashed #888; padding:10px'><img src="http://images.pro-at.com/forums-bourse/0308/20110_210805.jpg" alt='' width='600' height='450' /><em style='display:block; text-align: right'>Cliquez pour agrandir</em></a></center>

Voici le programme de divergences cachées sur cours (indicateur dérivé):

<font color='#0000FF'></font>
//=================
//DCNC_SVAPO
//=================

//V1.0 du 08/02/2006
//

//Tracer le segment de la divergence cachée sur les cours
//

SEG_COURS=SEG_C
<font color='#0000FF'></font>

Et la fenetre propriétés:

<center><a href='http://images.pro-at.com/forums-bourse/0308/20110_210807.png' target='_blank' style='display:block; width:600px; border:2px dashed #888; padding:10px'><img src="http://images.pro-at.com/forums-bourse/0308/20110_210807.png" alt='' width='600' height='450' /><em style='display:block; text-align: right'>Cliquez pour agrandir</em></a></center>

Voici un exemple de divergences cachées négatives entre le SVAPO et les cours:

<center><a href='http://images.pro-at.com/forums-bourse/0308/20110_210808.png' target='_blank' style='display:block; width:600px; border:2px dashed #888; padding:10px'><img src="http://images.pro-at.com/forums-bourse/0308/20110_210808.png" alt='' width='600' height='450' /><em style='display:block; text-align: right'>Cliquez pour agrandir</em></a></center>

[smallcaps90]

Bonjour Fred,


Bien reçu ton message en PV.
Vu le volume des docs, j'ai préféré t'envoyer un email à ton adresse free qui contient un zip des progs des divergences régulières que j'avais écrits pour MACD, STOCH, RSI et REPULSE ainsi que les 3 pdf promis des articles de Sylvain Vervoort sur SVAPO et son emploi.
J'ai oublié de te dire qu'il existe aussi des progs de règles statistiques qui permettent d'automatiser la recherche des divergences...

Cordialement.

[ftrillat]

Bonsoir à tous , est-ce que quelqu'un parmis vous a déjà programmer la technique des points pivots?

J'ai découvert cela au séminaire pro At avec Louis et je voudrais bien rentrer ce principe sur graphe AT pro.

Ce que j'ai trouvé sur le sujet si la programmation n'existe pas:

Les niveaux seront calculés avec les formules suivantes, formules qui qui utilisent les cotations de la <strong>veille.</strong>
Pivot = (H + B + C) / 3
S1 = (2 x Pivot) - H
S2 = Pivot - (H - B)
R1 = (2 x Pivot) - B
R2 = Pivot + (H - B)

S1 et S2 sont les deux supports
R1 et R2 sont les 2 résistances
H : cours le plus haut de la veille, B : le plus bas et C, le cours de clôture.

Pour le CAC cela donne pour la séance de demain (donc avec les cours de vendredi):
R2=4961.13
R1=4931
Pivot=4889.84
S1=4859.71
S2=4818.55

merci ftrillat