[Graphe AT PRo : programmation]

**rocabaz** · 08/11/2007, 13:23

moi aussi je suis impatient de voir le travail de smallcaps90
en attendant, max_et_min, peux-tu nous donner le programme du MACD binarisé car je vois qu'il est apparait sur ton graphique

merci beaucoup

**smallcaps90** · 08/11/2007, 15:17

Bonsoir fredifly,

Je poste une version PROTO des programmes indicateurs (stat à venir).

Tout ce qui suit est discutable tant en terme de structure des programmes qu'en termes d'algorithmes choisis.
Il est bien évident que de nombreuses améliorations peuvent y être apportées. On peut toujours faire autrement...

D'abord, la structure à respecter impérativement pour installer les différents programmes est la suivante :

<center><img src='http://images.pro-at.com/forums-bourse/1107/3668_081556.png' alt='' /></center>

Les programmes y sont rangés par GrapheAT Pro dans l'ordre alphabétique qui n'est pas forcément le plus important.
Je posterai donc les programmes par ordre d'importance décroissante.

===================================================
PROGRAMME INDICATEUR SOUS LES COURS : "SW_TREND_ME"

//===========
//SW_TREND_ME
//===========

//v0.4
//PROTO
//le 07/11/2007

//A/ =============PREPARATION
//

//A-1 Trois moyennes exponentielles sur 34 périodes
//
MEH(0)=EXPOSUIV(MEH,Haut,P1)
MEC(0)=EXPOSUIV(MEC,Cloture,P1)
MEB(0)=EXPOSUIV(MEB,Bas,P1)

//A-2 Limites des zones flat
//
LSup(0)=MEC*(1+P2)
LInf(0)=MEC*(1-P2)

//B ==============POINTS D'ACHAT/VENTE POTENTIELS
//

//B-1 Détermination de la tendance pricipale
//
Convexe = (MEC-2*MEC(1)+MEC(2)>=0) //Approximation de la dérivée seconde
Concave = NON(Convexe)
Ascendant = (MEC>MEC(1))
Descendant = NON(Ascendant)

Hausse_Convexe(0) = Convexe ET Ascendant
Hausse_Concave(0) = Concave ET Ascendant
Baisse_Convexe(0) = -(Concave ET Descendant)
Baisse_Concave(0) = -(Convexe ET Descendant)

//B-2 Recherche des périodes "flat"
//
Si RangHisto>=FinHisto-P3
Alors

Si Hausse_Convexe(i) ET (-Baisse_Convexe(i+1) OU -Baisse_Concave(i+1))
OU
-Baisse_Convexe(i) ET (Hausse_Convexe(i+1) OU Hausse_Concave(i+1))
Alors
Sup=LSup(1)
Inf=LInf(1)
//Période "flat" actuelle
Flat(1)=-1

//Périodes "flat" précédentes
k=1
TantQue k<=100 Faire
Si (MEC(k)Inf)
Alors
Flat(k)=-1
FinSi
k=k+1
FinTantQue
FinSi

//Périodes "flat" suivantes
Si (MEC(0)Inf)
Alors
Flat(0)=-1
FinSi

FinSi

//B-3 Mise à jour finale de l'histogramme des trends
//
POUR P3 COURS
Si Flat<>0
Alors
Ascendant=0
Descendant=0
FinSi
FINPOUR

//Fin du code

FENETRE PROPRIETES :
<center><img src='http://images.pro-at.com/forums-bourse/1107/3668_081559.png' alt='' /></center>

RMQ :
Les courbes non tracées n'ont plus d'intérêt, elles peuvent être supprimées.

=================================================
PROGRAMME INDICATEUR SUR LES COURS ET DERIVE DU PRECEDENT : "SW_ME"

//========
//SW_ME
//========

//V0.3
//PROTO
//le 08/11/2007

//A/ =============PREPARATION

//A-1 Moyennes expos
//
MEH=EXPOSUIV(MEH,Haut,P1)
MEC=EXPOSUIV(MEC,Cloture,P1)
MEB=EXPOSUIV(MEB,Bas,P1)

//A-2 Stop suiveur
//
//A DEFINIR

//B/ GESTION DES SIGNAUX D'ACHAT ET DE VENTE
//
//Sert uniquement à la mise au point :
//P2 permet de positionner la recherche sur n'importe
//quel signal d'achat/vente (normalement P2=0)
//

SI RANGHISTO=FINHISTO-P2 Alors

//B-1 Gestion des achats
//
k=0
TantQue k<=80 Faire

Si Descendant(k)<>0 Alors BREAK

Si SW_SIGNAUX_AV.Achat(k)<>0
Alors
Afficher "Achat validé"
A_Valid=1
B=Bas(k)
H=Haut(k)
DB$=datehisto$(k)

i=1

Si k>0 Alors SL=MEB(k-1) //Stop Loss au lendemain du X

TantQue i<=20 Faire
Si Haut(i+k)>H
Alors
H=haut(i+k)
DH$=datehisto$(i+k)
Pos=i+k
FinSi
i=i+1
FinTantQue

BREAK

FinSi
k=k+1
FinTantQue

//B-2 Gestion des ventes
//
k=0
TantQue k<=50 Faire

Si Ascendant(k)<>0 Alors BREAK

Si SW_SIGNAUX_AV.Vente(k)<>0
Alors
Afficher "vente validée"
V_Valid=1
B=Bas(k)
H=Haut(k)
DB$=datehisto$(k)

Si k>0 Alors SL=MEH(k-1) //Stop Loss au lendemain du X

i=1
TantQue i<=20 Faire
Si Bas(i+k)<B
Alors
B=Bas(i+k)
DB$=datehisto$(i+k)
Pos=i+k
FinSi
i=i+1
FinTantQue

BREAK

FinSi
k=k+1
FinTantQue

FINSI

//B-3 Gestion des Fibo's
//
Si A_Valid=1 Alors
//Calculs
//
Diff=H-B
F0=B
F50=B+0.5*Diff
F100=H
F150=B+1.5*Diff
F200=B+2*Diff

//Tracés sur les cours
//
i=Pos+1
TantQue i>=0 Faire
FIB_0(i)=F0
FIB_50(i)=F50
FIB_100(i)=F100
FIB_150(i)=F150
FIB_200(i)=F200
STOP_LOSS(i)=SL
i=i-1
FinTantQue
FinSi

Si V_Valid=1 Alors
//Calculs
//
Diff=H-B
F0=H
F50=H-0.5*Diff
F100=B
F150=H-1.5*Diff
F200=H-2*Diff

//Tracés sur les cours
//
i=Pos+1
TantQue i>=0 Faire
FIB_0(i)=F0
FIB_50(i)=F50
FIB_100(i)=F100
FIB_150(i)=F150
FIB_200(i)=F200
STOP_LOSS(i)=SL
i=i-1
FinTantQue
FinSi

//Fin du code

FENETRE PROPRIETES :
<center><img src='http://images.pro-at.com/forums-bourse/1107/3668_081601.png' alt='' /></center>

=================================================
PROGRAMME INDICATEUR SOUS LES COURS EGALEMENT DERIVE DU PREMIER : "SW_SIGNAUX_AV" :

//=============
//SW_SIGNAUX_AV
//=============

//Signaux d'achat/vente
//

//1/ Pullbacks baissiers en tendance haussière
//

Si Ascendant=1
Alors
Achat=(((croise(bas, MEH)<0 OU croise(bas, MEC)<0)
ET (bas>MEB) ET (bas(1)>MEH(1))) ET Flat=0)
FinSi

//2/ Pullbacks haussiers en tendance baissière
//
Si Descendant=1
Alors
Vente=(((croise(Haut, MEB)>0 OU croise(haut, MEC)>0)
ET (haut<MEH) ET (haut(1)<MEB(1))) ET Flat=0)
FinSi

//Fin du code

FENETRE PROPRIETES :

<center><img src='http://images.pro-at.com/forums-bourse/1107/3668_081604.png' alt='' /></center>

========================================
PROGRAMME INDICATEUR INDEPENDANT SOUS LES COURS : "SW_CONVCONC_ME"
(pas nécessaire au fonctionnement sert à la mise au point)

//==============
//SW_CONVCONC_ME
//==============

//Recherche des zones convexes/concaves et ascendantes/descendantes
//sur la moyenne expo des clotures sur 34 périodes
//Reprend le programme de 2006
//

MEC(0)=EXPOSUIV(MEC,Cloture,P1)

CONVEXE = (MEC-2*MEC(1)+MEC(2)>=0) //Approximation de la dérivée seconde
CONCAVE = NON(CONVEXE)
ASCENDANT = (MEC>MEC(1))
DESCENDANT = NON(ASCENDANT)

HAUSSE_CONVEXE = CONVEXE ET ASCENDANT
HAUSSE_CONCAVE = CONCAVE ET ASCENDANT
BAISSE_CONVEXE = -(CONCAVE ET DESCENDANT)
BAISSE_CONCAVE = -(CONVEXE ET DESCENDANT)

//Fin du code

FENETRE PROPRIETES :

<center><img src='http://images.pro-at.com/forums-bourse/1107/3668_081606.png' alt='' /></center>

========================================
PROGRAMLME INDICATEUR INDEPENDANT SOUS LES COURS : "SW_MACDHISTO" :

//========
//SW_MACDHISTO
//========

//le 05/11/2007

//MACD
//
ME1 = EXPOSUIV(ME1,CLOTURE,P1)
ME2 = EXPOSUIV(ME2,CLOTURE,P2)
SW_MACD = ME1-ME2

//SIGNAL
//
SW_MMACD = EXPOSUIV(SW_MMACD,SW_MACD,P3)

//MACD Histo colorié

SI SW_MACD-SW_MMACD>=0 ALORS SW_MACDHISTO_V = 1
SI SW_MACD-SW_MMACD<0 ALORS SW_MACDHISTO_R = -1

//fin du code

FENETRE PROPRIETES :

<center><img src='http://images.pro-at.com/forums-bourse/1107/3668_081607.png' alt='' /></center>

Avec Véolia en date d'hier :

<center><img src='http://images.pro-at.com/forums-bourse/1107/3668_081608.png' alt='' /></center>

L'indicateur "SW_TREND_ME" autour duquel tout est articulé montre les périodes de trend haussier en vert, de trend baissier en rouge et les périodes "15h" en bleu.

J'ai reporté sur un autre indicateur sous les cours :"SW_SIGNAUX_AV" le repèrage des signaux d'achat/vente trouvés sous forme de flèches vertes et rouges.
On ne les cherche pas sur la totalité se l'historique pour des raisons de temps de recherche. Normalement il suffirait de disposer du dernier signal en fait...Cela peut-être changé évidemment.

Les indicateurs sous les cours "SW_CONVCONC_ME" et "SW_MACD_HISTO" peuvent être supprimés, ils ne participent pas au fonctionnement d'ensemble...

On n'a plus de prise de position pendant les périodes "Flat 15h".

J'ai conservé les tracés des niveaux des Fibo's de mes posts précédents à partir du dernier signal d'achat de début novembre, il est bien sûr possible de programmer les niveaux que tu souhaites...Le tracé du STOP LOSS est là également lorsqu'il est connu.

Comme tu le constates, le signal d'achat de fin août qui nous gênait a disparu il se trouve dans une période "15h"....sans qu'il soit fait usage du MACDHISTO que j'ai donné ci-dessus au cas où...
les repères 1 et 2 en avril et mai correspondent à des non croisements des cours avec la MEH, mais ils s'en approchent de très près et on pourrait très facilement, si on le souhaitait, les utiliser comme d'autres entrées également...

J'ai sûrement oublié de dire des choses utiles...mille excuses!

Cordialement.

**fredifly** · 08/11/2007, 16:49

Wahooo..... C'est beau.... <img src='http://www.pro-at.com/style/images/icones/icon_smile_tongue.gif' border='0' alt='' title='' align='middle' />

Tu as fais un travail plus que magnifique Smallcaps...

De toute façon ce n'est que la première version de la méthode qui doit être améliorer.

Je vais tester tout ça.

Encore une fois merci pour ce beau travail.

Cordialement.

Fredifly.

**LONGWAY** · 08/11/2007, 17:11

Bonjour,

Super travail Smallcaps, je viens de recréer tous les indicateurs. Je vais les tester.

As tu reçu mon Email?

Cordialement

**max_et_min** · 08/11/2007, 17:17

Bonsoir à tous
Aprés ça je suis sans voix.
Bravo travail superbe.
pour répondre à rocabaz
J'utilise une copie du macd de base

// MACD P1=12 P2=26 P3=9
ema1 = ema1+(CLOTURE-ema1) * 2/(1+P1)
ema2 = ema2+(CLOTURE-ema2) * 2/(1+P2)
RMACD = ema1 - ema2

// Moyenne exponentielle du MACD
RMMACD = EXPOSUIV(RMMACD,RMACD,P3)

avec en HISTO
et 3 courbes
RMACDHISTO avec aucun
MACDH avec Histogramme et COULEUR VERT et 4
MACDB avec Histogramme et COULEUR ROUGE et 4

//***************
// MACD KOSTA
//***************
// MACD Histogramme
RMACDHISTO = RMACD-RMMACD
MACDH=0
MACDB=0
si RMACDHISTO>0 alors MACDH=1
si RMACDHISTO<0 alors MACDB=1

**trados** · 08/11/2007, 17:17

dis donc c'est du rapide
et apparemment pas de pb ça marche

merci beaucoup à vous deux

**smallcaps90** · 08/11/2007, 17:51

Rebonsoir fredifly,

Pendant que c'est chaud, voici la statistique promise qui s'associe aux indicateurs précédents. Elle semble trourner sans pb...

Pour plus de détails, lire les commentaires en tête du programme ci-dessous.

==========================================
PROGRAMME STATISTIQUE : "STAT_SWING_TRADE"

//================
//STAT_SWING_TRADE
//================

//PROTO
//v0.3
//le 08/11/2007

//===================================================================
//Statistique qui extrait d'un groupe donné, les valeurs qui
//ont dernièrement émis un signal d'achat, ou de vente, conforme
//à la méthode de Kosta : "Swing Trade".
//Pour l'instant l'affichage des paramètres suivants, et utiles
//au trade, sont présents dans le tableau de synthèse final :
//
//1- Affichage de la date du croisement cours/moyennes expos :
//celle-ci est récupérée de deux programmes indicateurs détectant
//les signaux d'achat et de vente : "SW_SIGNAUX_AV" et :
//"SW_TREND_ME" détectant la nature du trend en cours
//
//2- Affichage des valeurs des niveaux de retracements de Fibonacci
//que l'utilisateur peut modifier à loisir à la fin du programme
//indicateur associé également à cette statistique : "SW_ME", dans
//la limite maxi de 7 niveaux simultanés.
//Dans cette occurrence, il davra aussi modifier les intitulés
//des variables correspondantes à ces niveaux de telles sortes
//qu'elles correspondent dans le programme indicateur et dans cette
//statistique.
//
//3- Affichage du Stop loss récupéré du programme indicateur associé :
//"SW_ME" également.
//
//La recherche se fait sur les 50 dernières périodes de l'historique.
//Ceci peut être modifié à volonté.
//L'utilisateur doit définir le niveau de son entrée.
//La sortie de position n'est pas prise compte pour l'instant.
//Il doit aussi gèrer son money management en fonction de ses
//préférences et contraintes.
//===================================================================

//Fixer ici le nombre de périodes à scanner
//pour la recherche des signaux d'A/V:
//
D=50

//Rechercher les derniers signaux d'Achat/vente
//et leur position
//
//Signaux d'Achat
//
k=0
TantQue k<=D Faire

Si SW_TREND_ME.Descendant(k)<>0 Alors BREAK
Si SW_SIGNAUX_AV.Achat(k)<>0
Alors
DB$=datehisto$(k)
Colonne1="Achat possible après le " & DB$
//On peut placer ici les calculs des Fibo's
//On les récupère dans cette version
Colonne2=SW_ME.FIB_0
Colonne3=SW_ME.FIB_50
Colonne4=SW_ME.FIB_100
Colonne5=SW_ME.FIB_150
Colonne6=SW_ME.FIB_200
Colonne7=SW_ME.Stop_Loss
Select=1
BREAK
FinSi

k=k+1
FinTantQue

//Signaux de Vente
//
k=0
TantQue k<=D Faire

Si SW_TREND_ME.Ascendant(k)<>0 Alors BREAK
Si SW_SIGNAUX_AV.Vente(k)<>0
Alors
DH$=datehisto$(k)
Colonne1="Vente possible après le " & DH$
//On peut placer ici les calculs des Fibo's
//On les récupère dans cette version
Colonne2=SW_ME.FIB_0
Colonne3=SW_ME.FIB_50
Colonne4=SW_ME.FIB_100
Colonne5=SW_ME.FIB_150
Colonne6=SW_ME.FIB_200
Colonne7=SW_ME.Stop_Loss
Select=1
BREAK
FinSi

k=k+1
FinTantQue

//Sélection finale
//
Si Select=1
Alors
Selection
FinSi

//Fin du code

PROPRIETES DE LA STATISTIQUE :
<center><img src='http://images.pro-at.com/forums-bourse/1107/3668_081839.png' alt='' /></center>

Je l'ai appliquée sur le CAC40 en date d'hier soir et de ce soir :

<center><img src='http://images.pro-at.com/forums-bourse/1107/3668_081853.jpg' alt='' /></center>

1ère colonne : type opération et date du croisement cours/moyennes retenu
2ème colonne : cloture du jour
3ème colonne : niveau 0% de retracement de Fibo
4ème colonne : niveau 50%
5ème colonne : niveau 100%
6ème colonne : niveau 150%
7ème colonne : niveau 200%
A nouveau, je signale que j'ai gardé les niveaux d eretracements que j'avais choisis au début de l'étude mais chaque utilisateur peut définir ses propres niveaux de retracements évidemment.

8ème colonne : niveau du stop loss lorsqu'il est connu.
La dernière colonne est gèrée par GrapheAT pro et comporte les noms des valeurs sélectionnées par la stat.

<center><img src='http://images.pro-at.com/forums-bourse/1107/3668_081857.jpg' alt='' /></center>
Si un "0" est indiqué en colonne stop loss, cela signifie que sa valeur n'est pas encore connue, donc que le croisement a eu lieu au jour de la stat.
Il faut bien remarquer aussi que seuls les derniers signaux d'achat/vente sont répertiorés dans les tableaux.

ATTENTION!!!

Veolia n'a pas de stop loss indiqué en 8ème colonne pour la journée d'hier.
Ceci est du simplement au fait que j'ai relancé la stat ce soir en date d'hier soir en changeant la date en haut de la fenêtre dans laquelle s'exécute la stat. Et évidemment comme le programme ne garde pas en mémoire les valeurs des colonnes pour les jours précédents lorsqu'il y a un changement de signal d'A/V comme c'est le cas ce soir pour Véolia, le fait de changer la date avant de lancer la stat sur un jour antérieur ne récupèrera pas les valeurs pour ce(s) jour(s) là....
Si la stat avait été lancée avant le nouveau signal d'achat émis aujourd'hui sur Véolia, hier soir par exemple, la valeur de son stop loss antérieur aurait été disponible dans le tableau de synthèse évidemment...
J'avais lancé la stat dans une version antérieure, sans la colonne 2 : "cloture du soir", le 05/11 dernier et le stop loss antérieur sur Véolia était bien présent...

Mille excuses encore pour ce contre-temps.

Cordialement.

**elguapolatino** · 08/11/2007, 18:01

Dans ma recherche de renversement de tendance,sur les indicateus fournis par smallcaps que je remercie d'ailleurs,il etait dans mes intentions de vous demander ces éléments ,mais il y a une similitude avec les swing trade kosta, A VOIR:

peut-on avec,comme base de recherches
- un indicateur MACD parametre 7 15 4
-un indicateur STOCH parametre 8 8 5
et l'indicateur SAR_ATD

Avec ces éléments:
-Les valeurs dont la MACD coupe son signal à la baisse
- Les valeurs dont la STOCH coupe son signal à la baisse
Obtenir une statistique qui rechercherait les valeurs dont l'ecart à la cloture est le plus important en pourcentage avec la parabolique SAR
ceci en ordre decroissant

à exploiter aussi à la hausse

dont la continuation de mes recherches,je pensait aussi,à la place de la MACD et STOCH
Me servir de 3 moyennes à la baisses par ex: 20 30 50
mais j'aimerai y incorporer dans l'indicateur qui serait visible sur le graph, une moyenne soit exponentielle soit pondérée(eventuellement variable),qui couperait les moyennes en croix dorées, car elles serviraient de résistances.
une stat qui rechercherait les valeurs dont l'ecart à la cloture serait le plus important avec le SAR

je suis toujours en test et je ne suis pas sur d'obtenir des résultats concrets, si des amis peuvent se joindre dans cette analyse cele ne serait que meilleurs,si resultats il y a ,c'est avec plaisr que je les tansmettraient

AMICAL Marcel

**rocabaz** · 08/11/2007, 18:39

merci beaucoup Smallcaps90
tu es vraiment fantastique

pardonnez au débutant que je suis mais j'ai copié collé les programmes de smallcaps90
et par exemple pour SW_ME, le test grapheat me dit :
k=0
TantQue k<=80 Faire
Si Descendant(k)<>0 Alors BREAK

la variable descendant n'est pas de type tableau
alors là je ne comprends pas

merci beaucoup

**LONGWAY** · 08/11/2007, 18:48

Bonjour Rocabaz,

Je viens de tout intégrer et je n'ai aucun souci. As-tu appuyer sur controler ou sur tester pour avoir ce message?

Cordialement

**rocabaz** · 08/11/2007, 19:18

oui j'ai appuyé sur tester

**fredifly** · 08/11/2007, 19:22

Rebonsoir à toi aussi Smallcaps,

Merci pour le programme de statistique.

<img src='http://www.pro-at.com/style/images/icones/icon_smile_wink.gif' border='0' alt='' title='' align='middle' />

Fredifly.

**fredifly** · 08/11/2007, 19:24

<blockquote>Citation de : rocabaz (au 08-11-2007 19:39:52)

merci beaucoup Smallcaps90
tu es vraiment fantastique

pardonnez au débutant que je suis mais j'ai copié collé les programmes de smallcaps90
et par exemple pour SW_ME, le test grapheat me dit :
k=0
TantQue k<=80 Faire
Si Descendant(k)<>0 Alors BREAK

la variable descendant n'est pas de type tableau
alors là je ne comprends pas

merci beaucoup
</blockquote><hr />

Bonsoir Rocabz,

Si tu suis à la lettre ce qu'a écrit Smallcaps tu ne dois avoir aucun problème.

**smallcaps90** · 08/11/2007, 19:59

Bonsoir rocabaz,

Il faut bien comprendre la chose suivante...
Une variable peut-être définie dans un programme et utilisée aussi dans un autre.

C'est le cas de la variable "Descendant" qui est définie dans le programme "SW_TREND_ME" dans lequel elle apparaît aussi dans sa fenêtre "Propriétés". C'est donc une "courbe" visible dans cet indic.
Elle est utilisée aussi dans le programme "SW_ME" sans y être ds la fenêtre "Propriétés" puisque ce n'est pas une courbe visible dans cet indic.

Aussi tu comprends bien que "SW_TREND_ME" doit être exécuté pour que "SW_ME" puisse utiliser à son tour la variable "Descendant".

Tu n'auras donc plus de pb si Tu lances les indics "SW_TREND_ME" et "SW_ME" sur le même graphe.

Il faut aussi respecter scrupuleusement ce qui a été présenté au tout début de mon post dans le schéma qui représente la structure d'installation des programmes...

En fait comme expliqué plus haut il n'y a que les indics : "SW_CONVCONC_ME" et "SW_MACDHISTO" qui sont facultatifs ici.

Bon courage à toi...

**max_et_min** · 08/11/2007, 21:07

Bonsoir à tous
suite à notre conversation sur l'importance de la valeur de la moyenne
en premier jet en affinant le programme sur SW_TREND_ME

P1 à 37 semble être plus approprié avec de gros ecarts de résultat
à confirmer par vos essais
Cordialement

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire

Commentaire